ONCBRP6 ;HINES CIOFO/GWB - 1998 Breast Cancer Study - Table VI ;6/1/98
 ;;2.11;ONCOLOGY;**18**;Mar 07, 1995
 K TABLE,HTABLE
 S TABLE("81. DATE OF FIRST RECURRENCE")="DFR"
 S TABLE("82. TYPE OF FIRST RECURRENCE")="TFR"
 S HTABLE(1)="81. TYPE OF FIRST RECURRENCE"
 S HTABLE(2)="82. DATE OF FIRST RECURRENCE"
 S CHOICES=2
 W @IOF D HEAD^ONCBRP0
 W !," TABLE VI - FIRST RECURRENCE"
 W !," ---------------------------"
 S DIC="^ONCO(165.5,",DR="70",DA=ONCONUM,DIQ="ONCO" D EN^DIQ1
 S DIE="^ONCO(165.5,",DA=ONCONUM
DFR S DR="70 81. DATE OF FIRST RECURRENCE" D ^DIE G:$D(Y) JUMP
TFR S DR="71 82. TYPE OF FIRST RECURRENCE" D ^DIE G:$D(Y) JUMP
PRTC W ! K DIR S DIR(0)="E" D ^DIR S:$D(DIRUT) OUT="Y"
 G EXIT
JUMP ;Jump to prompts
 S XX="" R !!," GO TO ITEM NUMBER: ",X:DTIME I (X="")!(X[U) S OUT="Y" G EXIT
 I X["?" D  G JUMP
 .W !," CHOOSE FROM:" F I=1:1:CHOICES W !,?5,HTABLE(I)
 I '$D(TABLE(X)) S:X?1.2N X=X_"." S XX=X,X=$O(TABLE(X)) I ($P(X,XX,1)'="")!(X="") W *7,"??" D  G JUMP
 .W !," CHOOSE FROM:" F I=1:1:CHOICES W !,?5,HTABLE(I)
 S X=TABLE(X)
 G @X
EXIT K CHOICES,HTABLE,TABLE
 K PIECE
 K DA,DIE,DIR,DIROUT,DIRUT,DR,DTOUT,DUOUT,X,XX,Y
 Q