<?xml version="1.0" encoding="utf-8"?>
<!--tracking.mxml -->

<mx:Application
		xmlns:mx="http://www.adobe.com/2006/mxml"
		xmlns:control="gov.va.med.edp.control.*"
		xmlns:business="gov.va.med.edp.business.*"
		xmlns:view="gov.va.med.edp.view.*"
		xmlns:log="gov.va.med.edp.view.log.*"
		pageTitle="Patient Tracking"
		height="100%" width="100%" frameRate="100"
		paddingLeft="0" paddingRight="0" paddingBottom="0" paddingTop="6"
		creationComplete="initApp()" xmlns:debug="gov.va.med.edp.view.debug.*"
		initialize="callJSmaxBrowser();">

	<mx:Style source="edp.css"/>

	<mx:Script>
	<![CDATA[
import mx.managers.FocusManager;
import mx.managers.IFocusManagerContainer;
		import mx.accessibility.ButtonAccImpl;
		import gov.va.med.edp.widget.LinkButtonTab;
		import gov.va.med.edp.util.AccessibilityTools;
		import gov.va.med.edp.control.ModalDialogEvent;
		import flash.utils.getTimer;
		import gov.va.med.edp.control.ClearUnsavedViewsModelEvent;
		import mx.binding.utils.ChangeWatcher;
		import mx.core.Container;
		import mx.utils.URLUtil;
		import com.adobe.cairngorm.control.CairngormEventDispatcher;
		import com.adobe.cairngorm.control.CairngormEvent;
		import gov.va.med.edp.model.TrackingModelLocator;
		import gov.va.med.edp.control.InitAppEvent;
		import gov.va.med.edp.control.SwitchAppViewEvent;
		import gov.va.med.edp.control.TrackingEvent;
		import com.adobe.cairngorm.business.ServiceLocator;
		import gov.va.med.edp.business.Services;
		import gov.va.med.edp.vo.LookupVO;
		import gov.va.med.edp.util.InactivityTimeout;
		import gov.va.med.edp.view.DisconnectedDialog;
		import gov.va.med.edp.widget.InfoDialog;

		[Bindable]
		public var model:TrackingModelLocator = TrackingModelLocator.getInstance();

		[Bindable]
		private var inactivityTimeout:InactivityTimeout = new InactivityTimeout();

		private var modalCount: int = 0;

		/**
		 *  Function: callJSmaxBrowser()
		 *  Parameters:
		 *			  NA
		 *  Description:
		 *	 Calls external javascript to maximize browser and makescreen
		 *	 component visible if screen reader is activated
		 *
		 *  Created by: jtorreno
		 *
		 *  Date: 2008.05.12
		 *
		 **/
		private function callJSmaxBrowser():void {
			trace("** Is screen reader active: " + AccessibilityTools.isAccessibilityActive());

			if (AccessibilityTools.isAccessibilityActive()) {
				trace("** Calls external javascript to maximize browser and " +
					  "makescreen component visible")
				ExternalInterface.call("maximizeBrowser");
			}
		}


		private function initApp():void
		{
			ChangeWatcher.watch(model, "disconnected", connectionStatusChanged);
			model.reconnectFunction = reconnect;

			var e: InitAppEvent = new InitAppEvent(InitAppEvent.EVENT_INIT_APP);
			e.appName = TrackingModelLocator.APP_NAME_TRACKING;
			e.contextRoot = Application.application.parameters.contextRoot;
			e.helpContextRoot = Application.application.parameters.helpContextRoot;
			e.protocol = URLUtil.getProtocol(Application.application.url);
			if (e.protocol == "file") e.protocol = "http";

			// first check the vljServ parameter
			if (Application.application.parameters.hasOwnProperty("vljServ")) {
				e.server = Application.application.parameters.vljServ;
				e.mode = InitAppEvent.SERVICE_USE_VLJ;
			}
			// then check the cspServ parameter
			if ((e.server.length == 0) && Application.application.parameters.hasOwnProperty("cspServ")) {
				e.server = Application.application.parameters.cspServ;
				e.mode = InitAppEvent.SERVICE_USE_CSP;
				e.token = Application.application.parameters.cspToken;
			}
			// if running in development mode try localhost
			if ((e.server.length == 0) && (Application.application.url.substr(0, 7) == "file://")) {
				e.server = "localhost:7001";
				e.mode = InitAppEvent.SERVICE_USE_VLJ;
			}
			// default:  use the server and port of the HTML wrapper with VLJ
			if (e.server.length == 0) {
				e.server = URLUtil.getServerNameWithPort(Application.application.url);
				e.mode = InitAppEvent.SERVICE_USE_VLJ;
			}
			e.dispatch();

			Application.application.pageTitle = "Tracking System: " + e.server;

			if (AccessibilityTools.isAccessibilityActive()) {
				this.addEventListener(gov.va.med.edp.control.ModalDialogEvent.OPEN, setModalBackground);
				this.addEventListener(gov.va.med.edp.control.ModalDialogEvent.CLOSE, clearModalBackground);
			}

			if (ExternalInterface.available) {
				ExternalInterface.addCallback("getUnsavedDataWarning",
						function(): String {
							var x: String = model.modifiedViews();
							if (x.length > 0) {
								x = "The following views have unsaved changes: \n\n" + x +
									"\nDo you want to continue and lose these changes?";
								return x;
							}
							return "";
						}
						);
			}
		}

		private function connectionStatusChanged(e:Event):void {
			if (model.disconnected)
				DisconnectedDialog.show();
			else
				DisconnectedDialog.hide();
		}

		private function reconnect():void {
			new TrackingEvent(TrackingEvent.EVENT_INIT_TRACKING).dispatch();
		}

		private function proceed(): void {
			var e:SwitchAppViewEvent = new SwitchAppViewEvent(SwitchAppViewEvent.EVENT_SWITCH_APP_VIEW);
			if (model.appViewList.length > 0) {
				e.view = (model.appViewList[0] as LookupVO).data;
			}
			e.dispatch();
		}

		private function getView(view:Number): Container
		{
			if (view == TrackingModelLocator.VIEW_APP_INTRO) {
				return introView;
			} else if (view == TrackingModelLocator.VIEW_APP_VERSION_INCOMPATIBILITY) {
				return versionIncompatibilityView;
			} else {
				return trackingViews;
			}
		}

		private function set initSessionTimeout(value: uint):void
		{
			inactivityTimeout.start();
		}

		public function set workingStatus(bText:String):void
		{
			if (bText.length > 0) {
/* 				if (lblWorkingStatus.text == "") {   // true when starting timeout
					ExternalInterface.call("indicateTimeout");
					trace("done calling indicate timeout");
				} */
				currentState = 'sessionTimeOutState';
				lblWorkingStatus.text = bText;
			} else {
				currentState = "";
				lblWorkingStatus.text = "";
			}
		}

		private function setModalBackground(e: ModalDialogEvent): void
		{
			if (modalCount == 0) {
				if (e.dialogPanel != null) {
//										if (e.dialogPanel is IFocusManagerContainer) {
					//						if (IFocusManagerContainer(e.dialogPanel).focusManager)
					//							e.dialogPanel.systemManager.addFocusManager(IFocusManagerContainer(e.dialogPanel));
					//						else // Popups get their own focus loop
					//							IFocusManagerContainer(e.dialogPanel).focusManager = new FocusManager(IFocusManagerContainer(e.dialogPanel));
					//					}

					e.dialogPanel.setStyle("horizontalCenter", 0);
					e.dialogPanel.setStyle("verticalCenter", 0);
					emptyBackground.addChild(e.dialogPanel);

				}
				appView.selectedChild = emptyBackground;

			}
			modalCount++;
		}

		private function clearModalBackground(e: ModalDialogEvent): void
		{
			modalCount--;
			if (modalCount == 0) {
				
				emptyBackground.removeAllChildren();
				appView.selectedChild = getView(model.appViewState);
				callLater(resetSelectionForJaws);
			}
		}

		private function resetSelectionForJaws(): void
		{
			if (trackingViews != null && trackingViews.appList != null) {

				//            var selectedIndex:int = trackingViews.appList.selectedIndex;
				//            var dispObj:DisplayObject = trackingViews.appList.getChildAt(selectedIndex);
				//		      var lbt:LinkButtonTab = LinkButtonTab(dispObj);
				//			  lbt.setFocus();
				trackingViews.appList.setFocus();
			}
		}
        
		
	]]>
	</mx:Script>

	<!-- ========================================================================== -->

	<!-- the ServiceLocator where we specify the remote services -->
	<business:Services id="services"/>

	<!-- the FrontController, containing Commands specific to this appliation -->
	<control:TrackingController id="controller"/>

	<!-- ========================================================================== -->

	<mx:ViewStack
			id="appView"
			width="100%"
			height="100%"
			selectedChild="{getView(model.appViewState)}">

		<mx:TitleWindow id="introView" title="Emergency Department Integration Software"/>
		<mx:Canvas id="emptyBackground" width="100%" height="100%"/>
		<mx:Canvas id="versionIncompatibilityView">
			<mx:Panel title="EDIS Version Incompatibility"
					  paddingTop="10" paddingLeft="10" paddingRight="10" horizontalCenter="0" verticalCenter="0"
					  width="75%">
				<mx:Text width="100%">
					<mx:text>
						This is EDIS client version '{model.appClientVersion}'.
						The EDIS server package version running in your VistA account is
						'{model.session.serverPackageVersion}'.
						It appears that the web server has served you the wrong version of the user interface for your
						configuration.
					</mx:text>
				</mx:Text>
				<mx:ControlBar horizontalAlign="right">
					<mx:Button label="Proceed (Not Recommended)" click="proceed()"/>
					<mx:Button label="Exit" click="model.logout()"/>
				</mx:ControlBar>
			</mx:Panel>
		</mx:Canvas>
		<view:TrackingViews id="trackingViews"/>
	</mx:ViewStack>

	<mx:states>
		<mx:State name="sessionTimeOutState">
			<mx:AddChild relativeTo="{appView}" position="after">
				<mx:target>
					<mx:Label id="lblWorkingStatus" width="90%" text="" textAlign="center"
							  styleName="sessionTimeoutLabel"/>
				</mx:target>
			</mx:AddChild>
		</mx:State>
	</mx:states>
	<mx:Binding source="model.session.timeOut" destination="initSessionTimeout"/>
	<mx:Binding source="inactivityTimeout.status" destination="workingStatus"/>
</mx:Application>