source: FOIAVistA/tag/r/GEN_MED_REC_VITALS-GMRV/GMRVXENV.m@ 628

Last change on this file since 628 was 628, checked in by George Lilly, 14 years ago

initial load of FOIAVistA 6/30/08 version

File size: 1.4 KB
Line 
1GMRVXENV ;HIRMFO/RM-ENVIRONMENT CHECK FOR VITALS ;7/18/96
2 ;;4.0;Vitals/Measurements;;Apr 25, 1997
3EN1 ; environment check for the vitals package
4 N GMRV
5 S GMRV=+$$VERSION^XPDUTL("REGISTRATION") I GMRV<5.3 W !!,"PIMS (MAS) V5.3 OR GREATER IS REQUIRED - INSTALL ABORTED!" S XPDABORT=2 Q
6 S GMRV=+$$VERSION^XPDUTL("GMRV") I GMRV>0,GMRV<3 W !!,"GEN. MED. REC. - VITALS V3.0 is required",!,"prior to the installation of V4.0 - INSTALL ABORTED!" S XPDABORT=2 Q
7 I GMRV=3,+$$PATCH^XPDUTL("GMRV*3.0*3")=0 W !!,"GMRV*3*3 is required prior to the installation of v4.0 - Install aborted!" S XPDABORT=2 Q
8 ;
9 Q:+$$VERSION^XPDUTL("GMRV")'>0 ;quit if virgin install
10 K GMRVIEN,GMRVERR
11 ; how many V/M entries in Package File (#9.4)
12 D FIND^DIC(9.4,"","","X","GMRV","","C","","","GMRVIEN","GMRVERR")
13 ; quit if FileMan lookup errors out
14 I +$G(GMRVERR("DIERR")) D S GMRVSTOP=1 D KILL Q
15 .K GMRVMSG
16 .S GMRVMSG(1)="Error trying to lookup Vitals/Measurements in the PACKAGE (#9.4) file."
17 .S GMRVMSG(2)="Halting."
18 .D BMES^XPDUTL(.GMRVMSG)
19 .Q
20 ; delete duplicates
21 ; keep GEN. MED. REC. - VITALS entry
22 S GMRVSEQ=0
23 F S GMRVSEQ=$O(GMRVIEN("DILIST",1,GMRVSEQ)) Q:GMRVSEQ'>0 D
24 . S GMRVNAME=$G(GMRVIEN("DILIST",1,GMRVSEQ)) Q:GMRVNAME=""
25 . I GMRVNAME="GEN. MED. REC. - VITALS" Q
26 . S DA=$G(GMRVIEN("DILIST",2,GMRVSEQ))
27 . I DA S DIK="^DIC(9.4," D ^DIK
28 . Q
29KILL ;
30 S:$G(GMRVSTOP) XPDABORT=2 ;don't install transport global/leave in ^XTMP
31 K DA,DIK,GMRVERR,GMRVIEN,GMRVMSG,GMRVNAME,GMRVSEQ,X,Y
32 Q
Note: See TracBrowser for help on using the repository browser.