source: BMXNET_RPMS_dotNET_UTILITIES-BMX/branch/IHS BMX Framework/IndianHealthService.BMXNet.GeneratedDocumentation/Help/Presentation/Style/Transforms/main_sandcastle.xsl@ 1146

Last change on this file since 1146 was 1146, checked in by Sam Habiel, 13 years ago

Initial Import of BMX4
File size: 23.8 KB
Line 
1<?xml version="1.0"?>
2<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.1">
3
4 <!-- stuff specified to comments authored in DDUEXML -->
5
6
7 <xsl:include href="htmlBody.xsl"/>
8 <xsl:include href="utilities_reference.xsl" />
9
10 <xsl:variable name="summary" select="normalize-space(/document/comments/summary)" />
11 <xsl:variable name="abstractSummary" select="/document/comments/summary" />
12 <xsl:variable name="hasSeeAlsoSection" select="boolean((count(/document/comments//seealso | /document/reference/elements/element/overloads//seealso) > 0) or
13 ($group='type' or $group='member' or $group='list'))"/>
14 <xsl:variable name="examplesSection" select="boolean(string-length(/document/comments/example[normalize-space(.)]) > 0)"/>
15 <xsl:variable name="languageFilterSection" select="boolean(string-length(/document/comments/example[normalize-space(.)]) > 0)" />
16
17 <xsl:template name="body">
18
19 <!-- auto-inserted info -->
20 <!-- <xsl:apply-templates select="/document/reference/attributes" /> -->
21 <xsl:apply-templates select="/document/comments/preliminary" />
22 <xsl:apply-templates select="/document/comments/summary" />
23 <xsl:if test="$subgroup='overload'">
24 <xsl:apply-templates select="/document/reference/elements" mode="overloadSummary" />
25 </xsl:if>
26 <!-- assembly information -->
27 <xsl:if test="not($group='list' or $group='root' or $group='namespace')">
28 <xsl:call-template name="requirementsInfo"/>
29 </xsl:if>
30 <!-- syntax -->
31 <xsl:if test="not($group='list' or $group='namespace')">
32 <xsl:apply-templates select="/document/syntax" />
33 </xsl:if>
34 <!-- members -->
35 <xsl:choose>
36 <xsl:when test="$group='root'">
37 <xsl:apply-templates select="/document/reference/elements" mode="root" />
38 </xsl:when>
39 <xsl:when test="$group='namespace'">
40 <xsl:apply-templates select="/document/reference/elements" mode="namespace" />
41 </xsl:when>
42 <xsl:when test="$subgroup='enumeration'">
43 <xsl:apply-templates select="/document/reference/elements" mode="enumeration" />
44 </xsl:when>
45 <xsl:when test="$group='type'">
46 <xsl:apply-templates select="/document/reference/elements" mode="type" />
47 </xsl:when>
48 <xsl:when test="$group='list'">
49 <xsl:choose>
50 <xsl:when test="$subgroup='overload'">
51 <xsl:apply-templates select="/document/reference/elements" mode="overload" />
52 </xsl:when>
53 <xsl:when test="$subgroup='DerivedTypeList'">
54 <xsl:apply-templates select="/document/reference/elements" mode="derivedType" />
55 </xsl:when>
56 <xsl:otherwise>
57 <xsl:apply-templates select="/document/reference/elements" mode="member" />
58 </xsl:otherwise>
59 </xsl:choose>
60 </xsl:when>
61 </xsl:choose>
62 <!-- remarks -->
63 <xsl:apply-templates select="/document/comments/remarks" />
64 <!-- example -->
65 <xsl:apply-templates select="/document/comments/example" />
66 <!-- other comment sections -->
67 <!-- permissions -->
68 <xsl:call-template name="permissions" />
69 <!-- exceptions -->
70 <xsl:call-template name="exceptions" />
71 <!-- inheritance -->
72 <xsl:apply-templates select="/document/reference/family" />
73 <xsl:apply-templates select="/document/comments/threadsafety" />
74 <!--versions-->
75 <xsl:if test="not($group='list' or $group='namespace' or $group='root' )">
76 <xsl:apply-templates select="/document/reference/versions" />
77 </xsl:if>
78 <!-- see also -->
79 <xsl:call-template name="seealso" />
80
81 </xsl:template>
82
83 <xsl:template name="getParameterDescription">
84 <xsl:param name="name" />
85 <xsl:apply-templates select="/document/comments/param[@name=$name]" />
86 </xsl:template>
87
88 <xsl:template name="getReturnsDescription">
89 <xsl:param name="name" />
90 <xsl:apply-templates select="/document/comments/param[@name=$name]" />
91 </xsl:template>
92
93 <xsl:template name="getElementDescription">
94 <xsl:apply-templates select="summary[1]" />
95 </xsl:template>
96
97 <xsl:template name="getOverloadSummary">
98 <xsl:apply-templates select="overloads" mode="summary"/>
99 </xsl:template>
100
101 <xsl:template name="getOverloadSections">
102 <xsl:apply-templates select="overloads" mode="sections"/>
103 </xsl:template>
104
105 <xsl:template name="getInternalOnlyDescription">
106
107 </xsl:template>
108
109
110 <!-- block sections -->
111
112 <xsl:template match="summary">
113 <div class="summary">
114 <xsl:apply-templates />
115 </div>
116 </xsl:template>
117
118 <xsl:template match="overloads" mode="summary">
119 <xsl:choose>
120 <xsl:when test="count(summary) > 0">
121 <xsl:apply-templates select="summary" />
122 </xsl:when>
123 <xsl:otherwise>
124 <div class="summary">
125 <xsl:apply-templates/>
126 </div>
127 </xsl:otherwise>
128 </xsl:choose>
129 </xsl:template>
130
131 <xsl:template match="overloads" mode="sections">
132 <xsl:apply-templates select="remarks" />
133 <xsl:apply-templates select="example"/>
134 </xsl:template>
135
136 <xsl:template match="value">
137 <xsl:call-template name="subSection">
138 <xsl:with-param name="title">
139 <include item="fieldValueTitle" />
140 </xsl:with-param>
141 <xsl:with-param name="content">
142 <xsl:apply-templates />
143 </xsl:with-param>
144 </xsl:call-template>
145 </xsl:template>
146
147 <xsl:template match="returns">
148 <xsl:call-template name="subSection">
149 <xsl:with-param name="title">
150 <include item="methodValueTitle" />
151 </xsl:with-param>
152 <xsl:with-param name="content">
153 <xsl:apply-templates />
154 </xsl:with-param>
155 </xsl:call-template>
156 </xsl:template>
157
158 <xsl:template match="templates">
159 <xsl:call-template name="section">
160 <xsl:with-param name="toggleSwitch" select="'templates'" />
161 <xsl:with-param name="title">
162 <include item="templatesTitle" />
163 </xsl:with-param>
164 <xsl:with-param name="content">
165 <dl>
166 <xsl:for-each select="template">
167 <xsl:variable name="templateName" select="@name" />
168 <dt>
169 <span class="parameter">
170 <xsl:value-of select="$templateName"/>
171 </span>
172 </dt>
173 <dd>
174 <xsl:apply-templates select="/document/comments/typeparam[@name=$templateName]" />
175 </dd>
176 </xsl:for-each>
177 </dl>
178 </xsl:with-param>
179 </xsl:call-template>
180 </xsl:template>
181
182 <xsl:template match="remarks">
183 <xsl:call-template name="section">
184 <xsl:with-param name="toggleSwitch" select="'remarks'"/>
185 <xsl:with-param name="title"><include item="remarksTitle" /></xsl:with-param>
186 <xsl:with-param name="content"><xsl:apply-templates /></xsl:with-param>
187 </xsl:call-template>
188 </xsl:template>
189
190 <xsl:template match="example">
191 <xsl:call-template name="section">
192 <xsl:with-param name="toggleSwitch" select="'example'"/>
193 <xsl:with-param name="title"><include item="examplesTitle" /></xsl:with-param>
194 <xsl:with-param name="content"><xsl:apply-templates /></xsl:with-param>
195 </xsl:call-template>
196 </xsl:template>
197
198 <xsl:template match="para">
199 <p><xsl:apply-templates /></p>
200 </xsl:template>
201
202 <xsl:template match="code">
203
204 <xsl:variable name="codeLang">
205 <xsl:choose>
206 <xsl:when test="@language = 'vbs'">
207 <xsl:text>VBScript</xsl:text>
208 </xsl:when>
209 <xsl:when test="@language = 'vb' or @language = 'vb#' or @language = 'VB'" >
210 <xsl:text>VisualBasic</xsl:text>
211 </xsl:when>
212 <xsl:when test="@language = 'c#' or @language = 'cs' or @language = 'C#'" >
213 <xsl:text>CSharp</xsl:text>
214 </xsl:when>
215 <xsl:when test="@language = 'cpp' or @language = 'cpp#' or @language = 'c' or @language = 'c++' or @language = 'C++'" >
216 <xsl:text>ManagedCPlusPlus</xsl:text>
217 </xsl:when>
218 <xsl:when test="@language = 'j#' or @language = 'jsharp'">
219 <xsl:text>JSharp</xsl:text>
220 </xsl:when>
221 <xsl:when test="@language = 'js' or @language = 'jscript#' or @language = 'jscript' or @language = 'JScript'">
222 <xsl:text>JScript</xsl:text>
223 </xsl:when>
224 <xsl:when test="@language = 'xml'">
225 <xsl:text>xmlLang</xsl:text>
226 </xsl:when>
227 <xsl:when test="@language = 'html'">
228 <xsl:text>html</xsl:text>
229 </xsl:when>
230 <xsl:when test="@language = 'vb-c#'">
231 <xsl:text>visualbasicANDcsharp</xsl:text>
232 </xsl:when>
233 <xsl:when test="@language = 'xaml' or @language = 'XAML'">
234 <xsl:text>XAML</xsl:text>
235 </xsl:when>
236 <xsl:otherwise>
237 <xsl:text>other</xsl:text>
238 </xsl:otherwise>
239 </xsl:choose>
240 </xsl:variable>
241
242 <xsl:call-template name="codeSection">
243 <xsl:with-param name="codeLang" select="$codeLang" />
244 </xsl:call-template>
245
246 </xsl:template>
247
248 <xsl:template name="exceptions">
249 <xsl:if test="count(/document/comments/exception) &gt; 0">
250 <xsl:call-template name="section">
251 <xsl:with-param name="toggleSwitch" select="'exceptions'"/>
252 <xsl:with-param name="title"><include item="exceptionsTitle" /></xsl:with-param>
253 <xsl:with-param name="content">
254 <div class="tableSection">
255 <table width="100%" cellspacing="2" cellpadding="5" frame="lhs" >
256 <tr>
257 <th class="exceptionNameColumn"><include item="exceptionNameHeader" /></th>
258 <th class="exceptionConditionColumn"><include item="exceptionConditionHeader" /></th>
259 </tr>
260 <xsl:for-each select="/document/comments/exception">
261 <tr>
262 <td><referenceLink target="{@cref}" qualified="true" /></td>
263 <td>
264 <xsl:apply-templates select="." />
265 </td>
266 </tr>
267 </xsl:for-each>
268 </table>
269 </div>
270 </xsl:with-param>
271 </xsl:call-template>
272 </xsl:if>
273 </xsl:template>
274
275 <xsl:template name="permissions">
276 <xsl:if test="count(/document/comments/permission) &gt; 0">
277 <xsl:call-template name="section">
278 <xsl:with-param name="toggleSwitch" select="'permissions'" />
279 <xsl:with-param name="title">
280 <include item="permissionsTitle" />
281 </xsl:with-param>
282 <xsl:with-param name="content">
283 <div class="tableSection">
284 <table width="100%" cellspacing="2" cellpadding="5" frame="lhs" >
285 <tr>
286 <th class="permissionNameColumn">
287 <include item="permissionNameHeader" />
288 </th>
289 <th class="permissionDescriptionColumn">
290 <include item="permissionDescriptionHeader" />
291 </th>
292 </tr>
293 <xsl:for-each select="/document/comments/permission">
294 <tr>
295 <td>
296 <referenceLink target="{@cref}" qualified="true" />
297 </td>
298 <td>
299 <xsl:apply-templates select="." />
300 </td>
301 </tr>
302 </xsl:for-each>
303 </table>
304 </div>
305 </xsl:with-param>
306 </xsl:call-template>
307 </xsl:if>
308 </xsl:template>
309
310 <xsl:template name="seealso">
311 <xsl:if test="$hasSeeAlsoSection">
312 <xsl:call-template name="section">
313 <xsl:with-param name="toggleSwitch" select="'seeAlso'" />
314 <xsl:with-param name="title">
315 <include item="relatedTitle" />
316 </xsl:with-param>
317 <xsl:with-param name="content">
318 <xsl:call-template name="autogenSeeAlsoLinks"/>
319 <xsl:for-each select="/document/comments//seealso | /document/reference/elements/element/overloads//seealso">
320 <div class="seeAlsoStyle">
321 <xsl:apply-templates select=".">
322 <xsl:with-param name="displaySeeAlso" select="true()" />
323 </xsl:apply-templates>
324 </div>
325 </xsl:for-each>
326 </xsl:with-param>
327 </xsl:call-template>
328 </xsl:if>
329 </xsl:template>
330
331 <xsl:template match="list[@type='bullet']">
332 <ul>
333 <xsl:for-each select="item">
334 <li><xsl:apply-templates /></li>
335 </xsl:for-each>
336 </ul>
337 </xsl:template>
338
339 <xsl:template match="list[@type='number']">
340 <ol>
341 <xsl:for-each select="item">
342 <li><xsl:apply-templates /></li>
343 </xsl:for-each>
344 </ol>
345 </xsl:template>
346
347 <xsl:template match="list[@type='table']">
348 <div class="tableSection">
349 <table width="100%" cellspacing="2" cellpadding="5" frame="lhs" >
350 <xsl:for-each select="listheader">
351 <tr>
352 <xsl:for-each select="*">
353 <th><xsl:apply-templates /></th>
354 </xsl:for-each>
355 </tr>
356 </xsl:for-each>
357 <xsl:for-each select="item">
358 <tr>
359 <xsl:for-each select="*">
360 <td>
361 <xsl:apply-templates />
362 </td>
363 </xsl:for-each>
364 </tr>
365 </xsl:for-each>
366 </table>
367 </div>
368 </xsl:template>
369
370 <!-- inline tags -->
371
372 <xsl:template match="see[@cref]">
373 <xsl:choose>
374 <xsl:when test="normalize-space(.)">
375 <referenceLink target="{@cref}">
376 <xsl:value-of select="." />
377 </referenceLink>
378 </xsl:when>
379 <xsl:otherwise>
380 <referenceLink target="{@cref}"/>
381 </xsl:otherwise>
382 </xsl:choose>
383 </xsl:template>
384
385 <xsl:template match="see[@href]">
386 <xsl:choose>
387 <xsl:when test="normalize-space(.)">
388 <a>
389 <xsl:attribute name="href"><xsl:value-of select="@href"/></xsl:attribute>
390 <xsl:value-of select="." />
391 </a>
392 </xsl:when>
393 <xsl:otherwise>
394 <a>
395 <xsl:attribute name="href"><xsl:value-of select="@href"/></xsl:attribute>
396 <xsl:value-of select="@href" />
397 </a>
398 </xsl:otherwise>
399 </xsl:choose>
400 </xsl:template>
401
402 <xsl:template match="seealso[@href]">
403 <xsl:param name="displaySeeAlso" select="false()" />
404 <xsl:if test="$displaySeeAlso">
405 <xsl:choose>
406 <xsl:when test="normalize-space(.)">
407 <a>
408 <xsl:attribute name="href"><xsl:value-of select="@href"/></xsl:attribute>
409 <xsl:value-of select="." />
410 </a>
411 </xsl:when>
412 <xsl:otherwise>
413 <a>
414 <xsl:attribute name="href"><xsl:value-of select="@href"/></xsl:attribute>
415 <xsl:value-of select="@href" />
416 </a>
417 </xsl:otherwise>
418 </xsl:choose>
419 </xsl:if>
420 </xsl:template>
421
422 <xsl:template match="see[@langword]">
423 <span class="keyword">
424 <xsl:choose>
425 <xsl:when test="@langword='null' or @langword='Nothing' or @langword='nullptr'">
426 <span class="languageSpecificText">
427 <span class="cs">null</span>
428 <span class="vb">Nothing</span>
429 <span class="cpp">nullptr</span>
430 </span>
431 </xsl:when>
432 <xsl:when test="@langword='static' or @langword='Shared'">
433 <span class="languageSpecificText">
434 <span class="cs">static</span>
435 <span class="vb">Shared</span>
436 <span class="cpp">static</span>
437 </span>
438 </xsl:when>
439 <xsl:when test="@langword='virtual' or @langword='Overridable'">
440 <span class="languageSpecificText">
441 <span class="cs">virtual</span>
442 <span class="vb">Overridable</span>
443 <span class="cpp">virtual</span>
444 </span>
445 </xsl:when>
446 <xsl:when test="@langword='true' or @langword='True'">
447 <span class="languageSpecificText">
448 <span class="cs">true</span>
449 <span class="vb">True</span>
450 <span class="cpp">true</span>
451 </span>
452 </xsl:when>
453 <xsl:when test="@langword='false' or @langword='False'">
454 <span class="languageSpecificText">
455 <span class="cs">false</span>
456 <span class="vb">False</span>
457 <span class="cpp">false</span>
458 </span>
459 </xsl:when>
460 <xsl:when test="@langword='abstract'">
461 <span class="languageSpecificText">
462 <span class="cs">abstract</span>
463 <span class="vb">MustInherit</span>
464 <span class="cpp">abstract</span>
465 </span>
466 </xsl:when>
467 <xsl:otherwise>
468 <xsl:value-of select="@langword" />
469 </xsl:otherwise>
470 </xsl:choose>
471 </span>
472 <xsl:choose>
473 <xsl:when test="@langword='null' or @langword='Nothing' or @langword='nullptr'">
474 <span class="nu"><include item="nullKeyword"/></span>
475 </xsl:when>
476 <xsl:when test="@langword='static' or @langword='Shared'">
477 <span class="nu"><include item="staticKeyword"/></span>
478 </xsl:when>
479 <xsl:when test="@langword='virtual' or @langword='Overridable'">
480 <span class="nu"><include item="virtualKeyword"/></span>
481 </xsl:when>
482 <xsl:when test="@langword='true' or @langword='True'">
483 <span class="nu"><include item="trueKeyword"/></span>
484 </xsl:when>
485 <xsl:when test="@langword='false' or @langword='False'">
486 <span class="nu"><include item="falseKeyword"/></span>
487 </xsl:when>
488 <xsl:when test="@langword='abstract'">
489 <span class="nu"><include item="abstractKeyword"/></span>
490 </xsl:when>
491 </xsl:choose>
492
493 </xsl:template>
494
495 <xsl:template match="seealso">
496 <xsl:param name="displaySeeAlso" select="false()" />
497 <xsl:if test="$displaySeeAlso">
498 <xsl:choose>
499 <xsl:when test="normalize-space(.)">
500 <referenceLink target="{@cref}" qualified="true">
501 <xsl:value-of select="." />
502 </referenceLink>
503 </xsl:when>
504 <xsl:otherwise>
505 <referenceLink target="{@cref}" qualified="true" />
506 </xsl:otherwise>
507 </xsl:choose>
508 </xsl:if>
509 </xsl:template>
510
511 <xsl:template match="c">
512 <span class="code"><xsl:apply-templates/></span>
513 </xsl:template>
514
515 <xsl:template match="paramref">
516 <span class="parameter">
517 <xsl:value-of select="@name" />
518 </span>
519 </xsl:template>
520
521 <xsl:template match="typeparamref">
522 <span class="typeparameter">
523 <xsl:value-of select="@name" />
524 </span>
525 </xsl:template>
526
527 <xsl:template match="syntax">
528 <xsl:if test="count(*) > 0">
529 <xsl:call-template name="section">
530 <xsl:with-param name="toggleSwitch" select="'syntax'" />
531 <xsl:with-param name="title">
532 <include item="syntaxTitle"/>
533 </xsl:with-param>
534 <xsl:with-param name="content">
535 <div id="syntaxCodeBlocks" class="code">
536 <xsl:call-template name="syntaxBlocks" />
537 </div>
538 <!-- parameters & return value -->
539 <xsl:apply-templates select="/document/reference/parameters" />
540 <xsl:apply-templates select="/document/reference/templates" />
541 <xsl:apply-templates select="/document/comments/value" />
542 <xsl:apply-templates select="/document/comments/returns" />
543 <xsl:apply-templates select="/document/reference/implements" />
544 </xsl:with-param>
545 </xsl:call-template>
546 </xsl:if>
547 </xsl:template>
548
549 <xsl:template name="runningHeader">
550 <include item="runningHeaderText" />
551 </xsl:template>
552
553 <!-- pass through html tags -->
554
555 <xsl:template match="p|ol|ul|li|dl|dt|dd|table|tr|th|td|a|img|b|i|strong|em|del|sub|sup|br|hr|h1|h2|h3|h4|h5|h6|pre|div|span|blockquote|abbr|acronym|u|font|map|area">
556 <xsl:copy>
557 <xsl:copy-of select="@*" />
558 <xsl:apply-templates />
559 </xsl:copy>
560 </xsl:template>
561
562 <!-- extra tag support -->
563
564 <xsl:template match="threadsafety">
565 <xsl:call-template name="section">
566 <xsl:with-param name="toggleSwitch" select="'threadSafety'" />
567 <xsl:with-param name="title">
568 <include item="threadSafetyTitle" />
569 </xsl:with-param>
570 <xsl:with-param name="content">
571 <xsl:choose>
572 <xsl:when test="normalize-space(.)">
573 <xsl:apply-templates />
574 </xsl:when>
575 <xsl:otherwise>
576 <xsl:if test="@static='true'">
577 <include item="staticThreadSafe" />
578 </xsl:if>
579 <xsl:if test="@static='false'">
580 <include item="staticNotThreadSafe" />
581 </xsl:if>
582 <xsl:if test="@instance='true'">
583 <include item="instanceThreadSafe" />
584 </xsl:if>
585 <xsl:if test="@instance='false'">
586 <include item="instanceNotThreadSafe" />
587 </xsl:if>
588 </xsl:otherwise>
589 </xsl:choose>
590 </xsl:with-param>
591 </xsl:call-template>
592 </xsl:template>
593
594 <xsl:template match="note">
595 <div class="alert">
596 <img>
597 <includeAttribute item="iconPath" name="src">
598 <parameter>alert_note.gif</parameter>
599 </includeAttribute>
600 <includeAttribute name="title" item="noteAltText" />
601 </img>
602 <xsl:text> </xsl:text>
603 <include item="noteTitle" />
604 <xsl:apply-templates />
605 </div>
606 </xsl:template>
607
608 <xsl:template match="preliminary">
609 <div class="preliminary">
610 <include item="preliminaryText" />
611 </div>
612 </xsl:template>
613
614 <!-- move these off into a shared file -->
615
616 <xsl:template name="createReferenceLink">
617 <xsl:param name="id" />
618 <xsl:param name="qualified" select="false()" />
619
620 <referenceLink target="{$id}" qualified="{$qualified}" />
621
622 </xsl:template>
623
624 <xsl:template name="section">
625 <xsl:param name="toggleSwitch" />
626 <xsl:param name="title" />
627 <xsl:param name="content" />
628
629 <xsl:variable name="toggleTitle" select="concat($toggleSwitch,'Toggle')" />
630 <xsl:variable name="toggleSection" select="concat($toggleSwitch,'Section')" />
631
632 <h1 class="heading">
633 <span onclick="ExpandCollapse({$toggleTitle})" style="cursor:default;" onkeypress="ExpandCollapse_CheckKey({$toggleTitle}, event)" tabindex="0">
634 <img id="{$toggleTitle}" class="toggle" name="toggleSwitch">
635 <includeAttribute name="src" item="iconPath">
636 <parameter>collapse_all.gif</parameter>
637 </includeAttribute>
638 </img>
639 <xsl:copy-of select="$title" />
640 </span>
641 </h1>
642
643 <div id="{$toggleSection}" class="section" name="collapseableSection" style="">
644 <xsl:copy-of select="$content" />
645 </div>
646
647 </xsl:template>
648
649 <xsl:template name="subSection">
650 <xsl:param name="title" />
651 <xsl:param name="content" />
652
653 <h4 class="subHeading">
654 <xsl:copy-of select="$title" />
655 </h4>
656 <xsl:copy-of select="$content" />
657
658 </xsl:template>
659
660 <xsl:template name="memberIntro">
661 <xsl:if test="$subgroup='members'">
662 <p>
663 <xsl:apply-templates select="/document/reference/containers/summary"/>
664 </p>
665 </xsl:if>
666 <xsl:call-template name="memberIntroBoilerplate"/>
667 </xsl:template>
668
669 <xsl:template name="codelangAttributes">
670 <xsl:call-template name="mshelpCodelangAttributes">
671 <xsl:with-param name="snippets" select="/document/comments/example/code" />
672 </xsl:call-template>
673 </xsl:template>
674
675 <!-- Footer stuff -->
676
677 <xsl:template name="foot">
678 <div id="footer">
679
680 <div class="footerLine">
681 <img width="100%" height="3px">
682 <includeAttribute name="src" item="iconPath">
683 <parameter>footer.gif</parameter>
684 </includeAttribute>
685 <includeAttribute name="title" item="footerImage" />
686 </img>
687 </div>
688
689 <include item="footer">
690 <parameter>
691 <xsl:value-of select="$key"/>
692 </parameter>
693 <parameter>
694 <xsl:call-template name="topicTitlePlain"/>
695 </parameter>
696 <parameter>
697 <xsl:value-of select="/document/metadata/item[@id='PBM_FileVersion']" />
698 </parameter>
699 <parameter>
700 <xsl:value-of select="/document/metadata/attribute[@name='TopicVersion']" />
701 </parameter>
702 </include>
703 </div>
704 </xsl:template>
705</xsl:stylesheet>
Note: See TracBrowser for help on using the repository browser.