ONCPPC6 ;HIRMFO/GWB - PCE Studies of Prostate Cancer - Table VI;7/22/96
 ;;2.11;ONCOLOGY;**6**;Mar 07, 1995
 K TABLE,HTABLE,ONCO
 S TABLE("SURGERY")="SS"
 S TABLE("RADIATION THERAPY")="SRT"
 S TABLE("CHEMOTHERAPY")="SC"
 S TABLE("HORMONE THERAPY")="SHT"
 S HTABLE(1)="SURGERY"
 S HTABLE(2)="RADIATION THERAPY"
 S HTABLE(3)="CHEMOTHERAPY"
 S HTABLE(4)="HORMONE THERAPY"
 S CHOICES=4
 W @IOF D HEAD^ONCPPC0 W !?24,"TABLE VI - SUBSEQUENT TREATMENT",!
RFSCOT S DIE="^ONCO(165.5,",DA=ONCONUM
 S DR="656REASON FOR SECOND COURSE OF THERAPY" D ^DIE G:$D(Y) PRTC
ST I $D(^ONCO(165.5,ONCONUM,4,0)) S SCTIEN=0 F  S SCTIEN=$O(^ONCO(165.5,ONCONUM,4,SCTIEN)) Q:SCTIEN'>0  D SS Q:$D(Y)
 K SCTIEN G PRTC
SS K ONC S DIC="^ONCO(165.5,",DR="60",DA=ONCONUM,DIQ="ONC"
 S DR(165.51)=".04;.041;.051;.061;.071",DA(165.51)=SCTIEN D EN^DIQ1
 S SURG=ONC(165.51,SCTIEN,.04),(SURG1,SURG2)=""
 S LOS=$L(SURG) I LOS<43 S SURG1=SURG G TOS
 S NOP=$L($E(SURG,1,42)," ")
 S SURG1=$P(SURG," ",1,NOP-1),SURG2=$P(SURG," ",NOP,999)
TOS W !!,"SUBSEQUENT SURGERY #",SCTIEN,":",!
 W !,"TYPE OF SURGERY....................: ",SURG1
 W:SURG2'="" !,?40,SURG2
 W !,"DATE OF SURGERY....................: ",ONC(165.51,SCTIEN,.041)
SRT W !!,"SUBSEQUENT RADIATION THERAPY #",SCTIEN,":",!
 S DIE="^ONCO(165.5,"_ONCONUM_",4,",DA(1)=ONCONUM,DA=SCTIEN
 S DR="16RADIATION THERAPY.................." D ^DIE G:$D(Y) JUMP
 W !,"DATE RADIATON THERAPY BEGAN........: ",ONC(165.51,SCTIEN,.051)
 W !
 S DR="4INTERSTITIAL RADIATION............." D ^DIE G:$D(Y) JUMP
 W !!,"  INTERSTITIAL RADIATION ADMINISTERED:",!
 S DR="5    IODINE 125....................." D ^DIE G:$D(Y) JUMP
 S DR="6    GOLD 198......................." D ^DIE G:$D(Y) JUMP
 S DR="7    PALLADIUM 103.................." D ^DIE G:$D(Y) JUMP
 S DR="8    IRIDIUM 192...................." D ^DIE G:$D(Y) JUMP
 S DR="9    OTHER INTERSTITIAL, NOS........" D ^DIE G:$D(Y) JUMP
 W !
 S DR="10EXTERNAL RADIATION................." D ^DIE G:$D(Y) JUMP
 W !!,"  EXTERNAL RADIATION ADMINISTERED:",!
 S DR="11    PROSTATE REGION ONLY..........." D ^DIE G:$D(Y) JUMP
 S DR="12    PROSTATE & PELVIC NODES........" D ^DIE G:$D(Y) JUMP
 S DR="13    PARA-AORTIC NODES.............." D ^DIE G:$D(Y) JUMP
 S DR="14    DISTANT METASTATIC SITES......." D ^DIE G:$D(Y) JUMP
 S DR="15    OTHER EXTERNAL, NOS............" D ^DIE G:$D(Y) JUMP
 W !!,"  TOTAL RAD DOSE:",!
 S DR="17    PROSTATE......................." D ^DIE G:$D(Y) JUMP
 S DR="18    PELVIC NODES..................." D ^DIE G:$D(Y) JUMP
 S DR="19    PARA-AORTIC NODES.............." D ^DIE G:$D(Y) JUMP
SC W !!,"SUBSEQUENT CHEMOTHERAPY #",SCTIEN,":",!
 S DIE="^ONCO(165.5,"_ONCONUM_",4,",DA(1)=ONCONUM,DA=SCTIEN
 S DR="20CHEMOTHERAPY......................." D ^DIE G:$D(Y) JUMP
 W !,"DATE CHEMOTHERAPY BEGAN............: ",ONC(165.51,SCTIEN,.061)
 W !!,"  DRUGS ADMINISTERED:",!
 S DR="21    ADRIAMYCIN....................." D ^DIE G:$D(Y) JUMP
 S DR="22    CYTOXAN........................" D ^DIE G:$D(Y) JUMP
 S DR="23    METHOTREXATE..................." D ^DIE G:$D(Y) JUMP
 S DR="24    FLUOROURACIL..................." D ^DIE G:$D(Y) JUMP
 S DR="25    OTHER.........................." D ^DIE G:$D(Y) JUMP
SHT W !!,"SUBSEQUENT HORMONE THERAPY #",SCTIEN,":",!
 S DIE="^ONCO(165.5,"_ONCONUM_",4,",DA(1)=ONCONUM,DA=SCTIEN
 S DR="26HORMONE THERAPY...................." D ^DIE G:$D(Y) JUMP
 W !,"DATE HORMONE THERAPY BEGAN.........: ",ONC(165.51,SCTIEN,.071)
 W !!,"  HORMONES ADMINISTERED:",!
 S DR="27    ESTROGENS......................" D ^DIE G:$D(Y) JUMP
 S DR="28    ANTIANDROGENS.................." D ^DIE G:$D(Y) JUMP
 S DR="29    PROGESTATIONAL AGENTS.........." D ^DIE G:$D(Y) JUMP
 S DR="30    LUTEINIZING HORMONE-RELEASING.." D ^DIE G:$D(Y) JUMP
 S DR="31    ORCHIECTOMY...................." D ^DIE G:$D(Y) JUMP
 S DR="32    OTHER.........................." D ^DIE G:$D(Y) JUMP
 Q
PRTC W ! K DIR S DIR(0)="E" D ^DIR
 G EXIT
JUMP ;Jump to prompts
 S XX="" R !!,"GO TO: ",X:DTIME I (X="")!(X[U) S Y(1)="",OUT="Y" Q
 I X["?" D  G JUMP
 .W !,"CHOOSE FROM:" F I=1:1:CHOICES W !,?5,HTABLE(I)
 I '$D(TABLE(X)) S XX=X,X=$O(TABLE(X)) I ($P(X,XX,1)'="")!(X="") W *7,"??" D  G JUMP
 .W !,"CHOOSE FROM:" F I=1:1:CHOICES W !,?5,HTABLE(I)
 S X=TABLE(X)
 G @X
EXIT K CHOICES,HTABLE,TABLE
 K LOS,NOP,SURG,SURG1,SURG2
 K DA,DIE,DIR,DIROUT,DIRUT,DR,DTOUT,DUOUT,X,XX,Y
 Q