GMRVXCH1 ;HIRMFO/YH-NEW QUALIFIER/CATEGORY ;8/21/96
 ;;4.0;Vitals/Measurements;;Apr 25, 1997
ADDCAT ;ADD NEW CATEGORIES TO #120.53
 D BMES^XPDUTL("Adding new categories to 120.53 file...")
 N GMRVTXT,GMRVCAT,GMRVTYP,GMRVLINE,GDA
 F GMRVTXT=1:1 S GMRVLINE=$P($T(CATTABL+GMRVTXT),";;",2) Q:GMRVLINE=""  S GMRVTYP=$P(GMRVLINE,";",2) Q:GMRVTYP=""  S GMRVTYP(1)=$O(^GMRD(120.51,"B",GMRVTYP,"")) Q:GMRVTYP(1)'>0  S GMRVCAT=$P(GMRVLINE,";") Q:GMRVCAT=""  D
 .  I $D(^GMRD(120.53,"B",GMRVCAT)) S GMRVCAT(1)=$O(^GMRD(120.53,"B",GMRVCAT,0)) D:$D(^GMRD(120.53,GMRVCAT(1),0))  Q
 . . Q:$D(^GMRD(120.53,GMRVCAT(1),1,"B",GMRVTYP(1)))
 . . I '$D(^GMRD(120.53,GMRVCAT(1),1,0)) S ^GMRD(120.53,GMRVCAT(1),1,0)="^120.531P^0^0"
 . . S GDA=+$P(^GMRD(120.53,GMRVCAT(1),1,0),"^",3)+1
 . . S ^GMRD(120.53,GMRVCAT(1),1,GDA,0)=GMRVTYP(1)_"^"_$P(GMRVLINE,";",3)
 . . S ^GMRD(120.53,GMRVCAT(1),1,"B",GMRVTYP(1),GDA)="",^GMRD(120.53,"C",GMRVTYP(1),GMRVCAT(1),GDA)=""
 . . S $P(^GMRD(120.53,GMRVCAT(1),1,0),"^",3)=GDA,$P(^(0),"^",4)=$P(^(0),"^",4)+1
 . . Q
 . E  D
 . . S GDA=+$P(^GMRD(120.53,0),"^",3)+1
 . . S ^GMRD(120.53,GDA,0)=GMRVCAT,^GMRD(120.53,GDA,1,0)="^120.531P^1^1"
 . . S ^GMRD(120.53,"B",GMRVCAT,GDA)=""
 . . S ^GMRD(120.53,GDA,1,1,0)=GMRVTYP(1)_"^"_$P(GMRVLINE,";",3)
 . . S ^GMRD(120.53,GDA,1,"B",GMRVTYP(1),1)=""
 . . S ^GMRD(120.53,"C",GMRVTYP(1),GDA,1)=""
 . . S $P(^GMRD(120.53,0),"^",3)=GDA,$P(^(0),"^",4)=$P(^(0),"^",4)+1
 . . Q
 . Q
 Q
ADDCHAR ;ADD NEW QUALIFIERS TO #120.52
 D BMES^XPDUTL("Adding new qualifiers to 120.52 file...")
 N GMRVTXT,GMRVCAT,GMRVCHA,GMRVTYP,GMRVLINE,GDA
 F GMRVTXT=1:1 S GMRVLINE=$P($T(CHRTABL+GMRVTXT),";;",2) Q:GMRVLINE=""  D
 . S GMRVTYP=$P(GMRVLINE,";",2) Q:GMRVTYP=""  S GMRVTYP(1)=$O(^GMRD(120.51,"B",GMRVTYP,0)) Q:GMRVTYP(1)'>0
 . S GMRVCHA=$P(GMRVLINE,";") Q:GMRVCHA=""  S GMRVCAT=$P(GMRVLINE,";",3),GMRVCAT(1)=$O(^GMRD(120.53,"B",GMRVCAT,0)) Q:GMRVCAT(1)'>0  I $D(^GMRD(120.53,GMRVCAT(1),0)) D
 . . I $D(^GMRD(120.52,"B",GMRVCHA)) D OLD^GMRVXCH3 Q
 . . D NEW^GMRVXCH3
 . . Q
 . Q
 Q
