<?xml version="1.0" ?>
<mx:Panel xmlns:mx="http://www.adobe.com/2006/mxml"
		  xmlns:pt="gov.va.med.edp.pt.demog.view.*"
		  layout="vertical" headerHeight="4"
		  borderStyle="solid" borderThickness="12" borderColor="#CCCCCC"
		  paddingTop="12" paddingLeft="12" paddingRight="12" paddingBottom="0"
		  implements="mx.managers.IFocusManagerContainer">
	<mx:Script><![CDATA[
import mx.core.Application;
		import gov.va.med.edp.util.AccessibilityTools;
		import gov.va.med.edp.pt.demog.model.PatientSelectVO;
		import gov.va.med.edp.control.ModalDialogEvent;
		import mx.managers.PopUpManager;
		import gov.va.med.edp.pt.demog.IPatientChecksController;
		import gov.va.med.edp.pt.demog.model.PatientChecksModel;

		public static function show(cntrl:IPatientChecksController, ptChecksModel:PatientChecksModel, patient:PatientSelectVO = null, dialogParent:Sprite = null, closeHandler:Function = null, centered:Boolean = false):void {
			var dialog:SelectPatientDialog = createDialog(cntrl, ptChecksModel, patient, dialogParent, closeHandler);
			if (dialogParent != null) {
				dialogParent.dispatchEvent(new ModalDialogEvent(ModalDialogEvent.OPEN, dialog));
			}
			if (!AccessibilityTools.isAccessibilityActive()) { // when accessibility active, we don't use a popup, so popup location is irreleant
				if (dialogParent != null) {
					dialog.validateNow();
					var point:Point = new Point();
					point = dialogParent.localToGlobal(point);
					point.y += dialogParent.height;
					if (centered) {
						point.x -= ((dialog.width - dialogParent.width) / 2);
					}
					if ((point.x + dialog.width) > Application.application.systemManager.screen.width) {
						dialog.x = Application.application.systemManager.screen.width - dialog.width;
					} else {
						dialog.x = point.x;
					}
					dialog.y = point.y;
				} else {
					PopUpManager.centerPopUp(dialog);
				}
			}
		}

		private static function createDialog(cntrl:IPatientChecksController, ptChecksModel:PatientChecksModel, patient:PatientSelectVO, dialogParent:Sprite, closeHandler:Function):SelectPatientDialog {
			var dialog:SelectPatientDialog = null;
			if (AccessibilityTools.isAccessibilityActive()) // no popup when accessibility is active
				dialog = new SelectPatientDialog();
			else
				dialog = SelectPatientDialog(PopUpManager.createPopUp(dialogParent, SelectPatientDialog, true));
			dialog.ptChecksController = cntrl;
			dialog.model = ptChecksModel;
			dialog.dialogParent = dialogParent;
			dialog.closeHandler = closeHandler;
			dialog.patient = patient;
			return dialog;
		}

		private function close(event:SelectPatientEvent):void {
			if (closed) return;
			closed = true;
			if (closeHandler != null) closeHandler(event);
			if (dialogParent != null) dialogParent.dispatchEvent(new ModalDialogEvent(ModalDialogEvent.CLOSE));
			if (!AccessibilityTools.isAccessibilityActive()) PopUpManager.removePopUp(this); // no popup when accessibility is active
		}

		[Bindable]
		public var ptChecksController:IPatientChecksController;

		[Bindable]
		public var model:PatientChecksModel;

		[Bindable]
		public var patient:PatientSelectVO;

		private var dialogParent:Sprite;
		private var closeHandler:Function;
		private var closed:Boolean = false;

		]]></mx:Script>
	<pt:SelectPatientPanel model="{model}" ptChecksController="{ptChecksController}"
						   cancel="close(event)" selectPatient="close(event)" initialPatient="{patient}"/>
</mx:Panel>