XMRUCX ;(WASH ISC)/THM/CAP-SMTP Receiver (RFC 821) for UCX ;03/25/2004  06:33
 ;;8.0;MailMan;**6,19,25,27**;Jun 28, 2002
 ;
 ;Entry for Inet_servers interface RECEIVER
 ;SMTP service request invokes MailMan
SOC25 ;
 ;S (XMRPORT,IO,IO(0))=%,X=$E(%_"-INETMM",1,15) D SETENV^%ZOSV
 ;I $$NEWERR^%ZTER N $ETRAP,$ESTACK S $ETRAP="D R^XMCTRAP Q"
 ;E  S X="R^XMCTRAP",@^%ZOSF("TRAP")
 ;D DT^DICRW,DUZ^XUP(.5)
 ;S ER=0
 ;O IO:(SHARE) U IO
 ;S XMCHAN="TCP/IP-MAILMAN",XMNO220=""
 ;D ENT^XMR
 ;;G HALT^XMRTCP
 ;Q
SOC ;
 S (XMRPORT,IO,IO(0))="SYS$NET",X=$E(%_"INETMM",1,15) D SETENV^%ZOSV
 I $$NEWERR^%ZTER N $ETRAP,$ESTACK S $ETRAP="S ZZIO=$ZIO H 33 D R^XMCTRAP Q"
 E  S X="R^XMCTRAP",@^%ZOSF("TRAP")
 D DT^DICRW,DUZ^XUP(.5)
 S ER=0
 O IO:(TCPDEV):33 U IO
 S XMCHAN="TCP/IP-MAILMAN",XMNO220=""
 D ENT^XMR
 ;G HALT^XMRTCP
 Q
GTM2 ;Entry point for %ZISTCPS to GT.M
 ;The device has been open and setup in %ZISTCPS
 N $ETRAP,$ESTACK S $ETRAP="D ^%ZTER S ZZIO=$ZIO H 33 D R^XMCTRAP Q"
 S XMRPORT=IO
 D SETNM^%ZOSV($E(IO_"INETMM",1,15)),COUNT^XUSCNT(1) ;Process counting under GT.M
 N DIQUIET S DIQUIET=1 D DT^DICRW,DUZ^XUP(.5)
 S ER=0,XMS0C=1
 U IO:(DELIMITER=$C(13))
 S XMCHAN="TCP/GTM" ;,XMNO220=""
 D ENT^XMR
 D COUNT^XUSCNT(-1) ;Check out GT.M counting
 Q
STARTGTM ;Start the %ZISTCPS service
 D LISTEN^%ZISTCPS(25,"GTM2^XMRUCX")
 Q
CACHEVMS ;Cache/VMS tcpip service entry point
 N $ETRAP,$ESTACK S $ETRAP="S ZZIO=$ZIO H 33 D R^XMCTRAP Q"
 S (XMRPORT,IO,IO(0))="SYS$NET" D SETNM^%ZOSV($E("INETMM-"_$J,1,15))
 N DIQUIET S DIQUIET=1 D DT^DICRW,DUZ^XUP(.5)
 S ER=0,XMS0C=1
 O IO::33 U IO:(::"-M")
 S XMCHAN="TCP/IP-MAILMAN",XMNO220=""
 D ENT^XMR
 Q