source: FOIAVistA/tag/r/PROSTHETICS-RMPR-RMPO-RMPS/RMPRCPT9.m@ 636

Last change on this file since 636 was 628, checked in by George Lilly, 14 years ago

initial load of FOIAVistA 6/30/08 version

File size: 2.8 KB
Line 
1RMPRCPT9 ;HIN/RVD-(2529-3) CPT MODIFIER UTILITY ;11/5/99
2 ;;3.0;PROSTHETICS;**41,69**;Feb 09, 1996
3 ;
4 ;RVD 5/14/03 patch #69 - changed GX modifier to GY.
5 ;process CPT field
6 ;Set variable RMCPT for all valid CPT modifier.
7 Q:'$D(X)
8 N DIR,RM6611,RMCPT1,RMCPSO,RMCP0,RMCP4,RMCRF,RMCBW,RMCPT5,RMHCPCS,RMCP11,RMCLEN,DIROUT,DTOUT,DUOUT
9 S RM6611=X
10 K RMCPT1,X
11 S RMCP4=$G(^RMPR(661.1,RM6611,4))
12 S RMCP11=$G(^RMPR(661.1,RM6611,0))
13 S RMCP5=$G(^RMPR(661.1,RM6611,5))
14 S RMCRF=$P(RMCP5,U,1)
15 S (RMCPT1,RMCPHC)=$P(RMCP4,U,1),RMCPT=""
16 S RMHCPCS=$P(RMCP11,U,1),RMCPHC2=$E(RMHCPCS,1,2)
17 S RMCPSO="V"
18 ;set CPT MODIFIER field in 664.1 to null if HCPCS has no CPT modifier.
19 I RMCPT1="" S $P(^RMPR(664.1,DA(1),2,DA,2),U,2)=RMCPT,X=RM6611 G KILL
20 ;next code will be used for different CPT Modifiers.
21 ;G:$D(D6I) QH
22 I (RMCPT1["LT"),(RMCPT1["RT") D LRT G:$D(DUOUT)!$D(DTOUT)!$D(DIRUT) EXIT
23 I (RMCPT1["KM"),(RMCPT1["KN") D KMN G:$D(DUOUT)!$D(DTOUT)!$D(DIRUT) EXIT
24 I RMCPT1["RR",$G(RMCRF) D RR G:$D(DUOUT)!$D(DTOUT)!$D(DIRUT) EXIT
25 I RMCPT1["RP" D RP G:$D(DUOUT)!$D(DTOUT)!$D(DIRUT) EXIT
26 I RMCPT1["PL" D PL G:$D(DUOUT)!$D(DTOUT)!$D(DIRUT) EXIT
27 I RMCPT1["UE" D UE G:$D(DUOUT)!$D(DTOUT)!$D(DIRUT) EXIT
28 I RMCPT1["NU" D NU G:$D(DUOUT)!$D(DTOUT)!$D(DIRUT) EXIT
29 I (RMCPT1["GY") D GY
30 I (RMCPT1["QH") D QH
31 I RMCPT1["KA" D KA
32EXIT ;CLEAN-UP
33 S RMCLEN=$L(RMCPT),RMCPT=$E(RMCPT,1,RMCLEN-1)
34 S $P(^RMPR(664.1,DA(1),2,DA,2),U,2)=RMCPT,X=RM6611
35KILL K DIR,RM6611,RMCPT1,RMCPSO,RMCP0,RMCP4,RMCRF,RMCBW,RMCPT5,RMHCPCS,RMCP11,RMCLEN,RMCP5,RMCPHC2,RMCPHC
36 Q
37LRT ;prompt for LEFT OR RIGHT CPT modifier
38 K DIR
39 S DIR(0)="SBO^LT:Left;RT:Right;B:Both Left and Right"
40 S DIR("A")="Enter a CPT MODIFIER for HCPCS "_RMHCPCS
41 D ^DIR I $D(DUOUT)!$D(DTOUT)!($D(Y)&(Y="")) W !,"This is a required field!!!" G LRT
42 I Y="B" S Y="LT,RT"
43 S RMCPT=RMCPT_Y_","
44 Q
45 ;
46KMN ;prompt for new impression/moulage or previous master model.
47 K DIR
48 S DIR(0)="SBO^KM:new impression/moulage;KN:previous master model"
49 S DIR("A")="Enter a CPT MODIFIER for HCPCS "_RMHCPCS
50 D ^DIR I $D(DUOUT)!$D(DTOUT)!($D(Y)&(Y="")) W !,"This is a required field!!!" G KMN
51 S RMCPT=RMCPT_Y_","
52 Q
53 ;
54RR ;Append "RR" cpt modifier"
55 S DIR(0)="Y"
56 S DIR("A")="Is this RENTAL "
57 S DIR("?")="Enter 'Y for YES' or 'N for NO' ",DIR("B")="Y"
58 D ^DIR K DIR I $D(DUOUT)!$D(DTOUT) W !,"This is a required field!!!" G RR
59 S:$G(Y) RMCPT=RMCPT_"RR,"
60 Q
61 ;
62RP ;append "RP" cpt modifier.
63 I $D(RMTYPE),((RMTYPE="R")!(RMTYPE="X")) S RMCPT=RMCPT_"RP,"
64 Q
65 ;
66UE ;append "UE" cpt modifier.
67 I RMCPSO="V" S RMCPT=RMCPT_"UE,"
68 Q
69 ;
70NU ;append "NU" cpt modifier.
71 I (RMCPSO="C"),(RMCPT'["RR") S RMCPT=RMCPT_"NU,"
72 Q
73 ;
74QH ;append "QH" CPT modifier for Home Oxygen.
75 S RMCPT=RMCPT_"QH,"
76 Q
77 ;
78PL ;Append PL cpt modifier.
79 S RMCPT=RMCPT_"PL,"
80 Q
81 ;
82KA ;Append KA cpt modifier for HCPCS that contains wheelchair accessories.
83 S RMCPT=RMCPT_"KA,"
84 Q
85 ;
86GY ;Append GY CPT Modifier.
87 S RMCPT=RMCPT_"GY,"
88 Q
Note: See TracBrowser for help on using the repository browser.