OOPSCA2 ;WIOFO/CAH-CA2 DISPLAY ;12/02/99
 ;;2.0;ASISTS;;Jun 03, 2002
CA2(IEN,CALL) ;
CA2PG1 N LIN S PG=0,EX="",LIN=$S(($E(IOST,1,2)="C-"):IOSL-2,1:IOSL-6)
 K DIQ,DA,DR
 S DIC="^OOPS(2260,"
 S DR=".01;1;5:12;15;16;17;60:63;70;207:220;223:227;230:265;267:270",DA=IEN,DIQ="OOPS" D EN^DIQ1
 D HDR
 W !,"NAME OF EMPLOYEE...............: ",OOPS(2260,IEN,1) D P Q:EX=U
 W !,"SSN............................: ",OOPS(2260,IEN,5) D P Q:EX=U
 W !,"DOB............................: ",OOPS(2260,IEN,6) D P Q:EX=U
 W !,"SEX............................: ",OOPS(2260,IEN,7) D P Q:EX=U
 W !,"HOME TELEPHONE.................: ",OOPS(2260,IEN,12) D P Q:EX=U
 W !,"GRADE/STEP.....................: ",OOPS(2260,IEN,16) W:OOPS(2260,IEN,16)'="" "/" W OOPS(2260,IEN,17) D P Q:EX=U
 W !,"PAY PLAN.......................: ",OOPS(2260,IEN,63) D P Q:EX=U
 W !,"EMPLOYEE'S ADDRESS.............: ",OOPS(2260,IEN,8) D P Q:EX=U
 W !,"CITY...........................: ",OOPS(2260,IEN,9) D P Q:EX=U
 W !,"STATE..........................: ",OOPS(2260,IEN,10) D P Q:EX=U
 W !,"ZIP............................: ",OOPS(2260,IEN,11) D P Q:EX=U
 W !,"DEPENDENTS.....................: ",OOPS(2260,IEN,207) D P Q:EX=U
 W !,"EMPLOYEE'S OCCUPATION..........: ",OOPS(2260,IEN,208) D P Q:EX=U
 D:$D(OOPS(2260,IEN,209))  Q:EX=U
 .W !,"ILLNESS OCCURRED (LOCATION)....: ",OOPS(2260,IEN,209) D P Q:EX=U
 .W !,"ILLNESS OCCURRED ADDRESS.......: ",OOPS(2260,IEN,210) D P Q:EX=U
 .W !,"ILLNESS OCCURRED CITY..........: ",OOPS(2260,IEN,211) D P Q:EX=U
 .W !,"ILLNESS OCCURRED STATE.........: ",OOPS(2260,IEN,212) D P Q:EX=U
 .W !,"ILLNESS OCCURRED ZIP CODE......: ",OOPS(2260,IEN,213) D P Q:EX=U
 W !,"DATE FIRST AWARE OF ILLNESS....: ",OOPS(2260,IEN,214) D P Q:EX=U
 W !,"DATE FIRST REALIZED CAUSE.......: ",OOPS(2260,IEN,215) D P Q:EX=U
 W !,"RELATIONSHIP OF ILLNESS TO EMP.: "
 S OPFLD=216 D WP K OPFLD Q:EX=U
 W !,"NATURE OF DISEASE/ILLNESS......: "
 S OPFLD=217 D WP K OPFLD Q:EX=U
 W !,"REASON CLAIM NOT FILED.........: "
 S OPFLD=218 D WP K OPFLD Q:EX=U
 W !,"EMPLOYEE STATEMENT DELAY.......: "
 S OPFLD=219 D WP K OPFLD Q:EX=U
 W !,"REASON MEDICAL REPORT DELAYED..: "
 S OPFLD=220 D WP K OPFLD Q:EX=U
 W !,"DATE OF EMPLOYEE SIGNATURE.....: ",OOPS(2260,IEN,223) D P Q:EX=U
 I CALL="E" D  G KILL
 .I $E(IOST,1,2)="C-" W ! K DIR S DIR(0)="E" D ^DIR W @IOF
