| 1 | ENTINSD ;WOIFO/SAB - IT NON-SPACE FILE LOCATION DD CALLS ;2/4/2008
|
|---|
| 2 | ;;7.0;ENGINEERING;**87**;Aug 17, 1993;Build 16
|
|---|
| 3 | Q
|
|---|
| 4 | ;
|
|---|
| 5 | NSPT(DA,ENF) ; NON-SPACE FILE LOCATION triggers of the NON-SPACE FILE PERSON
|
|---|
| 6 | ; and NON-SPACE FILE DATE/TIME fields
|
|---|
| 7 | ; called by new-style MUMPS field x-ref logic on NON-SPACE FILE
|
|---|
| 8 | ; LOCATION (#90) field of file 6914 when value changes
|
|---|
| 9 | ;
|
|---|
| 10 | ; input
|
|---|
| 11 | ; DA - ien of entry in file 6914
|
|---|
| 12 | ; ENF - flag, "S" for set logic or "K" for kill logic
|
|---|
| 13 | ;
|
|---|
| 14 | Q:'$G(DA) ; ien required
|
|---|
| 15 | Q:"^S^K^"'[("^"_ENF_"^") ; must be S or K
|
|---|
| 16 | ;
|
|---|
| 17 | N ENFDA
|
|---|
| 18 | S ENFDA(6914,DA_",",90.1)=$S(ENF="S":DUZ,1:"@") ; non-space file person
|
|---|
| 19 | S ENFDA(6914,DA_",",90.2)=$S(ENF="S":$$NOW^XLFDT(),1:"@") ; date/time
|
|---|
| 20 | D FILE^DIE("","ENFDA")
|
|---|
| 21 | Q
|
|---|
| 22 | ;
|
|---|
| 23 | BUL(DA) ; Send a bulletin
|
|---|
| 24 | ; called by new-style MUMPS record x-ref set logic on NON-SPACE FILE
|
|---|
| 25 | ; LOCATION (#90) field of file 6914 when value changes
|
|---|
| 26 | ;
|
|---|
| 27 | ; input
|
|---|
| 28 | ; DA - ien of entry in file 6914
|
|---|
| 29 | ;
|
|---|
| 30 | Q:'$G(DA) ; ien required
|
|---|
| 31 | ;
|
|---|
| 32 | ; new all input and output variables of the bulletin API
|
|---|
| 33 | N XMDUZ,XMBNAME,XMPARM,XMBODY,XMTO,XMINSTR,XMATTACH,XMZ,XMERR
|
|---|
| 34 | ;
|
|---|
| 35 | ; set variables for the bulletin API
|
|---|
| 36 | S XMDUZ=DUZ ; sender
|
|---|
| 37 | S XMBNAME="EN NON-SPACE FILE LOC" ; bulletin name
|
|---|
| 38 | S XMTO("G.EN NON-SPACE FILE LOC")="" ; mail group
|
|---|
| 39 | S XMTO(DUZ)=""
|
|---|
| 40 | S XMPARM(1)=DA ; equipment entry #
|
|---|
| 41 | S XMPARM(2)=$$GET1^DIQ(6914,DA_",",90) ; non-space file location
|
|---|
| 42 | S XMPARM(3)=$$GET1^DIQ(6914,DA_",",90.1) ; non-space file person
|
|---|
| 43 | S XMPARM(4)=$$GET1^DIQ(6914,DA_",",90.2) ; non-space file date/time
|
|---|
| 44 | ;
|
|---|
| 45 | ; send the bulletin
|
|---|
| 46 | D SENDBULL^XMXAPI(XMDUZ,XMBNAME,.XMPARM,"",.XMTO)
|
|---|
| 47 | Q
|
|---|
| 48 | ;
|
|---|
| 49 | DELNSP(DA) ; Delete Non-Space File Location (#90) field value
|
|---|
| 50 | ; called by new-style MUMPS field x-ref set logic on LOCATION (#24)
|
|---|
| 51 | ; field of file 6914 when LOCATION value changes
|
|---|
| 52 | ;
|
|---|
| 53 | ; input
|
|---|
| 54 | ; DA - ien of entry in file 6914
|
|---|
| 55 | ;
|
|---|
| 56 | Q:'$G(DA) ; ien required
|
|---|
| 57 | ;
|
|---|
| 58 | N ENFDA
|
|---|
| 59 | S ENFDA(6914,DA_",",90)="@"
|
|---|
| 60 | D FILE^DIE("","ENFDA")
|
|---|
| 61 | Q
|
|---|
| 62 | ; ENTINSD
|
|---|
