source: EDIS/trunk/java/tracking-ui-core/src/main/flex/gov/va/med/edp/widget/StatusRenderer.mxml@ 1227

<?xml version="1.0" encoding="utf-8"?>
<mx:Label
        xmlns:mx="http://www.adobe.com/2006/mxml">

        <mx:Script>
                <![CDATA[
            import mx.controls.listClasses.ListBase;
            import mx.controls.dataGridClasses.DataGridListData;
                        import gov.va.med.edp.model.TrackingModelLocator;
                        import gov.va.med.edp.vo.LookupVO;
                        import gov.va.med.edp.util.Vista;

                        private var model: TrackingModelLocator = TrackingModelLocator.getInstance();
                        private var _data: Object;
                
                        override public function set data(value: Object): void {
                                _data = value;
                                if (value == null) return;

                                var status: Number = value[DataGridListData(listData).dataField];
                                var i: int = Vista.locateIndex(model.config.statusList, status);
                                if (i > -1) {
                                        this.text = LookupVO(model.config.statusList[i]).label;
                                } else {
                                        this.text = "";
                                }
                        }
                        
                        override public function get data(): Object {
                                return _data;
                        }

            override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
            {
                super.updateDisplayList(unscaledWidth, unscaledHeight);

                if(owner is mx.controls.DataGrid && mx.controls.DataGrid(owner).isItemSelected(data)) { //figure out if this itemRenderer is selected
                    setStyle('color', 0xFFFFFF);  // FIXME: anyway to discover this value from the theme?
                } else { //otherwise, return the label to its regular state
                    setStyle('color', 0x000000); // FIXME: anyway to discover this value from the theme?
                }
            }
                ]]>
    </mx:Script>

</mx:Label>