CA2PG2 ;
 ; Changed from 122 to 15 - Use Occ Code from PAID
 W !,"OCCUPATION CODE................: ",OOPS(2260,IEN,15) D P Q:EX=U
 W !,"NOI CODE.......................: ",OOPS(2260,IEN,62) D P Q:EX=U
 W !,"TYPE CODE......................: ",OOPS(2260,IEN,226) D P Q:EX=U
 W !,"SOURCE CODE....................: ",OOPS(2260,IEN,227) D P Q:EX=U
 W !,"OWCP CHARGEBACK CODE...........: ",OOPS(2260,IEN,70) D P Q:EX=U
 D:$D(OOPS(2260,IEN,230))  Q:EX=U
 .W !,"AGENCY NAME....................: ",OOPS(2260,IEN,230) D P Q:EX=U
 .W !,"AGENCY ADDRESS.................: ",OOPS(2260,IEN,231) D P Q:EX=U
 .W !,"AGENCY CITY....................: ",OOPS(2260,IEN,232) D P Q:EX=U
 .W !,"AGENCY STATE...................: ",OOPS(2260,IEN,233) D P Q:EX=U
 .W !,"AGENCY ZIP CODE................: ",OOPS(2260,IEN,234) D P Q:EX=U
 D:$D(OOPS(2260,IEN,237))  Q:EX=U
 .W !,"EMPLOYEE'S DUTY STATION........: ",OOPS(2260,IEN,237) D P Q:EX=U
 .W !,"DUTY STATION ADDRESS...........: ",OOPS(2260,IEN,238) D P Q:EX=U
 .W !,"DUTY STATION CITY..............: ",OOPS(2260,IEN,239) D P Q:EX=U
 .W !,"DUTY STATION STATE.............: ",OOPS(2260,IEN,240) D P Q:EX=U
 .W !,"DUTY STATION ZIP CODE..........: ",OOPS(2260,IEN,241) D P Q:EX=U
 W !,"REGULAR HRS FROM TIME..........: ",OOPS(2260,IEN,242) D P Q:EX=U
 W !,"REGULAR HRS TO TIME............: ",OOPS(2260,IEN,243) D P Q:EX=U
 W !,"REGULAR WORK SCHEDULE..........: ",OOPS(2260,IEN,244) D P Q:EX=U
 D:$D(OOPS(2260,IEN,245))  Q:EX=U
 .W !,"1ST PROVIDING PHYSICAN NAME....: ",OOPS(2260,IEN,245) D P Q:EX=U
 .W !,"1ST PROVIDING PHYS. ADDRESS....: ",OOPS(2260,IEN,246) D P Q:EX=U
 .W !,"1ST PROVIDING PHYS. CITY.......: ",OOPS(2260,IEN,247) D P Q:EX=U
 .W !,"1ST PROVIDING PHYS. STATE......: ",OOPS(2260,IEN,248) D P Q:EX=U
 .W !,"1ST PROVIDING PHYS. ZIP CODE...: ",OOPS(2260,IEN,249) D P Q:EX=U
 .W !,"1ST PROVIDING PHYS. TITLE......: ",OOPS(2260,IEN,270) D P Q:EX=U
 W !,"FIRST DATE OF MEDICAL CARE.....: ",OOPS(2260,IEN,250) D P Q:EX=U
 W !,"DISABLED FOR WORK..............: ",OOPS(2260,IEN,251) D P Q:EX=U
 W !,"DATE 1ST REPORTED TO SUPERVISOR: ",OOPS(2260,IEN,252) D P Q:EX=U
 W !,"DATE/TIME WORK STOPPED.........: ",OOPS(2260,IEN,253) D P Q:EX=U
 W !,"DATE PAY STOPPED...............: ",OOPS(2260,IEN,254) D P Q:EX=U
 W !,"DATE OF LAST EXPOSURE..........: ",OOPS(2260,IEN,255) D P Q:EX=U
 W !,"DATE/TIME RETURNED TO WORK.....: ",OOPS(2260,IEN,256) D P Q:EX=U
 W !,"WORK DUTY CHANGED..............: "
 S OPFLD=257 D WP K OPFLD Q:EX=U
 W !,"EMPLOYEE RETIREMENT COVERAGE...: ",OOPS(2260,IEN,60) D P Q:EX=U
 I $D(OOPS(2260,IEN,61)) D  Q:EX=U
 . W !,"EMP RETIREMENT COVERAGE DESC.: ",OOPS(2260,IEN,61) D P Q:EX=U
 W !,"INJURY CAUSED BY 3RD PARTY.....: ",OOPS(2260,IEN,258) D P Q:EX=U
 D:$D(OOPS(2260,IEN,259))  Q:EX=U
 .W !,"3RD PARTY NAME.................: ",OOPS(2260,IEN,259) D P Q:EX=U
 .W !,"3RD PARTY ADDRESS..............: ",OOPS(2260,IEN,260) D P Q:EX=U
 .W !,"3RD PARTY CITY.................: ",OOPS(2260,IEN,261) D P Q:EX=U
 .W !,"3RD PARTY STATE................: ",OOPS(2260,IEN,262) D P Q:EX=U
 .W !,"3RD PARTY ZIP CODE.............: ",OOPS(2260,IEN,263) D P Q:EX=U
 W !,"SUPERVISOR EXCEPTION...........: ",OOPS(2260,IEN,264) D P Q:EX=U
 W !,"NAME OF SUPERVISOR.............: ",OOPS(2260,IEN,265) D P Q:EX=U
 W !,"SUPERVISOR'S DATE OF SIGNATURE.: ",OOPS(2260,IEN,267) D P Q:EX=U
 W !,"SUPERVISOR'S TITLE.............: ",OOPS(2260,IEN,268) D P Q:EX=U
 W !,"SUPERVISOR'S OFFICE PHONE......: ",OOPS(2260,IEN,269) D P Q:EX=U
 I $E(IOST,1,2)="C-" W ! K DIR S DIR(0)="E" D ^DIR W @IOF
