source: FOIAVistA/trunk/r/CONTROLLED_SUBSTANCES-PSD/PSDPUGS.m@ 1397

Last change on this file since 1397 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 4.6 KB
Line 
1PSDPUGS ;BIR/JPW-Green Sheets Ready for Pickup Log ; 29 Aug 94
2 ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97
3 I '$D(PSDSITE) D ^PSDSET Q:'$D(PSDSITE)
4 S OK=$S($D(^XUSEC("PSJ RPHARM",DUZ)):1,$D(^XUSEC("PSJ PHARM TECH",DUZ)):1,1:0)
5 I 'OK W $C(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to",!,?12,"print the Green Sheets Ready for Pickup Log.",!!,"PSJ RPHARM or PSJ PHARM TECH security key required.",! K OK Q
6ASKD ;ask disp loccation
7 S PSDS=$P(PSDSITE,U,3),PSDSN=$P(PSDSITE,U,4)
8 I $P(PSDSITE,U,5) S PSDS=PSDS_"^"_+$P($G(^PSD(58.8,+PSDS,0)),"^",5) G ASKN
9 K DIC,DA S DIC=58.8,DIC(0)="QEAZ",DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S($P(^(0),""^"",2)[""M"":1,$P(^(0),""^"",2)[""S"":1,1:0)"
10 S DIC("A")="Select Primary Dispensing Site: ",DIC("B")=$P(PSDSITE,U,4)
11 D ^DIC K DIC G:Y<0 END
12 S PSDS=+Y,PSDSN=$P(Y,"^",2),PSDS=PSDS_"^"_+$P(Y(0),"^",5)
13 S $P(PSDSITE,U,3)=+Y,$P(PSDSITE,U,4)=PSDSN
14ASKN ;ask naou or group
15 W !!,?5,"Select one of the following:",!!,?10,"N",?20,"NAOU (One, Some, or ^ALL)",!,?10,"G",?20,"Group of NAOUs",!
16 K DA,DIR,DIRUT S DIR(0)="SOA^N:NAOU;G:Group of NAOUs",DIR("A")="Select Method: "
17 S DIR("?",1)="Enter 'N' to select one, some or ^ALL NAOU(s).",DIR("?")="Enter 'G' to select a group of NAOUs, or '^' to quit"
18 D ^DIR K DIR G:$D(DIRUT) END S SEL=Y D NOW^%DTC S PSDT=X,PSDPT=+$E(%,1,12) K DA,DIC S CNT=0
19 I SEL="G" D GROUP G:'$D(PSDG) END G DEV
20 F S DIC=58.8,DIC("A")="Select NAOU: ",DIC(0)="QEA",DIC("S")="I $P(^(0),""^"",2)=""N"",'$P(^(0),""^"",7),$P(^(0),""^"",4)=+PSDS" D ^DIC K DIC Q:Y<0 D
21 .S NAOU(+Y)="",CNT=CNT+1
22 I '$D(NAOU)&(X'="^ALL") G END
23 S:X="^ALL" ALL=1
24DEV ;ask device and queue info
25 W !!,"You may queue this report to print at a later time.",!!
26 S Y=$P($G(^PSD(58.8,+PSDS,2)),"^",9),C=$P(^DD(58.8,24,0),"^",2) D Y^DIQ S PSDEV=Y
27 K %ZIS,IOP,IO("Q"),POP S %ZIS="QM",%ZIS("B")=PSDEV D ^%ZIS I POP W !,"NO DEVICE SELECTED OR REPORT PRINTED!" G END
28 I $D(IO("Q")) K IO("Q"),ZTIO,ZTSAVE,ZTDTH,ZTSK S ZTRTN="START^PSDPUGS",ZTDESC="CS Pharm Green Sheets Ready for Pickup Log" D SAVE,^%ZTLOAD,HOME^%ZIS K ZTSK G END
29 U IO
30START ;compile data
31 K ^TMP("PSDPUGS",$J)
32 I $D(PSDG) F PSD=0:0 S PSD=$O(PSDG(PSD)) Q:'PSD F PSDN=0:0 S PSDN=$O(^PSI(58.2,PSD,3,PSDN)) Q:'PSDN I $D(^PSD(58.8,PSDN,0)),'$P(^(0),"^",7),$P(^(0),"^",4)=+PSDS S NAOU(PSDN)="",CNT=CNT+1
33 I $D(ALL) F PSD=0:0 S PSD=$O(^PSD(58.8,PSD)) Q:'PSD I $D(^PSD(58.8,PSD,0)),$P(^(0),"^",2)="N",$P(^(0),"^",4)=+PSDS,'$P(^(0),"^",7) S NAOU(+PSD)=""
34 F PSD=0:0 S PSD=$O(^PSD(58.8,"AC",5,PSD)) Q:'PSD F DRUG=0:0 S DRUG=$O(^PSD(58.8,"AC",5,PSD,DRUG)) Q:'DRUG D
35 .F PSDA=0:0 S PSDA=$O(^PSD(58.8,"AC",5,PSD,DRUG,PSDA)) Q:'PSDA I $D(^PSD(58.8,PSD,1,DRUG,3,PSDA,0)) S NODE=^PSD(58.8,PSD,1,DRUG,3,PSDA,0) D
36 ..I $D(NAOU(PSD)),$P($G(^PSD(58.81,+$P(NODE,U,17),"CS")),U,4) S PSDNA=$S($P($G(^PSD(58.8,PSD,0)),"^")]"":$P(^(0),"^"),1:"ZZ/"_PSD) D
37 ...S DRUGN=$S($P($G(^PSDRUG(DRUG,0)),"^")]"":$P(^(0),"^"),1:"ZZ/"_DRUG),STAT=+$P(NODE,"^",11) Q:STAT'=5
38 ...S NUM=$P(NODE,"^",16),^TMP("PSDPUGS",$J,PSDNA,NUM,DRUGN)=""
39PRINT ;print green sheets ready for pickup by naou, green sheet #
40 S (PG,PSDOUT,NAOU)=0 D NOW^%DTC S Y=+$E(%,1,12) X ^DD("DD") S RPDT=Y
41 K LN S $P(LN,"-",80)="" I '$D(^TMP("PSDPUGS",$J)) D HDR W !!,?10,"**** NO PENDING GREEN SHEETS READY FOR PICKUP ****" G END
42 S NAOU="" F S NAOU=$O(^TMP("PSDPUGS",$J,NAOU)) Q:NAOU=""!(PSDOUT) D HDR Q:PSDOUT W !,?2,"=> NAOU: "_NAOU,! D Q:PSDOUT
43 .S NUM="" F S NUM=$O(^TMP("PSDPUGS",$J,NAOU,NUM)) Q:NUM=""!(PSDOUT) D:$Y+4>IOSL HDR Q:PSDOUT S DRUG=$O(^TMP("PSDPUGS",$J,NAOU,NUM,0)) Q:DRUG="" D
44 ..W !,NUM,?12,DRUG,?55,"__________",?68,"__________",!,?55,"(Pharmacy)",?70,"(Nurse)",!
45DONE I $E(IOST)'="C" W @IOF
46 I $E(IOST,1,2)="C-",'PSDOUT W ! K DIR,DIRUT S DIR(0)="EA",DIR("A")="END OF REPORT! Press <RET> to return to the menu" D ^DIR K DIR
47END K %,%H,%I,%ZIS,ALL,C,CNT,DA,DIC,DIR,DIROUT,DIRUT,DRUG,DRUGN,DTOUT,DUOUT,LN,NAOU,NODE,NUM
48 K OK,PG,POP,PSD,PSDA,PSDEV,PSDG,PSDIO,PSDN,PSDNA,PSDS,PSDSN,PSDOUT,PSDPT,PSDT,RPDT,SEL,STAT,X,Y,ZTDESC,ZTDTH,ZTRTN,ZTSAVE,ZTSK
49 K ^TMP("PSDPUGS",$J) D ^%ZISC
50 S:$D(ZTQUEUED) ZTREQ="@"
51 Q
52GROUP ;select group of naous
53 K DA,DIC F S DIC=58.2,DIC("A")="Select NAOU INVENTORY GROUP NAME: ",DIC(0)="QEA",DIC("S")="I $S($D(^PSI(58.2,""CS"",+Y)):1,1:0)" D ^DIC K DIC Q:Y<0 S PSDG(+Y)=""
54 Q
55SAVE S (ZTSAVE("PSDT"),ZTSAVE("CNT"),ZTSAVE("PSDS"))="" S:$D(PSDG) ZTSAVE("PSDG(")="" S:$D(NAOU) ZTSAVE("NAOU(")="" S:$D(ALL) ZTSAVE("ALL")=""
56 Q
57HDR ;header for log
58 I $E(IOST,1,2)="C-",PG W ! K DA,DIR S DIR(0)="E" D ^DIR K DIR I 'Y S PSDOUT=1 Q
59 S PG=PG+1 W:$Y @IOF W !,?25,"Green Sheets Ready for Pickup",?70,"Page: ",PG,!,?30,RPDT,!
60 W !,?57,"PICKED",?70,"GIVEN",!,"DISP #",?12,"DRUG",?57,"UP BY",?70,"TO BY"
61 W !,LN,!
62 Q
Note: See TracBrowser for help on using the repository browser.