source: FOIAVistA/tag/r/TEXT_INTEGRATION_UTILITIES-GMRP-TIU/TIUFHLP.m@ 636

Last change on this file since 636 was 628, checked in by George Lilly, 14 years ago

initial load of FOIAVistA 6/30/08 version
File size: 7.1 KB
Line 
1TIUFHLP ; SLC/MAM,JER - On-line help library: HELP ;4/23/97 11:19
2 ;;1.0;TEXT INTEGRATION UTILITIES;;Jun 20, 1997
3 ;
4HELP ; Action Help for TIUF Document Definition Templates A, C, H, J,T,D,X
5 N TIUX,ORU,ORUPRMT,VALMDDF,VALMPGE,CREATE,DTOUT,DIRUT,DIROUT
6 S TIUX=$$UPPER^TIULS(X),CREATE=$G(TIUFCBEG)
7 S VALMBCK="R",VALMSG=$$VMSG^TIUFL
8 D ONE:TIUX="?NEW",ONE:TIUX="?",TWO:TIUX="??",THREE:TIUX="???"
9HELPX I $D(DTOUT) S VALMBCK="Q"
10 Q
11 ;
12ONE ; Help for One ?.
13 ;Requires CREATE
14 I TIUX="?NEW" W !?3 D FULL^VALM1,ITEM(^TMP("TIUF",$J,"NEWHELP")) D Q ;Option Create
15 . W !," Enter ? for Help"
16 . W !," Enter ?? for detailed help on actions including PRINTING"
17 . W !," Enter ??? for detailed help on display"
18 . D PAUSE^TIUFXHLX
19 I TIUFTMPL="C",'$D(TIUFSTMP) W !,TIUFCMSG(1),!,TIUFCMSG(2),! W:$D(TIUFCMSG(3)) TIUFCMSG(3),! D PAUSE^TIUFXHLX Q:$D(DIRUT)
20 D DISP^XQORM1 D PAUSE^TIUFXHLX Q:$D(DIRUT)
21 W !!," Type action name from Action List. Example: Type 'D' or 'DET' for Detailed",!,"Display. There are also 'Hidden Actions' which don't show on the Action List",!,"such as PL Print List."
22 W " Enter ?? to see hidden actions, and for",!,"descriptions of actions."
23 D PAUSE^TIUFXHLX Q:$D(DIRUT)
24 W !," Action and Entry Number can be selected in a single step. Examples: To see a",!,"Detailed Display of Entry 3, enter 'DET=3'. To scroll to the extreme right,",!,"enter '>=>'.",!
25 D PAUSE^TIUFXHLX Q:$D(DIRUT)
26 I ("HACJ"[TIUFTMPL&'$D(TIUFSTMP))!($G(TIUFSTMP)="T") D Q:$D(DIRUT)
27 . W !!,"To see more columns of essential information, enter '>' to scroll to the right",!,"whenever >>> shows on the highlighted message bar. Enter '<' to scroll left.",!!
28 . D PAUSE^TIUFXHLX
29 W !," Enter ? for Help"
30 W !," Enter ?? for detailed help on actions including PRINTING"
31 W !," Enter ??? for detailed help on display",!
32 I TIUFTMPL="C" W " Enter '?NEW' for New User Help"
33 D PAUSE^TIUFXHLX Q:$D(DIRUT)
34 W !," When editing a field (as opposed to Selecting an Action), ? will give you one"
35 W !,"line of help on the field. ?? will give you a complete description of the"
36 W !,"field and how it works.",!
37 D PAUSE^TIUFXHLX
38 Q
39 ;
40TWO ; Help for ??
41 D FULL^VALM1,CLEAR^VALM1
42 W !!,$$CENTER^TIUFL("Help on Listed Actions",80),!!
43 W !,"Actions are not selectable when they are enclosed in parentheses.",!!
44 K DIRUT D MENU(XQORNOD) Q:$D(DIRUT)
45 W !!,$$CENTER^TIUFL("Help on Hidden Actions including PRINTING",80),!!
46 D MENU(^TMP("TIUF",$J,"HIDDEN"))
47 Q
48 ;
49THREE ; Help for ???
50 D FULL^VALM1,CLEAR^VALM1
51 I "HACJ"[TIUFTMPL,'$D(TIUFSTMP) D BASINFD
52 I $G(TIUFSTMP)="T" D ITEMINFD
53 I $G(TIUFSTMP)="D" D EDITVW^TIUFHLP1
54 I $G(TIUFSTMP)="X" D BOILTX^TIUFHLP1
55 Q
56 ;
57BASINFD ; Write Field Description for Basic Info Fields
58 N TIUI,FLDNM,FLDNO,MSG,HERE
59 W !,$$CENTER^TIUFL("Help on Display",80),! K DIROUT
60 F FLDNO=.01,.04,.1,.13,.07,.05,.06,.08,.12,.03,.11 D Q:$D(DIROUT)
61 . I $G(TIUFTMPL)="J",(FLDNO=.1)!(FLDNO=.08)!(FLDNO=.12)!(FLDNO=.11) Q
62 . S FLDNM=$P(^TMP("TIUF",$J,FLDNO,"LABEL"),U)
63 . K DIRUT W:$$CONTINUE !?1,$G(IOINHI),FLDNM,$G(IOINORM),! Q:$D(DIRUT)
64 . I FLDNO=.01,TIUFTMPL="H",'$D(TIUFSTMP) W !," Plus (+) indicates entry has Items under it and can be expanded.",!!
65 . D HELP^DIE(8925.1,"",FLDNO,"D")
66 . S HERE=1 I $G(TIUFTMPL)="J",(FLDNO=.04)!(FLDNO=.07)!(FLDNO=.01) S HERE=0
67 . F TIUI=1:1:DIHELP S MSG=^TMP("DIHELP",$J,TIUI) K DIRUT D Q:$D(DIRUT)
68 . . I FLDNO=.04,$G(TIUFTMPL)="J",MSG["O OBJECT" S HERE=1
69 . . I FLDNO=.07,$G(TIUFTMPL)="J",MSG["OBJECT STATUS",MSG'["OBJECT STATUS," S HERE=1
70 . . I FLDNO=.01,$G(TIUFTMPL)="J",MSG["OBJECT Name" S HERE=1
71 . . W:HERE&$$CONTINUE ?3,MSG,!
72 D CLEAN^DILF
73 Q
74 ;
75ITEMINFD ; Write Field Description for Item Fields
76 N TIUI,FLDNM,FLDNO,MSG
77 W !,$$CENTER^TIUFL("Help on Display",80),! K DIROUT
78 F FLDNO=10 D Q:$D(DIROUT)
79 . S FLDNM=^TMP("TIUF",$J,FLDNO,"LABEL")
80 . K DIRUT W:$$CONTINUE !?1,$G(IOINHI),FLDNM,$G(IOINORM),! Q:$D(DIRUT)
81 . D HELP^DIE(8925.1,"",FLDNO,"D")
82 . F TIUI=1:1:DIHELP S MSG=^TMP("DIHELP",$J,TIUI) K DIRUT D Q:$D(DIRUT)
83 . . W:$$CONTINUE ?3,MSG,!
84 K DIROUT F FLDNO=2:1:4 D Q:$D(DIROUT)
85 . S FLDNM=^TMP("TIUF",$J,10,FLDNO,"LABEL")
86 . K DIRUT W:$$CONTINUE !?1,$G(IOINHI),FLDNM,$G(IOINORM),! Q:$D(DIRUT)
87 . D HELP^DIE(8925.14,"",FLDNO,"D")
88 . F TIUI=1:1:DIHELP S MSG=^TMP("DIHELP",$J,TIUI) K DIRUT D Q:$D(DIRUT)
89 . . W:$$CONTINUE ?3,MSG,!
90 D CLEAN^DILF
91 Q
92 ;
93MENU(XQORNOD) ; Unwind protocol menus for help
94 N TIUSEQ,TIUI,TIUJ
95 K DIRUT W:$$CONTINUE "The following actions are available:",! Q:$D(DIRUT)
96 S TIUI=0 F S TIUI=$O(^ORD(101,+XQORNOD,10,TIUI)) Q:+TIUI'>0 K DIRUT D Q:$D(DIRUT)
97 . S TIUJ=+$P($G(^ORD(101,+XQORNOD,10,TIUI,0)),U,3) S:$D(TIUSEQ(TIUJ)) TIUJ=TIUJ+.1
98 . S TIUSEQ(TIUJ)=+$P(^ORD(101,+XQORNOD,10,TIUI,0),U)
99 S TIUI=0 F S TIUI=$O(TIUSEQ(TIUI)) Q:+TIUI'>0 K DIRUT D Q:$D(DIRUT)
100 . I $D(^ORD(101,+TIUSEQ(TIUI),0)) D ITEM(+TIUSEQ(TIUI))
101 Q
102ITEM(XQORNOD) ; Show descriptions of protocol menu actions
103 N TIUI,TMPQUIT,HERE
104 Q:$P($G(^ORD(101,+XQORNOD,0)),U,2)']""
105 I $G(TIUFTMPL)="J",$G(TIUFSTMP)="D",(^ORD(101,+XQORNOD,0)["Items")!(^ORD(101,+XQORNOD,0)["Boil")!(^ORD(101,+XQORNOD,0)["Upload") Q
106 I $G(TIUFSTMP)="T",^ORD(101,+XQORNOD,0)["Try" Q
107 Q:XQORNOD=^TMP("TIUF",$J,"STOP") ;protocol TIUF QUIT1 in hidden actions - dummy to allow user to enter QU
108 ; ?NEW for create is contained in protocol TIUFC ACTION MENU; don't write the name of the protocol:
109 ; Note on heritable fields is contained in protocol TIUFD ACTION MENU MGR; don't write the name of the protocol:
110 I XQORNOD'=^TMP("TIUF",$J,"NEWHELP"),XQORNOD'=^TMP("TIUF",$J,"INHERIT") K DIRUT W:$$CONTINUE ?1,$G(IOINHI),$$UPPER^TIULS($P($G(^ORD(101,+XQORNOD,0)),U,2)),$G(IOINORM),! Q:$D(DIRUT)
111 S HERE=1 I $G(TIUFTMPL)="J",$G(^ORD(101,+XQORNOD,0))["Delete" S HERE=0
112 S TIUI=0 F S TIUI=$O(^ORD(101,+XQORNOD,1,TIUI)) Q:+TIUI'>0 K DIRUT D Q:$D(DIRUT)
113 . S LINE=$G(^ORD(101,+XQORNOD,1,TIUI,0))
114 . Q:'$$CONTINUE
115 . I 'HERE,LINE["OBJECT DELETE" S HERE=1
116 . I 'HERE Q
117 . ; ?NEW for create, note on heritable: first 2 lines aren't relevant:
118 . I XQORNOD=^TMP("TIUF",$J,"NEWHELP")!(XQORNOD=^TMP("TIUF",$J,"INHERIT")),TIUI<3 Q
119 . ;protocol description is written in 2 parts, first for clinicians, second for managers. Display appropriate part:
120 . I TIUFWHO="C" D
121 . . Q:LINE["CLINICIAN OPTIONS"
122 . . I LINE'["MANAGER OPTIONS" W ?3,$G(^ORD(101,+XQORNOD,1,TIUI,0)),! Q
123 . . S TIUI=5000
124 . I "NM"[TIUFWHO D
125 . . I LINE["CLINICIAN OPTIONS" S TMPQUIT=1 Q
126 . . I LINE["MANAGER OPTIONS" S TMPQUIT=0 Q
127 . . Q:$G(TMPQUIT)
128 . . W ?3,$G(^ORD(101,+XQORNOD,1,TIUI,0)),!
129 Q:XQORNOD=^TMP("TIUF",$J,"NEWHELP") ;don't show items of TIUFC ACTION MENU
130 Q:XQORNOD=^TMP("TIUF",$J,"INHERIT") ;don't show items of TIUFD ACTION MENU MGR
131 S TIUI=0 F S TIUI=$O(^ORD(101,+XQORNOD,10,TIUI)) Q:+TIUI'>0 K DIRUT D Q:$D(DIRUT)
132 . D ITEM(+$G(^ORD(101,+XQORNOD,10,+TIUI,0))_";ORD(101,")
133 Q
134CONTINUE() ; Pagination control
135 N Y K DIRUT
136 I $Y<(IOSL-2) S Y=1 G CONTX
137 S Y=$$BOTTM W @IOF,!
138CONTX Q Y
139 ;
140BOTTM() ; Call DIR at bottom of screen
141 N DIR,X,Y
142 I $E(IOST)'="C" S Y=1 G BOTTX
143 I (IOSL>($Y+5)) F W ! Q:IOSL<($Y+6)
144 S DIR(0)="FO^1:1",DIR("A")="Press RETURN to continue or '^' or '^^' to exit"
145 S DIR("?")="Enter '^' to quit present section or '^^' to quit to menu"
146 D ^DIR I $D(DIRUT),(Y="") K DIRUT
147 S Y=$S(Y="^"!(Y="^^"):Y,$D(DTOUT):"",1:1)
148BOTTX Q Y
Note: See TracBrowser for help on using the repository browser.