CHRTABL ;;QUALIFIER;TYPE;CATEGORY
 ;;FEMORAL;PULSE;LOCATION
 ;;POPLITEAL;PULSE;LOCATION
 ;;POSTERIOR TIBIAL;PULSE;LOCATION
 ;;DORSALIS PEDIS;PULSE;LOCATION
 ;;BRACHIAL;PULSE;LOCATION
 ;;ULNAR;PULSE;LOCATION
 ;;PALPATED;PULSE;METHOD
 ;;DOPPLER;PULSE;METHOD
 ;;AUSCULTATE;PULSE;METHOD
 ;;RIGHT;PULSE;SITE
 ;;LEFT;PULSE;SITE
 ;;CUFF;BLOOD PRESSURE;METHOD
 ;;NON-INVASIVE;BLOOD PRESSURE;METHOD
 ;;DOPPLER;BLOOD PRESSURE;METHOD
 ;;PALPATED;BLOOD PRESSURE;METHOD
 ;;ADULT;BLOOD PRESSURE;CUFF SIZE;
 ;;SM ADULT;BLOOD PRESSURE;CUFF SIZE
 ;;LG ADULT;BLOOD PRESSURE;CUFF SIZE
 ;;THIGH;BLOOD PRESSURE;CUFF SIZE
 ;;PEDIATRIC;BLOOD PRESSURE;CUFF SIZE
 ;;CHAIR;WEIGHT;METHOD
 ;;STANDING;WEIGHT;METHOD
 ;;BED;WEIGHT;METHOD
 ;;RIGHT;CIRCUMFERENCE/GIRTH;SITE
 ;;LEFT;CIRCUMFERENCE/GIRTH;SITE
 ;;HEAD;CIRCUMFERENCE/GIRTH;LOCATION
 ;;ABDOMINAL;CIRCUMFERENCE/GIRTH;LOCATION
 ;;CALF;CIRCUMFERENCE/GIRTH;LOCATION
 ;;THIGH;CIRCUMFERENCE/GIRTH;LOCATION
 ;;LOWER ARM;CIRCUMFERENCE/GIRTH;LOCATION
 ;;UPPER ARM;CIRCUMFERENCE/GIRTH;LOCATION
 ;;OTHER;CIRCUMFERENCE/GIRTH;LOCATION
 ;;WRIST;CIRCUMFERENCE/GIRTH;LOCATION
 ;;ANKLE;CIRCUMFERENCE/GIRTH;LOCATION
 ;;ACTUAL;HEIGHT;QUALITY
 ;;ESTIMATED;HEIGHT;QUALITY
 ;;MASK;PULSE OXIMETRY;METHOD
 ;;T-PIECE;PULSE OXIMETRY;METHOD
 ;;FACE TENT;PULSE OXIMETRY;METHOD
 ;;AEROSOL/HUMIDIFIED MASK;PULSE OXIMETRY;METHOD
 ;;NASAL CANNULA;PULSE OXIMETRY;METHOD
 ;;NON RE-BREATHER;PULSE OXIMETRY;METHOD
 ;;PARTIAL RE-BREATHER;PULSE OXIMETRY;METHOD
 ;;TRACHEOSTOMY COLLAR;PULSE OXIMETRY;METHOD
 ;;VENTILATOR;PULSE OXIMETRY;METHOD
 ;;VENTURI MASK;PULSE OXIMETRY;METHOD
 ;;SITTING;RESPIRATION;POSITION
 ;;STANDING;RESPIRATION;POSITION
 ;;LYING;RESPIRATION;POSITION
 ;;SITTING;PULSE;POSITION
 ;;STANDING;PULSE;POSITION
 ;;LYING;PULSE;POSITION
 Q
CATTABL ;;CATEGORY;TYPE;MIN^MAX^REQ^PRINT ORDER^EDIT ORDER^DEFAULT CHAR.
 ;;METHOD;PULSE;^1^^3^3
 ;;SITE;PULSE;^1^^1^2
 ;;METHOD;BLOOD PRESSURE;^1^^3^3^PALPATED
 ;;CUFF SIZE;BLOOD PRESSURE;^1^^4^4^ADULT
 ;;METHOD;WEIGHT;^1^^2^2^STANDING
 ;;SITE;CIRCUMFERENCE/GIRTH;^1^^1^2
 ;;LOCATION;CIRCUMFERENCE/GIRTH;^1^^2^1
 ;;QUALITY;HEIGHT;^1^^1^1^
 ;;POSITION;RESPIRATION;^1^^2^2
 ;;POSITION;PULSE;^1^^4^4
 ;;METHOD;PULSE OXIMETRY;^1^^1^1
 Q