source: FOIAVistA/tag/r/MAILMAN-XM/XMUT1A.m@ 628

Last change on this file since 628 was 628, checked in by George Lilly, 14 years ago

initial load of FOIAVistA 6/30/08 version

File size: 2.6 KB
Line 
1XMUT1A ;(WASH ISC)/CAP-Recover msgs for a user (cont.) ;04/17/2002 11:50
2 ;;8.0;MailMan;;Jun 28, 2002
3 ; Entry points used by MailMan options (not covered by DBIA):
4 ; DEL XMUT-REC-DELETE
5 ; LIST XMUT-REC-RPT
6NOKL G FX:$D(^DOPT("XMUT1",1)) S DIK="^DOPT(""XMUT1"","
7GO S ^DOPT("XMUT1",0)="Recover Messages Function^1N^"
8 F I=1:1 S X=$E($T(TABLE+I),4,99) Q:X="" S ^DOPT("XMUT1",I,0)=X
9 D IXALL^DIK
10FX S DIC="^DOPT(""XMUT1"",",DIC(0)="AEQZ" D ^DIC K DIC Q:Y<0
11 S X=$P(Y(0),U,2,99) K DD,DO,Y D @X
12 D ^%ZISC
13 W ! K DIE,DIF G FX
14TABLE ;;;DESCRIPTION^PROGRAM OR TAG^PROGRAM
15 ;;FIND MESSAGES FOR USER^A^XMUT1
16 ;;LIST MESSAGES IN USER'S BASKETS^M^XMUT1
17 ;;LOAD MESSAGES INTO IN-BASKET^G^XMUT1
18 ;;LIST MESSAGES FOUND^LIST^XMUT1A
19 ;;DELETE LIST OF RECOVERED MESSAGES FROM THE UTILITY GLOBAL^DEL^XMUT1A
20 ;;
21LIST ;LIST MESSAGES FOUND
22 N J,C,F,I,X,XME0
23 S (J,C,F)="" W !!,"CHOOSE FROM:",!
24 F I=0:0 S I=$O(^TMP("XMUT1",I)) Q:'I I $D(^VA(200,I,0)) W !,$J(I,8)," ",$$NAME^XMXUTIL(I) I 'J S J=I
25 I 'J G NO
26L W !!,"WHICH ONE: ",J,"//" R X:DTIME I X="" S X=J
27 Q:"^"[$E(X) I X="?" D H1 G L
28 I X="??" G LIST
29 I '$D(^TMP("XMUT1",X)) D H1 G LIST
30 S XME0=X,ZTSAVE("XME0")=""
31 D EN^XUTMDEVQ("ZTSK^XMUT1A","MailMan List Messages Found (XMUT-REC-RPT)",.ZTSAVE)
32 Q
33ZTSK ;
34 D NOW^%DTC S Y=%,XMF0=^DD("DD") K %,%I,%H X XMF0
35 S XMC0=0,XMB0=0 S XMA0=$$NAME^XMXUTIL(XME0)_" - "_Y D H
36N S XMC0=$O(^TMP("XMUT1",XME0,XMC0)) G NQ:'XMC0
37 S I=$G(^XMB(3.9,XMC0,0))
38 I I="" W !!,"Message removed from list - no longer in 3.9 file.",! K ^TMP("XMUT1",XME0,XMC0) G N
39 S XMD0=XMD0+1,Y=$P(I,"^",3) I Y?7N!(Y?7N1"."1N.N) X XMF0
40 W !?2,Y,?22,$P(I,"^")
41 G N:IOSL-6>XMD0 I $E(IOST,1,2)'="C-" D H G N
42 I '$D(ZTQUEUED) U IO(0) K DIR S DIR(0)="E" D ^DIR K DIR,DIRUT G NQ:X["^" U IO
43 D H G N
44H S XMB0=XMB0+1,XMD0=5
45 W @IOF,!,"CONTENTS OF MAILBOXES FOR ",XMA0,?60,"PAGE: ",XMB0,!!
46 W " DATE@TIME",?22,"SUBJECT",!!
47 Q
48NQ K XMA0,XMB0,XMD0,XMC0,XME0,XMF0
49 I $D(ZTQUEUED) W @IOF K ZTSK S ZTREQ="@" Q
50 D ^%ZISC
51 Q
52 ;
53DEL ;DELETE LIST FROM ^TMP("XMUT1"...
54 S (J,C,F)="" W !!,"CHOOSE FROM:",!
55 F I=0:0 S I=$O(^TMP("XMUT1",I)) Q:'I I $D(^VA(200,I,0)) W !,$J(I,8)," ",$$NAME^XMXUTIL(I) I 'J S J=I
56 I 'J G NO
57D W !!,"WHICH ONE ",J,"//" R X:DTIME I X="" S X=J
58 Q:"^"[$E(X) I X="?" D H1 G D
59 I X="??" D H1 G DEL
60 I '$D(^TMP("XMUT1",X)) D H1 G DEL
61 S XME0=X,XMB0=$G(^VA(200,XME0,0))
62 I XMB0="" W !," NO SUCH USER !!!",$C(7) G DQ
63 S DIR(0)="Y",DIR("B")="NO",DIR("A")="DO YOU MEAN '"_$$NAME^XMXUTIL(XME0)_"' "
64 D ^DIR K DIR,DIRUT Q:"^"[X!("yY"'[X)
65DQ K ^TMP("XMUT1",XME0) W " << DELETED !!!" K XME0 Q
66H1 W !!,"Choose NUMBER from list. Or enter '??' for a list.",!,$C(7) Q
67NO W !!!,"NO MESSAGES RECOVERED FOR ANYBODY !!!" Q
Note: See TracBrowser for help on using the repository browser.