source: FOIAVistA/tag/r/KERNEL-XU-A4A7-USC-XG-XLF-XNOA-XPD-XQ-XVIR-ZI-ZOSF-ZOSV-ZT-ZU-%Z-XIP--XQAB--XUC--XUR--ZIN--ZTED/XPDR.m@ 949

Last change on this file since 949 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 7.1 KB
Line 
1XPDR ;SFISC/RSD - Routine File Edit ;09/17/96 10:05
2 ;;8.0;KERNEL;**1,2,44,393**;Jul 10, 1995;Build 12
3 Q
4UPDT ;update routine file
5 N DIR,DIRUT,XPD,XPDI,XPDJ,XPDN,X,X1,Y,Y1,% W !
6 W ! S DIR(0)="FO^1:9^K:X'?.1""-""1U.7UNP X",DIR("A")="Routine Namespace",DIR("?")="Enter 1 to 8 characters, preceed with ""-"" to exclude namespace"
7 ;XPDN(0=excluded names or 1=include names, namespace)=""
8 F D ^DIR Q:$D(DIRUT) S X=$E(Y,$L(Y))="*",%=$E(Y)="-",XPDN('%,$E(Y,%+1,$L(Y)-X))=""
9 Q:'$D(XPDN)!$D(DTOUT)!$D(DUOUT)
10 W !!,"NAMESPACE INCLUDE",?35,"EXCLUDE",!,?11,"-------",?35,"-------"
11 S (X,Y)="",(X1,Y1)=1
12 F D W !?11,X,?35,Y Q:'X1&'Y1
13 .S:X1 X=$O(XPDN(1,X)),X1=X]"" S:Y1 Y=$O(XPDN(0,Y)),Y1=Y]""
14 K DIR S DIR(0)="Y",DIR("A")="OK to continue",DIR("B")="YES" D ^DIR
15 Q:'Y!$D(DIRUT) W !
16 S DIR(0)="Y",DIR("A")="Want me to clean up the Routine File before updating",DIR("?")="YES means you want to go throught the Routine file and delete any routine name that no longer exists on the system."
17 D ^DIR
18 Q:$D(DIRUT) D WAIT^DICD,DELRTN:Y
19 ;loop thru include list XPDN(1,XPDI)
20 S XPDI="" F S XPDI=$O(XPDN(1,XPDI)) Q:XPDI="" D
21 .S XPDJ=XPDI D:$D(^$R(XPDJ)) F S XPDJ=$O(^$R(XPDJ)) Q:XPDJ=""!($P(XPDJ,XPDI)]"") D
22 ..;if name XPDJ is in the exclude list, XPDN(0,XPDJ) or in Routine file, quit
23 ..Q:$D(XPDN(0,XPDJ))!$O(^DIC(9.8,"B",XPDJ,0))
24 ..;check if XPDJ is refered in the namespace by checking the subscript
25 ..;before XPDJ, if sub exist and $P(XPDJ,sub)="" then it is part of the
26 ..;namespace, quit
27 ..S %=$O(XPDN(0,XPDJ),-1) I $L(%),$P(XPDJ,%)="" Q
28 ..N XPD S XPD(9.8,"+1,",.01)=XPDJ,XPD(9.8,"+1,",1)="R"
29 ..D ADD^DICA("","XPD")
30 W " ...Done.",!
31 Q
32VER ;verify Routine file
33 N DIR,DIRUT,X,Y
34 W !,"I will delete all local entries in the Routine File in which",!,"the Routine no longer exist on this system!",!
35 S DIR(0)="Y",DIR("A")="OK to continue",DIR("B")="YES" D ^DIR
36 Q:'Y!$D(DIRUT) D DELRTN
37 W " ...Done.",!
38 Q
39DELRTN ;delete routine file entries
40 N DA,DIK,Y
41 W !,"Routines listed as National will not be deleted!"
42 S DIK="^DIC(9.8,",DA=0
43 F S DA=$O(^DIC(9.8,DA)) Q:'DA S Y=$G(^(DA,0)) I "R"=$P(Y,U,2),$G(^DIC(9.8,DA,6))<2,$T(^@$P(Y,U))="" D ^DIK
44 Q
45PURGE ;purge file
46 N DA,DIK,DIR,DIRUT,X,XPD,XPDF,XPDI,XPDJ,XPDL,XPDN,XPDPG,XPDS,XPDUL,Y,Z
47 S DIR("?")="Enter the file you want to purge the data from.",DIR(0)="SM^B:Build;I:Install;ALL:Build & Install",DIR("A")="Purge from what file(s)"
48 D ^DIR Q:$D(DIRUT)
49 S XPDF=$S(Y="I":9.7,1:9.6) S:Y="ALL" XPDF(1)=9.7
50 K DIR S DIR("?")="Enter the number of Versions to keep in the file, for each package",DIR(0)="N^0:100:0",DIR("A")="Versions to Retain",DIR("B")=1
51 D ^DIR Q:$D(DIRUT) S XPDN=Y
52 K DIR
53 S DIR(0)="FO^3:30",DIR("?")="^D PURGEH^XPDR",DIR("A")="Package Name",DIR("B")="ALL"
54 F D ^DIR Q:$D(DIRUT) S XPD(X)="" Q:X="ALL" K DIR("B") S DIR("A")="Another Package Name"
55 Q:'$D(XPD)
56 ;if they want all, make sure all is the only one
57 I $D(XPD("ALL")) K XPD S XPD("ALL")=""
58 ;XPDF(1) is defined if doing both files, do purge twice
59 K ^TMP($J) D PURGE1(XPDF),PURGE1($G(XPDF(1))):$D(XPDF(1))
60 I '$D(^TMP($J)) W !!,"No match found" Q
61 K XPD,DIR
62 S DIR(0)="E",$P(XPDUL,"-",IOM)=""
63 ;if ALL, reset XPDF to next file and Do, then reset back to 9.6
64 D I $D(XPDF(1)) D ^DIR I Y S XPDF=XPDF(1) D S XPDF=9.6
65 .S XPD="^TMP("_$J_","_XPDF,XPDS=XPD_",",XPD=XPD_")",XPDL=$L(XPDS),XPDPG=1,Y=1
66 .W @IOF D HDR
67 .;loop thru ^TMP($J,file,package) & show list, quit if user "^"
68 .F S XPD=$Q(@XPD) Q:XPD=""!($E(XPD,1,XPDL)'=XPDS) D Q:'Y
69 ..S Z=@XPD W $P(Z,"^"),$S($P(Z,"^",3):" (duplicates)",1:""),! Q:$Y<(IOSL-4)
70 ..D ^DIR Q:'Y
71 ..S XPDPG=XPDPG+1 W @IOF D HDR
72 S DIR(0)="Y",DIR("A")="OK to DELETE these entries",DIR("B")="NO"
73 W !! D ^DIR
74 I $D(DIRUT)!'Y W !!,"Nothing Purged" Q
75 ;loop thru and delete
76 D I $D(XPDF(1)) S XPDF=XPDF(1) D
77 .S DIK="^XPD("_XPDF_",",XPD="^TMP("_$J_","_XPDF,XPDS=XPD_",",XPD=XPD_")",XPDL=$L(XPDS)
78 .F S XPD=$Q(@XPD) Q:XPD=""!($E(XPD,1,XPDL)'=XPDS) D
79 ..S XPDI=@XPD F XPDJ=2:1 S DA=$P(XPDI,"^",XPDJ) Q:'DA D ^DIK
80 Q
81 ;
82PURGE1(XPDF) ;XPDF=file #
83 N XPDFL,XPDI,XPDJ,XPDP,XPDV,Y,Z
84 W "."
85 ;if All, loop thru B x-ref
86 I $D(XPD("ALL")) D
87 .S XPDI=""
88 .F S XPDI=$O(^XPD(XPDF,"B",XPDI)) Q:XPDI="" D
89 ..S X=$$PKG^XPDUTL(XPDI) D PURGE2(X)
90 ..W "."
91 E S XPDI="" F S XPDI=$O(XPD(XPDI)) Q:XPDI="" D
92 .D PURGE2(XPDI)
93 .W "."
94 ;loop thru each package, XPDP=package name
95 S XPDP="" F S XPDP=$O(^TMP($J,XPDF,XPDP)) Q:XPDP="" D
96 .S XPDV="",XPDL=XPDN
97 .;the last is the most recent, XPDN = number to retain, XPDV=version
98 .;XPDS=type (T/V/Z)
99 .F S XPDV=$O(^TMP($J,XPDF,XPDP,XPDV),-1),XPDS="" Q:'XPDV!'XPDL F S XPDS=$O(^TMP($J,XPDF,XPDP,XPDV,XPDS),-1) Q:XPDS=""!'XPDL D
100 ..S Y="" F S Y=$O(^TMP($J,XPDF,XPDP,XPDV,XPDS,Y),-1) Q:Y=""!'XPDL D
101 ...I $D(^TMP($J,XPDF,XPDP,XPDV,XPDS,Y))#2 K ^(Y) S XPDL=XPDL-1 Q
102 ...S Z="" F S Z=$O(^TMP($J,XPDF,XPDP,XPDV,XPDS,Y,Z),-1) Q:Z=""!'XPDL K ^(Z) S XPDL=XPDL-1
103 Q
104 ;
105PURGE2(XPDX) ;XPDX=package name
106 ;XPDFL=1 this is not a patch, quit when we find a patch during loop
107 S XPDS=XPDX,XPDL=$L(XPDX),XPDFL=XPDX'["*"
108 ;loop and find matches
109 D F S XPDS=$O(^XPD(XPDF,"B",XPDS)) Q:XPDS=""!($E(XPDS,1,XPDL)'=XPDX)!($S(XPDFL:XPDS["*",1:0)) D
110 .S Y=$O(^XPD(XPDF,"B",XPDS,0)) Q:'Y
111 .Q:'$D(^XPD(XPDF,Y,0)) S Z=^(0),Y=XPDS_"^"_Y
112 .;can't delete Installs that status isn't 'Install Completed'
113 .I XPDF=9.7 Q:$P(Z,U,9)<3
114 .S XPDV=$$VER^XPDUTL(XPDS)
115 .;TMP($J,file,package name,version,"*","T/V/Z",num,patch)=NAME^DA^duplicat DAs
116 .I XPDS["*" D Q
117 ..I XPDV?1.2N1"."1.2N S ^TMP($J,XPDF,$$PKG^XPDUTL(XPDS),+XPDV,"*Z",0,+$P(XPDS,"*",3))=Y_$$DUP(XPDS,$P(Y,"^",2)) Q
118 ..I XPDV["T" S ^TMP($J,XPDF,$$PKG^XPDUTL(XPDS),+XPDV,"*T",+$P(XPDV,"T",2),+$P(XPDS,"*",3))=Y_$$DUP(XPDS,$P(Y,"^",2)) Q
119 ..I XPDV["V" S ^TMP($J,XPDF,$$PKG^XPDUTL(XPDS),+XPDV,"*V",+$P(XPDV,"V",2),+$P(XPDS,"*",3))=Y_$$DUP(XPDS,$P(Y,"^",2)) Q
120 ..S ^TMP($J,XPDF,$$PKG^XPDUTL(XPDS),+XPDV,"*",+$P(XPDS,"*",3))=Y_$$DUP(XPDS,$P(Y,"^",2))
121 .;TMP($J,file,package name,version,"Z",0)=NAME^DA^duplicate DAs
122 .I XPDV?1.2N1"."1.2N S ^TMP($J,XPDF,$$PKG^XPDUTL(XPDS),+XPDV,"Z",0)=Y_$$DUP(XPDS,$P(Y,"^",2)) Q
123 .;TMP($J,file,package name,version,"T/V",num)=NAME^DA^dup DAs
124 .I XPDV["T" S ^TMP($J,XPDF,$$PKG^XPDUTL(XPDS),+XPDV,"T",+$P(XPDV,"T",2))=Y_$$DUP(XPDS,$P(Y,"^",2)) Q
125 .I XPDV["V" S ^TMP($J,XPDF,$$PKG^XPDUTL(XPDS),+XPDV,"V",+$P(XPDV,"V",2))=Y_$$DUP(XPDS,$P(Y,"^",2)) Q
126 Q
127PURGEH ;executable help from DIR call at PURGE+8
128 W:$E(DIR("A"),1)="P" !,"Enter 'ALL' to purge all packages, or"
129 W !,"Enter the name of the Package you want to Purge.",!," i.e. KERNEL 8.0 will purge version 8.0Tx and 8.0Vx",!," XU*8.0 will purge all patches for 8.0",!
130 N DIR,X,Y
131 S DIR(0)="Y",DIR("A")="Want to see the "_$S(XPDF=9.7:"Install File",$D(XPDF(1)):"Build & Install Files",1:"Build File")_" List",DIR("B")="Y"
132 D ^DIR Q:'Y!$D(DIRUT)
133 D PURGEH1("^XPD(9.6,"):XPDF=9.6,PURGEH1("^XPD(9.7,"):XPDF=9.7!$D(XPDF(1))
134 Q
135 ;
136DUP(Z,Z1) ;find duplicate, Z=NAME, Z1=last ien
137 ;returns Y=DA^dup DA^dup DA...
138 N Y S Y=""
139 F S Z1=$O(^XPD(XPDF,"B",Z,Z1)) Q:'Z1 S Y=Y_"^"_Z1
140 Q Y
141 ;
142PURGEH1(DIC) ;
143 W !!,$S(DIC[9.6:"BUILD ",1:"INSTALL ")_"File"
144 S DIC(0)="QE",X="??" D ^DIC
145 Q
146 ;
147HDR W !,"Package(s) in ",$S(XPDF=9.7:"INSTALL",1:"BUILD")," File, "
148 I XPDN W "Retain last ",$S(XPDN=1:"version",1:XPDN_" versions")
149 E W "Don't retain any versions"
150 W ?70,"PAGE ",XPDPG,!,XPDUL,!
151 Q
Note: See TracBrowser for help on using the repository browser.