<?xml version="1.0" encoding="utf-8"?>
<mx:Canvas
	xmlns:mx="http://www.adobe.com/2006/mxml"
	xmlns:widget="gov.va.med.edp.widget.*"
	width="195"
	horizontalScrollPolicy="off" verticalScrollPolicy="off" tabChildren="true" focusEnabled="false" creationComplete="layoutControls()">
	
	<mx:Metadata>
		[Event(name="change", type="mx.events.CalendarLayoutChangeEvent")]
 		[Event(name=DateTimeEvent.EVENT_DATE_TIME, type="gov.va.med.edp.control.DateTimeEvent")]
 	</mx:Metadata>  	

	<mx:Script>
	<![CDATA[
		import mx.events.CalendarLayoutChangeEvent;
		import gov.va.med.edp.control.DateTimeEvent;
		import gov.va.med.edp.control.DateTimeEvent;
		import gov.va.med.edp.control.DateTimeEvent;
		import mx.binding.utils.BindingUtils;
		import gov.va.med.edp.control.DateTimeEvent;
		import gov.va.med.edp.model.TrackingModelLocator;
		import gov.va.med.edp.util.AccessibilityTools;

        [Bindable]
		public var _selectedDate: Date;
		
		[Bindable]
		private var _tabIndexBase:int = -1;
		
		[Bindable]
		private var _dateType:String = "";		
		
		[Bindable]
		public function set selectedDate(date:Date):void
		{
			dateInput.text = "";
			timeInput.text = "";
			if (date != null){
				dateChooser.selectedDate = date;
				timeChooser.hour = date.getHours();
				timeChooser.minute = date.getMinutes();
				dateInput.text = dateFormatter.format(date);
				timeInput.text = get2DigitTime(date.getHours().toString()) + ":" + get2DigitTime(date.getMinutes().toString());
			} else {
				dateChooser.selectedDate = null;
				timeChooser.hour = 00;
				timeChooser.minute = 00;
			}		
		} 
		public function get selectedDate():Date
		{
			return this._selectedDate;
		} 
		
        private function get2DigitTime(time:String):String {
        	if (time.length == 1) return "0" + time;
        	return time;
        }		
        
        private function layoutControls():void {
        	if (AccessibilityTools.isAccessibilityActive()){
        		textControlsBox.visible = true;
        		calendarControlsBox.visible = false;  
           	} else {
        		textControlsBox.visible = false;
        		calendarControlsBox.visible = true;        	
        	}
        }			
			
		private function fireEventFromCalendarControls(event: Event): void
		{
			if (dateChooser.selectedDate == null){
				this._selectedDate = null;
				return;
			}
				
			var hours:int = timeChooser.hour;
			var minutes:int = timeChooser.minute;
            var year:int = dateChooser.selectedDate.fullYear;
			var month:int  = dateChooser.selectedDate.month;
			var date:int = dateChooser.selectedDate.date;

			var dateTime:Date = new Date(year,month, date,hours,minutes);
			this._selectedDate = dateTime;

			var dateTimeEvent:DateTimeEvent = new DateTimeEvent(DateTimeEvent.EVENT_DATE_TIME);
			dateTimeEvent.dateTime = dateTime;
			dispatchEvent(dateTimeEvent);

			var chgEvent: CalendarLayoutChangeEvent =
				new CalendarLayoutChangeEvent(CalendarLayoutChangeEvent.CHANGE);
			chgEvent.newDate = dateTime;
			dispatchEvent(chgEvent);
		}

		private function fireEventFromTextControls(event: Event): void
		{
			var isValid:Boolean = false;
		
			if (event.currentTarget.id == "dateInput"){
				isValid = isDateValid(dateInput.text);			
			}

			if (event.currentTarget.id == "timeInput"){
				isValid = isTimeValid(timeInput.text);			
			}			
			
			if (!isValid){
				this._selectedDate = null;
				return;
			}
		
	     	var date:Array = dateInput.text.split("/");
			var time:Array = timeInput.text.split(":");	
			var hours:int = parseInt(time[0]);
			var minutes:int = parseInt(time[1]);
            //var year:int = parseInt(date[2]);
            var year:int = formatYear(date[2]);
			var month:int  = parseInt(date[0]);
			var day:int = parseInt(date[1]);
		    var dateTime:Date = new Date(year,month-1,day,hours,minutes);
			
			this._selectedDate = dateTime;
		    dateInput.text = DateField.dateToString(dateTime, "MM/DD/YYYY");
		
			var dateTimeEvent:DateTimeEvent = new DateTimeEvent(DateTimeEvent.EVENT_DATE_TIME);
			dateTimeEvent.dateTime = dateTime;
			dispatchEvent(dateTimeEvent);
			
			var chgEvent: CalendarLayoutChangeEvent =
				new CalendarLayoutChangeEvent(CalendarLayoutChangeEvent.CHANGE);
			chgEvent.newDate = dateTime;
			dispatchEvent(chgEvent);
			
		}
        
        // added by jtorreno 08/17/2008
        // formats year according to the length of the string and its value
        // Formatting is based on the autoformatting algorithm of the datechooser field in flex
        // This is implemented if accessibility is enabled
        private function formatYear(yearStr: String): int
        {
        	var newYear:int = 1900;
        	var yearLen:int = 0;
        	var year:int = 0;
        	
        	if (yearStr != null)
        	{
        		yearLen = yearStr.length;
        		year = parseInt(yearStr);
        	}
        	
        	if ((yearLen > 0) && (yearLen <=3))
        	{
	        	if ((year > 0) && (year < 70) && (yearLen == 2))
			    {
			     	newYear = year + 2000;
			    } else { 	 
			     	if (((year >= 70) && (year <= 99) && (yearLen == 1)) ||
			     	    ((year <= 99) && (yearLen == 3)))
			     	{    
			     	   newYear = year + 1900;
			     	} else {
			     		newYear = year;
			     	}  
			     }
	        } else {
	        	newYear = year;
	        }
	        	
        	return newYear
        }
        
        // modified by jtorreno 8/17/2008
        // changed some rules to allow date formatting
		private function isDateValid(dateString: String): Boolean
		{
			var isValid:Boolean = false;
				
			// minimum and maximum length of string that can be entered
			if ((dateString.length >= 5) &&  (dateString.length <= 10))
			{
			    var date:Array = dateString.split("/");
				// checks if array is composed of 3 fields ( Month, Day , Year)
				if (date.length == 3)
				{
					var monthStr:String  = date[0];
					var dayStr:String = date[1];				
            		var yearStr:String = date[2];
                    
                    // checks string length of month, day, year for validity        		
            		if ((monthStr.length > 0) && (monthStr.length <= 2) 
            		    && (dayStr.length > 0) && (dayStr.length <= 2) 
            		    && (yearStr.length > 0) && (yearStr.length <= 4))
            		{
            			var year:Number = parseInt(yearStr);
						var month:Number  = parseInt(monthStr);
						var day:Number = parseInt(dayStr);
					
						if (isNaN(year) || isNaN(month) || isNaN(day)){
							isValid = false;
						} else 
						     {
								if (month > 0 && month < 13){
									if (day > 0 && day < 32){
										isValid = true;
									}
								}     
            			     }
            		 }
                }		
			}
						
			return isValid;
		}
		
		//added by jtorreno 08/17/2008
		// resets time text if it is left blank 
		private function resetTimeText(event:Event):void
		{
			if (event.currentTarget.id == "timeInput"){
			    if ((timeInput.text == null) || (timeInput.text.length == 0)) 
			    {
			    	timeInput.text = "00:00"
			    }
						
			}	
		}

		private function isTimeValid(timeString: String): Boolean
		{
			var isValid:Boolean = false;
				if (timeString.length == 5){
					var time:Array = timeString.split(":");
					var hourStr:String  = time[0];
					var minStr:String = time[1];				
            		if (hourStr.length == 2 && minStr.length == 2){
            			var hour:Number = parseInt(hourStr);
						var min:Number  = parseInt(minStr);
						if (isNaN(hour) || isNaN(min)){
							isValid = false;
						} else {
								if (hour > -1 && hour < 24){
									if (min > -1 && min < 60){
										isValid = true;
									}
								}     
            				}
            			}
				}			
			return isValid;
		}

		private function setAccessibilityPropertiesForDateInput(): void {
			AccessibilityTools.accessComponentName(dateInput, "Date");
			AccessibilityTools.accessComponentDescription(dateInput, "Enter " + _dateType + "date as MM/DD/YYYY.");
			
		}
		
		private function setAccessibilityPropertiesForTimeInput(): void {
			AccessibilityTools.accessComponentName(timeInput,"Time");
			AccessibilityTools.accessComponentDescription(timeInput,"Enter " + _dateType + "time in military time format as HH:MM");
		}		

        public function set tabIndexBase(value:int):void {
        	_tabIndexBase = value;
        }

        public function get tabIndexBase():int {
            return _tabIndexBase;
        }
        
        public function set dateType(value:String):void {
        	_dateType = value;
        }

        public function get dateType():String {
            return _dateType;
        }        
	]]>
	
    </mx:Script>
    
    
    <mx:HBox id="calendarControlsBox" width="100%" height="100%" x="0" y="0" visible="true">
		<mx:DateField 
			id="dateChooser"
			initialize="{AccessibilityTools.accessComponentName(dateChooser,'Date Chooser')}"
			yearNavigationEnabled="true" 
			editable="{AccessibilityTools.setToFalseIfAccessToolIsActive()}" 
			change="{fireEventFromCalendarControls(event)}" 
			width="110"
			tabIndex="{_tabIndexBase}"/>
		<widget:TimeEntry 
			id="timeChooser"
			initialize="{AccessibilityTools.accessComponentName(timeChooser,'Time Chooser')}"
			showSeconds="false" 
			is24Hour="true" 
	        backgroundColor="white" 
	        borderThickness="1" 
	        borderStyle="solid"
	        cornerRadius="5" 
	        keyDown="{fireEventFromCalendarControls(event)}" 
	        click="{fireEventFromCalendarControls(event)}"
	        tabIndexBase="{_tabIndexBase + 1}"/>    
    </mx:HBox>

    <mx:HBox id="textControlsBox" width="100%" height="100%" x="0" y="0">
		<mx:TextInput id="dateInput"
		restrict="0123456789/" 
		toolTip="date (MM/DD/YYYY)"
		tabIndex="{_tabIndexBase}"
		focusOut="fireEventFromTextControls(event)"
		initialize="setAccessibilityPropertiesForDateInput()"
		width="90"/>
		<mx:TextInput id="timeInput" 
		text="00:00"
		toolTip="time (HH:MM)"
		restrict="0123456789:"
		tabIndex="{_tabIndexBase + 1}"
		change="fireEventFromTextControls(event)"	
		initialize="setAccessibilityPropertiesForTimeInput()"
		width="60"/>
    </mx:HBox>  

	<mx:DateValidator source="{dateChooser}" property="text" required="true" />
	<mx:DateValidator source="{dateInput}" property="text" required="true" />
	<mx:StringValidator source="{timeInput}" property="text" required="true" />	
 	<mx:DateFormatter id="dateFormatter" formatString="MM/DD/YYYY" />
 </mx:Canvas>