source: FOIAVistA/tag/r/SURGERY-SR/SROALMN.m@ 628

Last change on this file since 628 was 628, checked in by George Lilly, 14 years ago

initial load of FOIAVistA 6/30/08 version

File size: 4.6 KB
Line 
1SROALMN ;BIR/ADM - LIST OF 1-LINER CASES WITH MISSING INFO ;05/04/07
2 ;;3.0; Surgery ;**153,160**;24 Jun 93;Build 7
3 S (GRAND,SRNEW,SRSOUT,TOT)=0,(SRHDR,SRPAGE)=1,SRTITLE="1-LINER CASES MISSING INFORMATION" K ^TMP("SRA",$J)
4 I SRFLG,SRASP S SRSPEC=$P(^SRO(137.45,SRASP,0),"^")
5 F S SRSD=$O(^SRF("AC",SRSD)) Q:'SRSD!(SRSD>SRED)!SRSOUT S SRTN=0 F S SRTN=$O(^SRF("AC",SRSD,SRTN)) Q:'SRTN!SRSOUT I $D(^SRF(SRTN,0)),$$MANDIV^SROUTL0(SRINSTP,SRTN) D UTL
6 I SRSP S SRSS="" F S SRSS=$O(^TMP("SRA",$J,SRSS)) Q:SRSS="" D SRSD Q:SRSOUT D:TOT TOT
7 I 'SRSP S SRNEW=1,(SRSD,TOT)=0 F S SRSD=$O(^TMP("SRA",$J,SRSD)) Q:'SRSD!SRSOUT S SRTN=0 F S SRTN=$O(^TMP("SRA",$J,SRSD,SRTN)) Q:'SRTN S SRA=^(SRTN) D CASE Q:SRSOUT
8 Q:SRSOUT I SRSP,'SRFLG,GRAND D GRAND
9 I SRFLG,'GRAND S SRSS=SRSPEC D HDR,GRAND
10 I SRSP,'SRFLG,'GRAND S SRSS="" D HDR,GRAND
11 I 'SRSP,'GRAND S SRSS="" D HDR,GRAND
12 I 'SRSP,GRAND S SRSS="" D GRAND
13 Q
14UTL ; set up TMP global
15 I '$P($G(^SRF(SRTN,.2)),"^",3)&'$P($G(^SRF(SRTN,.2)),"^",12) Q
16 I $P($G(^SRF(SRTN,30)),"^") Q
17 S SRA=$G(^SRF(SRTN,"RA")) I $P(SRA,"^",2)="N",$P(SRA,"^",6)="Y" Q
18 I SRFLG,$P(^SRF(SRTN,0),"^",4)'=SRASP Q
19 I SRSP S SRSS=$P(^SRF(SRTN,0),"^",4),SRSS=$S(SRSS:$P(^SRO(137.45,SRSS,0),"^"),1:"SPECIALTY NOT ENTERED"),^TMP("SRA",$J,SRSS,SRSD,SRTN)=SRA Q
20 S ^TMP("SRA",$J,SRSD,SRTN)=SRA
21 Q
22SRSD S SRNEW=1,(SRSD,TOT)=0 F S SRSD=$O(^TMP("SRA",$J,SRSS,SRSD)) Q:'SRSD!SRSOUT S SRTN=0 F S SRTN=$O(^TMP("SRA",$J,SRSS,SRSD,SRTN)) Q:'SRTN S SRA=^(SRTN) D CASE Q:SRSOUT
23 Q
24CASE I $P(SRA,"^",2)="N",$P(SRA,"^",6)="N" S SRATYPE="EXCLUDED"
25 S:$P(SRA,"^",2)="C" SRATYPE="CARDIAC" S:$P(SRA,"^",2)="" SRATYPE="NON-ASSESSED" D LNR
26 S SRFLD="" I $O(SRX(SRFLD))'="" S TOT=TOT+1,GRAND=GRAND+1 D PRINT Q
27 I '$P($G(^SRO(136,SRTN,10)),"^")!('$P($G(^SRO(136,SRTN,0)),"^",2))!('$P($G(^SRO(136,SRTN,0)),"^",3)) D PRINT
28 Q
29LNR ; check for missing 1-liner information
30 K SRX,DA,DIC,DIQ,DR,SRY S DIC="^SRF(",DA=SRTN,DIQ="SRY",DIQ(0)="I"
31 I SRATYPE'="EXCLUDED" S DR=".011;.03;.04;.035;.166;1.09;1.13"
32 I SRATYPE="EXCLUDED" S DR=".035;.03;102"
33 D EN^DIQ1 D ^SROAUTL2 K DA,DIC,DIQ,DR,SRY,SRZ
34 D TECH^SROPRIN I SRTECH="NOT ENTERED" S SRX("ANESTHESIA TECHNIQUE")="Anesthesia Technique"
35 Q
36PRINT ; print assessments
37 K SRCPTT S SRCPTT="NOT ENTERED"
38 I $Y+5>IOSL!SRNEW D PAGE I SRSOUT Q
39 S SRA(0)=^SRF(SRTN,0),DFN=$P(SRA(0),"^") N I D DEM^VADPT S SRANM=VADM(1),SRASSN=VA("PID") K VADM
40 I $L(SRANM)>19 S SRANM=$P(SRANM,",")_","_$E($P(SRANM,",",2))_"."
41 S SROPER=$P(^SRF(SRTN,"OP"),"^") I $O(^SRF(SRTN,13,0)) S SROTHER=0 F I=0:0 S SROTHER=$O(^SRF(SRTN,13,SROTHER)) Q:'SROTHER D OTHER
42 K SROPS,MM,MMM S:$L(SROPER)<63 SROPS(1)=SROPER I $L(SROPER)>62 S SROPER=SROPER_" " F M=1:1 D LOOP Q:MMM=""
43 S X=$P(SRA,"^"),SRSTATUS=$S(X="T":"TRANSMITTED",X="C":"COMPLETE",X="I":"INCOMPLETE",1:"NO ASSESSMENT"),Y=SRSD D D^DIQ S SRDT=$P(Y,"@")
44 I $Y+5>IOSL D PAGE I SRSOUT Q
45 W !,SRTN,?18,SRANM_" "_VA("PID"),?53,SRATYPE,?67,SRSTATUS,!,SRDT F I=1:1 Q:'$D(SROPS(I)) W ?18,SROPS(I),!
46 N I,SRPROC,SRL S SRL=100 D CPTS^SROAUTL0 W ?18,"CPT Codes: "
47 F I=1:1 Q:'$D(SRPROC(I)) W:I=1 ?29,SRPROC(I) W:I'=1 !,?29,SRPROC(I)
48 S CNT=1 W !,?5,"Missing information:"
49 I '$P($G(^SRO(136,SRTN,10)),"^")!('$P($G(^SRO(136,SRTN,0)),"^",2))!('$P($G(^SRO(136,SRTN,0)),"^",3)) W !,$J(CNT_". ",8),"The final coding for Procedure and Diagnosis is not complete." S CNT=CNT+1
50 F S SRFLD=$O(SRX(SRFLD)) Q:SRFLD="" D:$Y+5>IOSL PAGE Q:SRSOUT W !,$J(CNT_". ",8),SRX(SRFLD) S CNT=CNT+1
51 I 'SRSOUT W ! F LINE=1:1:80 W "-"
52 Q
53OTHER ; other operations
54 S SRLONG=1 I $L(SROPER)+$L($P(^SRF(SRTN,13,SROTHER,0),"^"))>125 S SRLONG=0,SROTHER=999,SROPERS=" ..."
55 I SRLONG S SROPERS=$P(^SRF(SRTN,13,SROTHER,0),"^")
56 S SROPER=SROPER_$S(SROPERS'=" ...":", "_SROPERS,1:SROPERS)
57 Q
58LOOP ; break procedures
59 S SROPS(M)="" F LOOP=1:1 S MM=$P(SROPER," "),MMM=$P(SROPER," ",2,200) Q:MMM="" Q:$L(SROPS(M))+$L(MM)'<63 S SROPS(M)=SROPS(M)_MM_" ",SROPER=MMM
60 Q
61PAGE I $E(IOST)="P"!SRHDR G HDR
62 W !!,"Press <RET> to continue, or '^' to quit " R X:DTIME I '$T!(X["^") S SRSOUT=1 Q
63 I X["?" W !!,"If you want to continue the listing, press the 'Enter' key.",!,"Type '^' to return to the menu." G PAGE
64HDR ; print heading
65 W @IOF,!,?(80-$L(SRTITLE)\2),SRTITLE,?70,$J("PAGE "_SRPAGE,9) W:$E(IOST)="P" !,?(80-$L(SRINST)\2),SRINST W !,?(80-$L(SRFRTO)\2),SRFRTO
66 W:$E(IOST)="P" !,?(80-$L(SRPRINT)\2),SRPRINT I SRSP,SRSS'="" W !!,"** "_SRSS
67 W !!,"CASE #",?18,"PATIENT",?53,"TYPE",?67,"STATUS",!,"OP DATE",?18,"OPERATION(S)",! F LINE=1:1:80 W "="
68 S SRHDR=0,SRNEW=0,SRPAGE=SRPAGE+1
69 Q
70TOT W !!,"TOTAL FOR "_SRSS_": ",TOT
71 Q
72GRAND I 'SRSP W !!,"TOTAL: ",GRAND Q
73 I SRSP,'SRFLG W !!,"TOTAL FOR ALL SPECIALTIES: ",GRAND Q
74 I SRSP,SRFLG S SRSS=SRSPEC D TOT
75 Q
Note: See TracBrowser for help on using the repository browser.