| 1 | XMJMOIE ;ISC-SF/GMB-Edit msg that user has sent to self ;04/19/2002 11:01
|
|---|
| 2 | ;;8.0;MailMan;;Jun 28, 2002
|
|---|
| 3 | EDIT(XMDUZ,XMK,XMZ,XMSUBJ,XMINSTR,XMRESTR) ;
|
|---|
| 4 | N XMABORT,XMDIR,XMOPT,XMOX,XMY
|
|---|
| 5 | S XMABORT=0
|
|---|
| 6 | F D Q:XMABORT
|
|---|
| 7 | . D SENDSET(.XMINSTR,.XMOPT,.XMOX,.XMDIR)
|
|---|
| 8 | . D XMDIR^XMJDIR(.XMDIR,.XMOPT,.XMOX,.XMY,.XMABORT) Q:XMABORT
|
|---|
| 9 | . K XMDIR,XMOPT,XMOX
|
|---|
| 10 | . D @XMY
|
|---|
| 11 | Q
|
|---|
| 12 | SENDSET(XMINSTR,XMOPT,XMOX,XMDIR) ;
|
|---|
| 13 | D OPTEDIT^XMXSEC2(.XMINSTR,.XMOPT,.XMOX,1)
|
|---|
| 14 | I $G(XMOPT("NS","?"))=37309.1 K XMOPT("NS","?") ; You have no Network Signature.
|
|---|
| 15 | D SET^XMXSEC2("IM",37445,.XMOPT,.XMOX) ; Include responses from another message
|
|---|
| 16 | S XMDIR("A")=$$EZBLD^DIALOG(34066) ; Select Edit option:
|
|---|
| 17 | S XMDIR("??")="XM-U-MO-EDIT"
|
|---|
| 18 | Q
|
|---|
| 19 | C ; Confidential msg
|
|---|
| 20 | N XMMSG
|
|---|
| 21 | D CONFID^XMXEDIT(XMZ,.XMINSTR,.XMMSG) I $D(XMERR) D SHOW^XMJERR Q
|
|---|
| 22 | W !,XMMSG
|
|---|
| 23 | Q
|
|---|
| 24 | D ; Delivery basket
|
|---|
| 25 | N XMMSG
|
|---|
| 26 | I $D(XMINSTR("RCPT BSKT")) D Q
|
|---|
| 27 | . D DELIVER^XMXEDIT(XMZ,"@",.XMINSTR,.XMMSG)
|
|---|
| 28 | . W !,XMMSG
|
|---|
| 29 | D D^XMJMSO
|
|---|
| 30 | Q:'$D(XMINSTR("RCPT BSKT"))
|
|---|
| 31 | D DELIVER^XMXEDIT(XMZ,XMINSTR("RCPT BSKT"),.XMINSTR,.XMMSG)
|
|---|
| 32 | Q
|
|---|
| 33 | ES ; Edit Subject
|
|---|
| 34 | D ES^XMJMSO
|
|---|
| 35 | Q
|
|---|
| 36 | ET ; Edit Text
|
|---|
| 37 | I $G(XMPAKMAN) Q:$$NOPAKEDT^XMJMSO
|
|---|
| 38 | I $D(XMSECURE) D
|
|---|
| 39 | . N XMIA S XMIA=1
|
|---|
| 40 | . D DECMSG^XMJMCODE(XMZ)
|
|---|
| 41 | D BODY^XMJMS(XMDUZ,XMZ,XMSUBJ,.XMRESTR)
|
|---|
| 42 | I $D(XMSECURE) D
|
|---|
| 43 | . N XMIA S XMIA=1
|
|---|
| 44 | . D ENCMSG^XMJMCODE(XMZ)
|
|---|
| 45 | Q
|
|---|
| 46 | I ; Information only msg
|
|---|
| 47 | N XMMSG
|
|---|
| 48 | D INFO^XMXEDIT(XMZ,.XMINSTR,.XMMSG)
|
|---|
| 49 | W !,XMMSG
|
|---|
| 50 | Q
|
|---|
| 51 | IM ; Include responses from another message
|
|---|
| 52 | ;I $G(XMPAKMAN) Q:$$NOPAKEDT^XMJMSO
|
|---|
| 53 | I $G(XMPAKMAN) D Q
|
|---|
| 54 | . W !,$$EZBLD^DIALOG(37445.4) ; You may not Include anything into a KIDS or PackMan message.
|
|---|
| 55 | I $D(XMSECURE) D
|
|---|
| 56 | . N XMIA S XMIA=1
|
|---|
| 57 | . D DECMSG^XMJMCODE(XMZ)
|
|---|
| 58 | D INCL^XMJMRO(XMDUZ,XMZ,XMZ,XMSUBJ,.XMRESTR,2,.XMABORT)
|
|---|
| 59 | I $D(XMSECURE) D
|
|---|
| 60 | . N XMIA S XMIA=1
|
|---|
| 61 | . D ENCMSG^XMJMCODE(XMZ)
|
|---|
| 62 | Q
|
|---|
| 63 | NS ; Add Network Signature
|
|---|
| 64 | D NS^XMJMSO
|
|---|
| 65 | Q
|
|---|
| 66 | P ; Priority msg
|
|---|
| 67 | N XMMSG
|
|---|
| 68 | D PRIORITY^XMXEDIT(XMZ,.XMINSTR,.XMMSG)
|
|---|
| 69 | W !,XMMSG
|
|---|
| 70 | Q
|
|---|
| 71 | R ; Confirm receipt of msg
|
|---|
| 72 | N XMMSG
|
|---|
| 73 | D CONFIRM^XMXEDIT(XMZ,.XMINSTR,.XMMSG)
|
|---|
| 74 | W !,XMMSG
|
|---|
| 75 | Q
|
|---|
| 76 | S ; Scramble msg
|
|---|
| 77 | N XMMSG
|
|---|
| 78 | I $D(XMSECURE) D Q
|
|---|
| 79 | . D SCRAMBLE^XMXEDIT(XMZ,.XMINSTR,.XMMSG)
|
|---|
| 80 | . W !,XMMSG
|
|---|
| 81 | D S^XMJMSO
|
|---|
| 82 | Q:'$D(XMINSTR("SCR KEY"))
|
|---|
| 83 | D SCRAMBLE^XMXEDIT(XMZ,.XMINSTR,.XMMSG)
|
|---|
| 84 | Q
|
|---|
| 85 | V ; Vaporize date
|
|---|
| 86 | N XMMSG
|
|---|
| 87 | I $G(XMINSTR("VAPOR")) D Q
|
|---|
| 88 | . D VAPOR^XMXEDIT(XMZ,"@",.XMINSTR,.XMMSG)
|
|---|
| 89 | . I XMK D KVAPOR^XMXUTIL(XMDUZ,XMK,XMZ,"@")
|
|---|
| 90 | . W !,XMMSG
|
|---|
| 91 | D V^XMJMSO
|
|---|
| 92 | Q:'$D(XMINSTR("VAPOR"))
|
|---|
| 93 | I XMK D KVAPOR^XMXUTIL(XMDUZ,XMK,XMZ,XMINSTR("VAPOR"))
|
|---|
| 94 | D VAPOR^XMXEDIT(XMZ,XMINSTR("VAPOR"),.XMINSTR,.XMMSG)
|
|---|
| 95 | Q
|
|---|
| 96 | X ; Closed msg
|
|---|
| 97 | N XMMSG
|
|---|
| 98 | D CLOSED^XMXEDIT(XMZ,.XMINSTR,.XMMSG) I $D(XMERR) D SHOW^XMJERR Q
|
|---|
| 99 | W !,XMMSG
|
|---|
| 100 | Q
|
|---|
