SDWLE113 ;IOFO BAY PINES/TEH - WAITING LIST-ENTER/EDIT ;20 Aug 2002  2:10 PM
 ;;5.3;scheduling;**263,273,394**;AUG 13 1993
 ;
 ;
 ;******************************************************************
 ;                             CHANGE LOG
 ;                                               
 ;   DATE                        PATCH                   DESCRIPTION
 ;   ----                        -----                   -----------
 ; 11/27/02                      SD*5.3*273              Add "/" to line EN1+2  
 ; 12/10/04                      SD*5.3*394              Sets SERVICE CONNECTED PRIORITY in WAIT LIST (409.3)
 ;   
 ;
EN ;Set record status to 'OPEN'
 ;
 N SDWLERR S DR="23////^S X=""O""",DIE="^SDWL(409.3," D ^DIE
 ;
 ;Ask comments
 ;
 I $D(^SDWL(409.3,SDWLDA,0)) I $P(^(0),U,18)'="" S DIR("B")=$P(^(0),U,18)
 S DIR(0)="FAOU^^",DIR("A")="Comments: " D ^DIR
 I Y["^" S SDWLERR=2 Q
 I X="@" S DR="25///@",DIE="^SDWL(409.3,",DA=SDWLDA D ^DIE G EN0
 S SDWLCOM=Y
 S DR="25////^S X=SDWLCOM",DIE="^SDWL(409.3,",DA=SDWLDA D ^DIE
 ;
 ;SET SERVICE CONNECTION PRIORITY
 ;
EN0 I $D(SDWLNSC),$D(^SDWL(409.3,SDWLDA)) D
 .S SDWLNSCP=$$GET1^DIQ(2,SDWLDFN_",",.302)
 .S DIE="^SDWL(409.3,",DA=SDWLDA,DR="14////^S X=SDWLNSCP" D ^DIE
 .S DR="15////^S X=SDWLNSC" D ^DIE
 K SDWLNSC,SDWLNSCP
 ;
EN1 ;Set Editing User
 ;
 S DR="28////^S X=DUZ",DIE="^SDWL(409.3," D ^DIE
 ;
 S SDWLERR=0 Q
 Q
 ;
END K SDWLCN,SDWLCN,SDWLY,SDWLNEW,SDWLSSN,SDWLNAM,SDWLDATA,SDWLIN,SDWLCL,SDWLTY,SDWLST,SDWLSP,SDWLSS
 K SDWLSC,SDWLPRI,SDWLRB,SDWLPROV,SDWLDAPT,SDWLST,SDWLCOM,SDWLDUZ,SDWLEDT,SDCL,SDWLTYE,SDWLINE,SDWLS,SDWLX,SDWLPRIE,SDWLPRVE
 K SDWLDAPE,SDWLRBE,SDWL,VA,VADM,VAIN,D0,DA,DI,DIC,DIE,DQ,DR,SDWLCLN,SDWLCNT,SDWLDIS,SDWLDISN,SDWLDT
 K SDWLDTP,SDWLINN,SDWLPRIN,SDWLTYN,SDWLB,SDWLCPT,SDWLFLG,SDWLPS,SDWLRNE,SDWLSCO,SDWLSCR,SDWLSPO,SDWLSCR,SDWLSPO,SDWLSSO
 K SDWLWR,VAERR,YY,MM,DD,SDWLSCP,SDWLVAR,SDWLF,SDWLSX,SDWLCP1,SCWLCP2,SDSWLTAG,SDWLTT,SDWLVBR,SDWLYN,X,Y
 K SDWLCP2,SDWLCP3,SDWLCP4,SDWLCP5,SDWLCP6,E,SDWLCOME,SDWLDFN,SDWLPCMM
 K DIR,SDWLSTO,SDWLINA,SDWLPOS,SDWLTEM,SDWLOPT,DUOUT
 I $D(SDWLDA),SDWLDA'="",$D(^SDWL(409.3,SDWLDA,0)),$P(^SDWL(409.3,SDWLDA,0),U,17)'["O" D
 .W !!,?15,"***  Patient being Removed from Wait List  ***" S DIK="^SDWL(409.3,",DA=SDWLDA D ^DIK S DUOUT=1
 K SDWLDA
 Q