source: EDIS/trunk/java/tracking-ui-core/src/main/flex/gov/va/med/edp/widget/ValueComboBox.mxml@ 1227

<?xml version="1.0" encoding="utf-8"?>
<!-- ValueComboBox.mxml
         allows value property to be settable
         based on "Rich Internet Applications with Adobe Flex and Java" page 319
-->

<mx:ComboBox xmlns:mx="http://www.adobe.com/2006/mxml">
        <mx:Script>
        <![CDATA[
            public var dataField: String = "data";
            
                private var candidateValue: Object;
            private var valueDirty: Boolean = false;
            private var candidateDataProvider: Object;
            private var dataProviderDirty: Boolean = false;
                
                [Bindable("change")]
                [Bindable("valueCommit")]
                [Inspectable(defaultValue="0", category="General", verbose="1")]
                override public function get value():Object
                {
                        var item: Object = selectedItem;
                        if ((item == null) || (typeof(item) != "object")) return item;
                        return item[dataField] ? item[dataField] : item.label;
                }
                
                public function set value(val:Object)  : void
                {
                candidateValue = val;
                        valueDirty = true;              
                        invalidateProperties();
                }
                
            private function applyValue(val:Object):void
            {
                if ((val != null) && (dataProvider != null)) {
                                for (var i : int = 0; i < dataProvider.length; i++) {
                                        if (dataProvider[i] == null) continue;
                                        
                                        // only checking dataField to avoid accidental selection
                                        // (could also check labelField, but not needed for ED app)
                                        if (val == dataProvider[i][dataField]) {
                                                selectedIndex = i; 
                                return;
                        }
                                }
                        }
                selectedIndex = -1;
                }       
        
                override public function set dataProvider(value:Object):void
                {
                        candidateDataProvider = value;
                        dataProviderDirty = true;
                        invalidateProperties();
                }
        
                override protected function commitProperties():void
                {
                        super.commitProperties();
                        
                        if (dataProviderDirty)  {
                        super.dataProvider = candidateDataProvider;
                        dataProviderDirty = false;
                        }
                        
                        if (valueDirty) {
                        applyValue(candidateValue);
                        valueDirty = false;
                        }                       
                }               
        ]]>
        </mx:Script>
</mx:ComboBox>