source: FOIAVistA/tag/r/IFCAP-PRC-PRX--PRCA--PRCN/PRCXLG01.m@ 1742

Last change on this file since 1742 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 3.2 KB
Line 
1PRCXLG01 ;WISC/LKG-SCRATCH ROUTINE FOR PRC*5*10 ;8/3/95 10:50
2V ;;5.0;IFCAP;**10**;4/21/95
3 W:$E($G(IOST),1,2)="C-" *7,!,"Invalid Entry Point." Q
4INSTALL ;Changes value for ROUTINE field in OPTION file entries
5 I $D(U)#10'=1!'$D(DUZ) D DT^DICRW
6 S PRCXTERM=$E($G(IOST),1,2)="C-"
7 W:PRCXTERM !!,"Changing the entry point for options PRCFD CHECKIN INVOICE and"
8 W:PRCXTERM !," PRCFD RECHARGE AN INVOICE",!
9 F PRCXA="PRCFD CHECKIN INVOICE~LOGIN^PRCFDE3~PRCFDCI","PRCFD RECHARGE AN INVOICE~RECHARGE^PRCFDE3~RECHARGE^PRCFDE1" S X=$P(PRCXA,"~"),PRCXB=$P(PRCXA,"~",2) D
10 . S DIC="^DIC(19,",DIC(0)="X" D ^DIC K DIC
11 . Q:+Y<1
12 . S DA=+Y Q:$G(^DIC(19,DA,25))'=$P(PRCXA,"~",3)
13 . S DIE="^DIC(19,",DR="25///^S X=PRCXB" D ^DIE K DA,DIE,DR
14 . W:PRCXTERM !,"Option ",$P(PRCXA,"~")," converted"
15 K PRCXA,PRCXB,X,Y
16 W:PRCXTERM !!,"Now rebuilding the 'AE' cross reference for the STATUS field (#50)"
17 W:PRCXTERM !," of the INVOICE TRACKING file (#421.5)."
18 W:PRCXTERM !,"There are ",$P($G(^PRCF(421.5,0)),U,4)+0," entries to reindex."
19 I PRCXTERM S %H=$H D YX^%DTC W !," Starting Date/Time: ",Y K X,Y,%,%H
20 L +^PRCF(421.5)
21 W:PRCXTERM !,?10,"Deleting old index"
22 K ^PRCF(421.5,"AE")
23 W:PRCXTERM !,?10,"Creating new index"
24 S DIK="^PRCF(421.5,",DIK(1)="50^AE" D ENALL^DIK K DIK
25 L -^PRCF(421.5)
26 I PRCXTERM S %H=$H D YX^%DTC W !," Ending Date/Time: ",Y K X,Y,%,%H
27 K PRCXTERM
28 Q
29REPT ;Displays to screen invoices where Date Due in Fiscal is non-
30 ;null but the Current Location is Fiscal or the Status is not 'Pending
31 ;Service Certification', suggesting inconsistency in the data
32 W !!,"This report will list information on Invoices where there is identified"
33 W !,"inconsistency in the values for fields DATE DUE IN FISCAL and either"
34 W !,"CURRENT INVOICE LOCATION or STATUS."
35 S %ZIS="QP" D ^%ZIS Q:POP
36 I $D(IO("Q")) D Q
37 . S ZTRTN="REPTIN^PRCXLG01",ZTDESC="Rept of Invoices with Inconsistent Date Due in Fiscal"
38 . D ^%ZTLOAD,HOME^%ZIS K ZTSK
39REPTIN ;Entry point for actual printing
40 U IO
41 S %H=$H D YX^%DTC S PRCXD=Y K X,Y,%,%H
42 S PRCXDA=0,PRCXC=0,PRCXH="",PRCXL=0,PRCXP=0 D HDR
43 F S PRCXDA=$O(^PRCF(421.5,PRCXDA)) Q:PRCXDA'?1.N D G:PRCXH["^" REPTX
44 . S PRCXNOD2=$G(^PRCF(421.5,PRCXDA,2))
45 . I ($P(PRCXNOD2,"^",8)=""&($P(PRCXNOD2,"^")=5))!($P(PRCXNOD2,"^",8)'=""&($P(PRCXNOD2,"^",4)["FISCAL"!($P(PRCXNOD2,"^")'=5))) D
46 . . D:PRCXL+6>IOSL HDR Q:PRCXH["^" S PRCXC=PRCXC+1
47 . . W !,"Invoice #: ",$P($G(^PRCF(421.5,PRCXDA,0)),"^"),?30,"Location: ",$P(PRCXNOD2,"^",4)
48 . . S X=$P(PRCXNOD2,"^")
49 . . W !,"Status: ",$S(X=0:"INCOMPLETE",X=3:"INVOICE RETURNED TO VENDOR",X=5:"PENDING SERVICE CERTIFICATION",X=10:"AWAITING VOUCHER AUDIT REVIEW",X=11:"VENDOR ID INCOMPLETE",X=15:"IN ACCOUNTING",X=20:"TRANSACTION COMPLETE",1:"")
50 . . S X=$P(PRCXNOD2,"^",8)
51 . . W ?45,"Date Due in Fiscal: ",$S(X]"":$E(X,4,5)_"/"_$E(X,6,7)_"/"_$E(X,2,3),1:""),!
52 . . S PRCXL=PRCXL+3
53 W !!,"COUNT= ",PRCXC,!,"<DONE>",! W:$E(IOST,1,2)'="C-" @IOF
54 D ^%ZISC S:$D(ZTQUEUED) ZTREC="@"
55REPTX K PRCXDA,PRCXNOD2,PRCXC,PRCXD,PRCXH,PRCXL,PRCXP,X
56 Q
57HDR R:$E(IOST,1,2)="C-"&PRCXP !,"Hit <RETURN> to Continue, '^' to Quit ",PRCXH:300
58 Q:PRCXH["^"
59 W:$E(IOST,1,2)="C-"!PRCXP @IOF S PRCXP=PRCXP+1
60 W !,?5,"REPORT OF CERTIFIED INVOICES WITH INCONSISTENT DATE DUE IN FISCAL"
61 W !,?20,"Run Date/Time: ",PRCXD,?65,"Page: ",PRCXP,!
62 S PRCXL=4
63 Q
Note: See TracBrowser for help on using the repository browser.