<?xml version="1.0" encoding="utf-8"?>
<!-- BigBoard.mxml -->

<mx:Application
        xmlns:mx="http://www.adobe.com/2006/mxml"
        xmlns:control="gov.va.med.edp.control.*"
        xmlns:business="gov.va.med.edp.business.*"
        xmlns:view="gov.va.med.edp.view.*"
        xmlns:log="gov.va.med.edp.view.log.*"
        pageTitle="Tracking Display Board"
        height="100%"
        width="100%"
        paddingLeft="0" paddingRight="0" paddingBottom="0"
        paddingTop="6"
        creationComplete="initApp()" xmlns:board="gov.va.med.edp.view.board.*">

    <mx:Style source="edp.css"/>

    <mx:Script>
	<![CDATA[
        import flash.utils.Timer;
        import flash.events.TimerEvent;
        import mx.managers.SystemManager;
        import mx.core.Container;
        import mx.utils.URLUtil;
        import com.adobe.cairngorm.control.CairngormEventDispatcher;
        import com.adobe.cairngorm.control.CairngormEvent;
        import gov.va.med.edp.model.TrackingModelLocator;
        import gov.va.med.edp.control.InitAppEvent;
        import gov.va.med.edp.util.InactivityTimeout;
        import com.adobe.cairngorm.business.ServiceLocator;
        import gov.va.med.edp.business.Services;

        public static const VERSION_INCOMPATIBILITY_RELOAD_COUNTDOWN:int = 10;

        [Bindable]
        public var model:TrackingModelLocator = TrackingModelLocator.getInstance();

        [Bindable]
        private var inactivityTimeout:InactivityTimeout = new InactivityTimeout();

        private var reloadTimer : Timer;
        private var digitalClockTimer:Timer;

        private function initApp():void
        {

            var e: InitAppEvent = new InitAppEvent(InitAppEvent.EVENT_INIT_APP);
            e.appName = TrackingModelLocator.APP_NAME_BIGBOARD;
            e.contextRoot = Application.application.parameters.contextRoot;
            e.helpContextRoot = Application.application.parameters.helpContextRoot;
            e.protocol = URLUtil.getProtocol(Application.application.url);
            if (e.protocol == "file") e.protocol = "http";

            // first check the vljServ parameter
            if (Application.application.parameters.hasOwnProperty("vljServ")) {
                e.server = Application.application.parameters.vljServ;
                e.mode = InitAppEvent.SERVICE_USE_VLJ;
            }
            if (Application.application.parameters.hasOwnProperty("timeout")) {
                e.timeout = new Boolean(Application.application.parameters.timeout);
            }
            if (Application.application.parameters.hasOwnProperty("siteId")) {
                e.siteId = Application.application.parameters.siteId;
            }
            if (Application.application.parameters.hasOwnProperty("area")) {
                e.areaName = Application.application.parameters.area;
            }


            // then check the cspServ parameter
            if ((e.server.length == 0) && Application.application.parameters.hasOwnProperty("cspServ")) {
                e.server = Application.application.parameters.cspServ;
                e.mode = InitAppEvent.SERVICE_USE_CSP;
                e.token = Application.application.parameters.cspToken;
            }
            // if running in development mode try localhost
            if ((e.server.length == 0) && (Application.application.url.substr(0, 7) == "file://")) {
                e.server = "localhost:7001";
                e.mode = InitAppEvent.SERVICE_USE_VLJ;
            }
            // default:  use the server and port of the HTML wrapper with VLJ
            if (e.server.length == 0) {
                e.server = URLUtil.getServerNameWithPort(Application.application.url);
                e.mode = InitAppEvent.SERVICE_USE_VLJ;
            }
            e.dispatch();

            Application.application.pageTitle = "Tracking System: " + e.server;
            //set up the digital clock
            digitalClockTimer = new Timer(1000);
            digitalClockTimer.addEventListener(TimerEvent.TIMER, resetClock);
            digitalClockTimer.start();
        }

        private function resetClock(event:TimerEvent):void {
            //currentMemoryLbl.text = "Total Flash Player Memory (bytes): " + System.totalMemory ;
            var clockDate:Date = new Date();
            currentDateLbl.text = clockDate.toLocaleDateString() + ", " + clockDate.toLocaleTimeString();
        }

        private function getView(view:Number): Container
        {
            switch (view) {
                case TrackingModelLocator.VIEW_APP_INTRO: return introView;
                case TrackingModelLocator.VIEW_APP_VERSION_INCOMPATIBILITY: return versionIncompatibilityView;
                case TrackingModelLocator.VIEW_APP_DISPLAY_BOARD: return bigBoard;
                default: return noneView;
            }
        }

        [Bindable(event="secondsUntilReloadChanged")]
        public function get secondsUntilReload():int {
            if (reloadTimer == null)
                return VERSION_INCOMPATIBILITY_RELOAD_COUNTDOWN;
            else
                return reloadTimer.repeatCount - reloadTimer.currentCount;
        }

        private function updateSecondsUntilReload(e:TimerEvent):void {
            dispatchEvent(new Event("secondsUntilReloadChanged"));
        }

        private function startTimer(): void {
            if (reloadTimer == null) {
                reloadTimer = new Timer(1000, VERSION_INCOMPATIBILITY_RELOAD_COUNTDOWN);
                reloadTimer.addEventListener(TimerEvent.TIMER, updateSecondsUntilReload);
                reloadTimer.addEventListener(TimerEvent.TIMER_COMPLETE, reloadApp);
            }
            reloadTimer.reset();
            reloadTimer.start();
        }

        private function reloadApp(e:TimerEvent):void {
            model.logout();
        }

        private function set initSessionTimeout(value: uint):void
        {
            if (Application.application.parameters.hasOwnProperty("timeout")) {
                var timeoutEnabled: Boolean = new Boolean(Application.application.parameters.timeout);
                if (timeoutEnabled) inactivityTimeout.start();
            }
            
        }

        public function set workingStatus(bText:String):void
        {
            if (bText.length > 0) {
                currentState = 'sessionTimeOutState';
                lblWorkingStatus.text = bText;
            } else {
                currentState = "";
                lblWorkingStatus.text = "";
            }
        }
        
		private function set addDebugTooltip(value: Boolean): void
		{        
            var debugStr: String = "EDIS Version=" + model.appClientVersion + "\n";
            if (model.bigboardInfo != null && value){
                 if (model.bigboardInfo.bigBoardSiteCode.length > 0 && model.bigboardInfo.bigBoardSiteCode != "null")debugStr = debugStr + "Site=" + model.bigboardInfo.bigBoardSiteCode + "\n";
                 if (model.bigboardInfo.bigBoardMachineName.length > 0 && model.bigboardInfo.bigBoardMachineName != "null")debugStr = debugStr + "Machine=" + model.bigboardInfo.bigBoardMachineName + "\n";
                 if (model.bigboardInfo.vistaLinkIPAddress.length > 0 && model.bigboardInfo.vistaLinkIPAddress != "null")debugStr = debugStr + "Vistalink-IPAddress=" + model.bigboardInfo.vistaLinkIPAddress + "\n";
                 if (model.bigboardInfo.vistaLinkPort.length > 0 && model.bigboardInfo.vistaLinkPort != "null")debugStr = debugStr + "Vistalink-Port=" + model.bigboardInfo.vistaLinkPort + "\n";
            }
            currentDateLbl.toolTip = debugStr;            			
		}
        
            

                
	]]>
    </mx:Script>

    <!-- ========================================================================== -->

    <!-- the ServiceLocator where we specify the remote services -->
    <business:Services id="services"/>

    <!-- the FrontController, containing Commands specific to this appliation -->
    <control:TrackingController id="controller"/>

    <!-- ========================================================================== -->

    <mx:ViewStack
            id="appView"
            width="100%"
            height="100%"
            selectedChild="{getView(model.appViewState)}">

        <mx:TitleWindow id="introView" title="Emergency Department Integration Software"/>
        <mx:Canvas id="noneView">
            <mx:Label horizontalCenter="0" verticalCenter="0" text="No Views Configured"/>
        </mx:Canvas>
        <mx:Canvas id="versionIncompatibilityView" show="startTimer()">
            <mx:Panel title="EDIS Version Incompatibility"
                      paddingTop="10" paddingLeft="10" paddingRight="10" horizontalCenter="0" verticalCenter="0"
                      width="75%">
                <mx:Text width="100%">
                    <mx:text>
                        This is EDIS board version '{model.appClientVersion}'.
                        The EDIS server package version running in your VistA account is
                        '{model.session.serverPackageVersion}'.
                        It appears that the web server has served the wrong version of the board for your configuration.
                        Will attempt to load version '{model.session.serverPackageVersion}' of the board in
                        {secondsUntilReload} seconds.
                    </mx:text>
                </mx:Text>
            </mx:Panel>
        </mx:Canvas>
        <board:BigDisplayBoard id="bigBoard"/>
    </mx:ViewStack>
    <mx:HBox width="100%">
        <mx:Label id="currentDateLbl" fontSize="10" width="100%" textAlign="center" fontWeight="bold"/>
<!--        <mx:Label id="currentMemoryLbl" fontSize="10" width="100%" textAlign="center" fontWeight="bold"/> --> 
    </mx:HBox>
    <mx:states>
        <mx:State name="sessionTimeOutState">
            <mx:AddChild relativeTo="{appView}" position="before">
                <mx:target>
                     <mx:VBox id="disconnectedBoardPanel" width="100%">
                        <mx:ApplicationControlBar paddingBottom="0" paddingTop="0" dock="true" width="100%" fillColors="[#FF0000,#BF0000]" fillAlphas="[0.8,0.8]">
                            <mx:Text id="lblWorkingStatus" horizontalCenter="0" verticalCenter="0"
                                     textAlign="center" width="100%" height="100%" color="white" fontSize="{model.boardSpec.displayBoardProperties.fontSize}"/>
                        </mx:ApplicationControlBar>
                    </mx:VBox>
                </mx:target>
            </mx:AddChild>
        </mx:State>
    </mx:states>
    <mx:Binding source="model.session.timeOut" destination="initSessionTimeout"/>
    <mx:Binding source="inactivityTimeout.status" destination="workingStatus"/>
	<mx:Binding source="model.boardSpec.specReady" destination="addDebugTooltip"/>
    
</mx:Application>