| 1 | XMUT4A ;ISC-SF/GMB- Integrity Checker for file 3.7 ;04/17/2002 11:54
|
|---|
| 2 | ;;8.0;MailMan;;Jun 28, 2002
|
|---|
| 3 | ADDITC(XMDUZ,XMK,XMZ,XMKZ) ; "C" xref, but msg not in bskt. Fix it.
|
|---|
| 4 | S ^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0)=XMZ_U_XMKZ_U_$S($D(^XMB(3.7,XMDUZ,"N0",XMK,XMZ)):"1",$D(^XMB(3.7,XMDUZ,"N",XMK,XMZ)):"1",1:"")
|
|---|
| 5 | S:'$D(^XMB(3.7,"M",XMZ,XMDUZ,XMK,XMZ)) ^XMB(3.7,"M",XMZ,XMDUZ,XMK,XMZ)=""
|
|---|
| 6 | Q
|
|---|
| 7 | ADDITM(XMDUZ,XMK,XMZ,XMKZ) ; "M" xref, but msg not in bskt. Fix it.
|
|---|
| 8 | ; out: XMKZ
|
|---|
| 9 | S XMKZ=$$GETXMKZ(XMDUZ,XMK,XMZ)
|
|---|
| 10 | D ADDITC(XMDUZ,XMK,XMZ,XMKZ)
|
|---|
| 11 | Q
|
|---|
| 12 | ADDITN(XMDUZ,XMTYPE,XMK,XMZ) ; "N" or "N0" xref, but msg not in bskt. Fix it.
|
|---|
| 13 | N XMKZ
|
|---|
| 14 | S XMKZ=$$GETXMKZ(XMDUZ,XMK,XMZ)
|
|---|
| 15 | S ^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0)=XMZ_U_XMKZ_"^1"
|
|---|
| 16 | S:'$D(^XMB(3.7,"M",XMZ,XMDUZ,XMK,XMZ)) ^XMB(3.7,"M",XMZ,XMDUZ,XMK,XMZ)=""
|
|---|
| 17 | Q
|
|---|
| 18 | GETXMKZ(XMDUZ,XMK,XMZ) ; Find or create the message's basket sequence number.
|
|---|
| 19 | N XMKZ
|
|---|
| 20 | S XMKZ=0
|
|---|
| 21 | F S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:'XMKZ Q:$D(^(XMKZ,XMZ))
|
|---|
| 22 | Q:XMKZ XMKZ
|
|---|
| 23 | L +^XMB(3.7,XMDUZ,2,XMK)
|
|---|
| 24 | S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",""),-1)+1
|
|---|
| 25 | S ^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,XMZ)=""
|
|---|
| 26 | L -^XMB(3.7,XMDUZ,2,XMK)
|
|---|
| 27 | Q XMKZ
|
|---|