KILL ;Kill Variables and Exit
 S:$D(ZTQUEUED) ZTREQ="@"
 K DIR,DIROUT,DIRUT,DTOUT,DUOUT,IEN,DASHES,OOPS,DA,DO,EX
 K DO,DIQ,DISYS,DIW,DIWI,DIWT,DIWTC,DIWX,DN,DR,I,Z,POP
 Q
P ;Print
 I ($Y'<(LIN-3)) D  Q:EX=U
 .I $E(IOST,1,2)="C-" W ! K DIR S DIR(0)="E" D ^DIR I 'Y S EX=U Q
 .D HDR Q
 Q
WP ;Process Word Processing Fields
 N DIWL,DIWR,DIWF,OPGLB,OPI,OPNODE,OPT,OPC
 K ^UTILITY($J,"W")
 S DIWL=1,DIWR="",DIWF="|C76"
 S OPNODE=$P($$GET1^DID(2260,OPFLD,"","GLOBAL SUBSCRIPT LOCATION"),";")
 S OPGLB="^OOPS(2260,IEN,OPNODE,OPI)"
 S OPI=0 F  S OPI=$O(@OPGLB) Q:'OPI  S X=$G(^(OPI,0)) D:X]"" ^DIWP
 S OPT=$G(^UTILITY($J,"W",1))+0
 I OPT S OPI=0 F OPC=1:1 S OPI=$O(^UTILITY($J,"W",1,OPI)) Q:'OPI!(EX=U)  D
 .W !?1,^UTILITY($J,"W",1,OPI,0) D P Q:EX=U
 K ^UTILITY($J,"W"),X
 Q
HDR ;HEADER
 W @IOF S PG=PG+1 K DASHES S $P(DASHES,"-",80)="-"
 W !,"Case # ",OOPS(2260,IEN,.01),?73,"Page ",PG
 W !,DASHES
 Q