PRCFOOR4 ;WISC/CTB,AKS - 850 UTILITIES ;12/15/94  12:00 PM
V ;;5.1;IFCAP;;Oct 20, 2000
 ;Per VHA Directive 10-93-142, this routine should not be modified.
REMOVE(DA) ;REMOVE MESSAGE FROM 423.6
 D KILL^PRCOSRV3(DA)
 QUIT
FCPBULL(PRCDA) ;FIRE BULLETIN THAT CCP MESSAGE HAS BEEN COMPLETED
 S XMB(1)=PRCDA,XMB="PRCF FMS ADJUSTMENTS",XMDUZ=.5,XMY(DUZ)=""
 D EN^XMB QUIT
BULL(PRCDA) ;FIRE BULLETIN THAT OOP MESSAGE HAS BEEN COMPLETED SUCCESSFULLY.
 S XMB(1)=PRCDA,XMB="PRCF_850_BULLETIN",XMDUZ=.5,XMY(DUZ)=""
 D EN^XMB
 Q
BULL1(PRCDA,X) ;FIRE BULLETIN THAT OOP MESSAGE ENCOUNTERED AN ERROR IN PROCESSING.
 ;PARAMATERS ARE: PRCDA=MSG NUMBER IN 423.6 WHICH FAILED, X=MESSAGE TEXT
 S XMB(1)=PRCDA,XMB="PRCF_850_BULLETIN1",XMDUZ=.5,XMY(DUZ)=""
 S X="  "_X,A(1)=X,XMTEXT="A("
 D EN^XMB
 QUIT
PRINT ;PRINT REPORT OF OUTSTANDING OBLIGATION REPORT - FILE 420.96
 D ^PRCFSITE Q:'%
 W ! K IO("Q"),PRCOSTAT S %ZIS("B")="HOME",%ZIS="QM" D ^%ZIS Q:POP
 I $D(IO("Q")) S ZTDTH="",ZTIO=IO D  Q
 .S ZTDESC="OUTSTANDING OBLIGATION REPORT"
 .S ZTRTN="RPT^PRCFOOR4",ZTSAVE("PRC*")=""
 .D ^%ZTLOAD
RPT ;
 S (PRCFAT,PRCFAS,PRCFCT,PRCFCS,PRCFOT,PRCFOS)=0
 S DIC="^PRCU(420.96,",FLDS="[PRCFOOR4]",BY="[PRCFOOR4]" S:$D(ION) IOP=ION
 S FR=PRC("SITE"),TO=PRC("SITE"),DIOEND="D B^PRCFOOR5",DHD="OUTSTANDING OBLIGATION REPORT"
 D EN1^DIP
 QUIT
PRINT2 ;PRINT REPORT OF ERRORS ON FCP CONVERSION - FILE 420.98
 QUIT
RESTART ;OPTION ENTRY POINT TO RESTART FAILED OUTSTANDING OBLIGATION REPORT
 ;ASK FOR MESSAGE NUMBER IN 423.6
 ;ASK FOR DEVICE
 ;SET VARIABLE PRCDA=INTERNAL REFERENCE NUMBER IN 423.6
 S DIC="^PRCF(423.6,",DIC(0)="AEQ" D ^DIC Q:Y<0
 S PRCDA=+Y
 ;W ! K IO("Q") S %ZIS("B")="HOME",%ZIS="QM" D ^%ZIS Q:POP
 ;I $D(IO("Q")) S ZTDTH="",ZTIO=IO D
 ;.S ZTDESC="OUTSTANDING OBLIGATION REPORT"
 ;.S ZTRTN="^PRCFOOR3",ZTSAVE("PRC*")=""
 ;.S ZTIO="" D ^%ZTLOAD
 S ZTDESC="OUTSTANDING OBLIGATION REPORT"
 S ZTRTN="^PRCFOOR3",ZTSAVE("PRC*")=""
 S ZTIO="" D ^%ZTLOAD
 QUIT
 ;D ^PRCFOOR3
 ;D ^%ZISC
 QUIT
RESTART1 ;OPTION ENTRY POINT TO RESTART FAILED FCP CONVERSION
 ;ASK FOR MESSAGE NUMBER IN 423.6
 ;SET VARIABLE PRCDA=INTERNAL REFERENCE NUMBER IN 423.6
 ;ASK FOR DEVICE
 S DIC="^PRCF(423.6,",DIC(0)="AEQ" D ^DIC Q:Y<0
 S PRCDA=+Y
 W ! K IO("Q") S %ZIS("B")="HOME",%ZIS="QM" D ^%ZIS Q:POP
 I $D(IO("Q")) S ZTDTH="",ZTIO=IO D
 .S ZTDESC="FUND CONTROL POINT CONVERSION"
 .S ZTRTN="^PRCFOOR2",ZTSAVE("PRC*")=""
 .D ^%ZTLOAD
 D ^PRCFOOR2
 D ^%ZISC
 QUIT
CLEAN(SITE) ;REMOVE ALL RECORDS FROM FILE 420.96 WITH STATION NUMBER (SITE)
 N N,DA,DIK
 S DIK="^PRCU(420.96,"
 S DA=0 F  S DA=$O(^PRCU(420.96,DA)) Q:'DA  S X=$P(^(DA,0),"^",8) I X=""!(X=SITE) D ^DIK
 QUIT