source: FOIAVistA/tag/r/REGISTRATION-DGQE-DG-DPT-GRPX-VAD-VAF-VAS-VAT-VAU--VA-VIC--DGBT--DGJ--DGYA--VALM/DGPFUT5.m@ 636

Last change on this file since 636 was 628, checked in by George Lilly, 14 years ago

initial load of FOIAVistA 6/30/08 version
File size: 4.3 KB
Line 
1DGPFUT5 ;ALB/SAE - PRF UTILITIES CONTINUED ; 12/18/03 09:00pm
2 ;;5.3;Registration;**554**;Aug 13, 1993
3 ;
4 Q ; no direct entry
5 ;
6DISPLAY(TXN,DGPFGOUT) ; entry point for user-review screen
7 ;
8 ; This routine completes the re-display process.
9 ; It re-displays information about the Flag, or Flag Assignment,
10 ; being created or modified by the user, prior to the 'file' question.
11 ;
12 ; Input:
13 ; TXN - transaction - has several '^' pieces starting with:
14 ; FA - FLAG ASSIGNMENT - Assign Flag
15 ; FA - FLAG ASSIGNMENT - Edit Flag Assignment
16 ; FA - FLAG ASSIGNMENT - Change Assignment Ownership
17 ; FM - FLAG MANAGEMENT - Add New Record Flag
18 ; FM - FLAG MANAGEMENT - Edit Record Flag
19 ; DGPFGOUT - name of global ^TMP global used to display
20 ;
21 ; Output:
22 ; none - display to user only
23 ;
24 ; Temporary variables:
25 N DIR,DIROUT,DIRUT,DTOUT,DUOUT,X,Y ; DIR Reader variables
26 ;
27 F D I Y=0!$D(DUOUT)!$D(DTOUT) W ! Q
28 . D DISP(TXN,DGPFGOUT)
29 . W ! S DIR(0)="Y",DIR("A")="Do you want to review again"
30 . S DIR("B")="NO" D ^DIR K DIR
31 ;
32 Q
33 ;
34DISP(TXN,DGPFGOUT) ; display user review screen(s):
35 ;
36 ; Re-displays information about the Flag or Flag Assignment being
37 ; created or modified.
38 ;
39 ; Input:
40 ; TXN - transaction - has several pieces starting with:
41 ; FA - FLAG ASSIGNMENT - Assign Flag
42 ; FA - FLAG ASSIGNMENT - Edit Flag Assignment
43 ; FA - FLAG ASSIGNMENT - Change Assignment Ownership
44 ; FM - FLAG MANAGEMENT - Add New Record Flag
45 ; FM - FLAG MANAGEMENT - Edit Record Flag
46 ; DGPFGOUT - name of global ^TMP global used to display
47 ;
48 ; Output:
49 ; none - display to user only
50 ;
51 ; Temporary variables:
52 N DGPFQUIT ; quit variable for loop
53 N DGPFCT ; counter variable for loop
54 N DGPFNEW ; new page indicator
55 N DIR,DIROUT,DIRUT,DTOUT,DUOUT,X,Y ; DIR Reader variables
56 N DGPFHDR ; used for new screens of word processing displays
57 N DGPFTHIS ; value of current node
58 ; DGPFTHIS("HEADER") ; this node in global array is a header
59 N DGPFNEXT ; next node in global array
60 N DGPFLAST ; prevents page feed and display of headers with no body
61 N DGPFLINE ; line for underlining headers
62 N DGPFPINV ; counter to control display of principal investigator label
63 N DGPFPAD ; pad for leading spaces
64 N DGPFACT ; ACTION as upper case
65 ;
66 S DGPFCT=0
67 S DGPFACT=$TR($P(TXN,U,3),"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")
68 S DGPFHDR("TOP")="REVIEW OF "_DGPFACT_" DATA INPUT BEFORE FILING"
69 ;
70 S DGPFLINE="",$P(DGPFLINE,"-",($L(DGPFHDR("TOP"))+1))=""
71 S DGPFHDR("TOPLINE")=DGPFLINE
72 S DGPFPINV=0
73 ;
74 W:$E(IOST,1,2)="C-" @IOF
75 W DGPFHDR("TOP"),!,DGPFHDR("TOPLINE")
76 F S DGPFCT=$O(@DGPFGOUT@(DGPFCT)) Q:DGPFCT="" D Q:$D(DGPFQUIT)
77 . K DGPFTHIS,DGPFNEXT
78 . S DGPFTHIS=@DGPFGOUT@(DGPFCT,0)
79 . S DGPFNEXT=$O(@DGPFGOUT@(DGPFCT))
80 . S DGPFNEXT=$S(DGPFNEXT="":"",1:@DGPFGOUT@(DGPFNEXT,0))
81 . S:$O(@DGPFGOUT@(DGPFCT))="" DGPFLAST=1
82 . ;
83 . I DGPFTHIS["Principal Investigator(s):" S DGPFPINV=DGPFPINV+1
84 . I DGPFTHIS["Action Comments:" S DGPFTHIS("HEADER")=1
85 . I DGPFTHIS["Flag Description:" S DGPFTHIS("HEADER")=1
86 . I DGPFTHIS["Reason For Flag Enter/Edit:" S DGPFTHIS("HEADER")=1
87 . I DGPFTHIS["Record Flag Assignment Narrative:" S DGPFTHIS("HEADER")=1
88 . I DGPFNEXT["Action Comments:" S DGPFNEXT("HEADER")=1
89 . I DGPFNEXT["Flag Description:" S DGPFNEXT("HEADER")=1
90 . I DGPFNEXT["Reason For Flag Enter/Edit:" S DGPFNEXT("HEADER")=1
91 . I DGPFNEXT["Record Flag Assignment Narrative:" S DGPFNEXT("HEADER")=1
92 . I $D(DGPFTHIS("HEADER")) S DGPFHDR(1)=DGPFTHIS D
93 . . S DGPFLINE=" ",$P(DGPFLINE,"-",($L(DGPFHDR(1))-1))=""
94 . ;
95 . ; if near the bottom, set new screen variable DGPFNEW
96 . I $Y+9>IOSL I $D(DGPFTHIS("HEADER"))!($Y+6>IOSL) S DGPFNEW=1
97 . I $D(DGPFNEW),'$D(DGPFLAST) D Q
98 . . K DGPFNEW W ! S DIR(0)="E" D ^DIR K DIR
99 . . I $D(DUOUT)!$D(DTOUT) S DGPFQUIT=1 Q
100 . . W:$E(IOST,1,2)="C-" @IOF
101 . . W DGPFHDR("TOP"),!,DGPFHDR("TOPLINE")
102 . . I $D(DGPFHDR(1)) D
103 . . . I DGPFTHIS?1." ",$D(DGPFNEXT("HEADER")) Q
104 . . . W !,DGPFHDR(1),!,DGPFLINE
105 . . W:'$D(DGPFTHIS("HEADER")) !,DGPFTHIS
106 . . I DGPFTHIS["Principal Investigator(s):" S DGPFPINV=1
107 . W:$D(DGPFTHIS("HEADER")) !
108 . ; remove label from Principal Investigator line if not first node
109 . I DGPFTHIS["Principal Investigator(s):",DGPFPINV>1 D
110 . . S DGPFPAD=$E($J("",27),1,27)
111 . . S DGPFTHIS=DGPFPAD_$P(DGPFTHIS,":",2)
112 . W !,DGPFTHIS
113 . W:$D(DGPFTHIS("HEADER")) !,DGPFLINE
114 W !
115 ;
116 Q
Note: See TracBrowser for help on using the repository browser.