source: FOIAVistA/trunk/r/CLINICAL_PROCEDURES-MD/MDPOST.m@ 1154

Last change on this file since 1154 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 3.4 KB
Line 
1MDPOST ; HOIFO/DP - Post Init ;2/18/04 11:39
2 ;;1.0;CLINICAL PROCEDURES;;Apr 01, 2004
3 ; Integration Agreements:
4 ; IA# 2263 [Supported] XPAR Utilities
5 ; IA# 3006 [Supported] Calls to XMXAPIG
6 ; IA# 10141 [Supported] Calls to XPDUTL
7 ;
8EN ; [Procedure] Setup preliminary parameters
9 ; This submodule is called during the KIDS installation
10 ; process.
11 ;
12 ; Variables:
13 ; DIK: [Private] Fileman delete variable
14 ; MDCLIENT: [Private] Current client version (#.#.#.#)
15 ; MDFILE: [Private] Scratch
16 ; MDRET: [Private] Scratch
17 ; MDX: [Private] Scratch
18 ;
19 ; New private variables
20 NEW DIK,MDCLIENT,MDFILE,MDRET,MDX
21 W $$MSG("Setting compatible client versions")
22 D XPARDEL("MD VERSION CHK",1)
23 D XPARDEL("MD CRC VALUES",1)
24 S MDCLIENT="1.0.0.0" D
25 .D SETPAR("MD VERSION CHK","CPUSER.EXE:"_MDCLIENT,1)
26 .D SETPAR("MD VERSION CHK","CPMANAGER.EXE:"_MDCLIENT,1)
27 .D SETPAR("MD VERSION CHK","CPGATEWAY.EXE:"_MDCLIENT,1)
28 .D SETPAR("MD CRC VALUES","CPUSER.EXE:"_MDCLIENT,"9FCFC891")
29 .D SETPAR("MD CRC VALUES","CPMANAGER.EXE:"_MDCLIENT,"85F451A6")
30 .D SETPAR("MD CRC VALUES","CPGATEWAY.EXE:"_MDCLIENT,"411D7A05")
31 ;
32 W $$MSG("Applying latest set of valid file types")
33 D GETLST^XPAR(.MDRET,"SYS","MD FILE EXTENSIONS")
34 F MDX=0:0 S MDX=$O(MDRET(MDX)) Q:'MDX D
35 .D DEL^XPAR("SYS","MD FILE EXTENSIONS",$P(MDRET(MDX),"^",1))
36 F MDX=1:1 S MDFILE=$P($T(FILEDAT+MDX),";;",2) Q:MDFILE="**END**" D
37 .D SETPAR("MD FILE EXTENSIONS",$P(MDFILE,U,1),$P(MDFILE,U,2))
38 ;
39 W $$MSG("Setting CP web link")
40 D SETPAR("MD WEBLINK",1,$$URL())
41 ;
42 W $$MSG("Validating Mail Group 'MD DEVICE ERRORS' membership")
43 D:'$$GOTLOCAL^XMXAPIG("MD DEVICE ERRORS")
44 .D MES^XPDUTL("There are no local users in the mail group.")
45 .D MES^XPDUTL("Adding '"_$$GET1^DIQ(200,DUZ_",",.01)_"'...")
46 .D ADDMBRS^XMXAPIG(DUZ,"MD DEVICE ERRORS",DUZ)
47 Q
48 ;
49INIT ; [Procedure] Build Procedure File
50 D INITPF^MDPOST1
51 Q
52 ;
53MSG(TEXT) ; [Procedure] Display message to user
54 ; Input parameters
55 ; 1. TEXT [Literal/Required] Text to display to the user
56 ;
57 D MES^XPDUTL(" MDPOST-"_TEXT_"...")
58 D MES^XPDUTL("")
59 Q ""
60 ;
61SETPAR(PAR,INS,VAL) ; [Procedure] Set value into XPAR parameter
62 ; Input parameters
63 ; 1. PAR [Literal/Required] Parameter
64 ; 2. INS [Literal/Required] Instance
65 ; 3. VAL [Literal/Required] New value
66 ;
67 D EN^XPAR("SYS",PAR,INS,VAL)
68 Q
69 ;
70XPARDEL(MDPAR,VALUES) ; [Procedure] Remove a parameter for XPAR
71 ; VALUES determines the mode of deletion.
72 ; 0: Will delete *BOTH* the values and the parameter definition (DEFAULT)
73 ; 1: Will only delete the values of the parameter
74 ;
75 ; Input parameters
76 ; 1. MDPAR [Literal/Required] Name of the parameter definition
77 ; 2. VALUES [Literal/] Values Only 0/1
78 ;
79 ; Variables:
80 ; DA: [Private] Fileman variable
81 ; DIK: [Private] Fileman variable
82 ; MDENT: [Private] Parameter entity
83 ;
84 ; New private variables
85 NEW DA,DIK,MDENT
86 S VALUES=$G(VALUES,0)
87 K ^TMP("MDPOST",$J)
88 D ENVAL^XPAR($NA(^TMP("MDPOST",$J)),MDPAR,"","",1)
89 S MDENT="" F S MDENT=$O(^TMP("MDPOST",$J,MDENT)) Q:MDENT="" D
90 .D NDEL^XPAR(MDENT,MDPAR)
91 K ^TMP("MDPOST",$J)
92 Q:VALUES
93 S DA=$$FIND1^DIC(8989.51,"","",MDPAR,"B") D:DA>0
94 .S DIK="^XTV(8989.51," D ^DIK
95 Q
96 ;
97URL() ; [Function] Return Clinical Procedures Homepage URL
98 Q "vista.med.va.gov/ClinicalSpecialties/clinproc/"
99 ;
100FILEDAT ; [Data Module] Allowable file types
101 ;;.txt^Text files
102 ;;.rtf^Rich text files
103 ;;.jpg^JPEG Images
104 ;;.jpeg^JPEG Images
105 ;;.bmp^Bitmap Images
106 ;;.tiff^TIFF Graphics
107 ;;.pdf^Portable Document Format
108 ;;.html^Hypertext Markup Language files
109 ;;**END**
Note: See TracBrowser for help on using the repository browser.