source: FOIAVistA/trunk/r/ENROLLMENT_APPLICATION_SYSTEM-EAS/EASEZP6F.m@ 1582

Last change on this file since 1582 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 4.2 KB
Line 
1EASEZP6F ;ALB/AMA - Print 1010EZ, Version 6 or greater ; 10/19/2000
2 ;;1.0;ENROLLMENT APPLICATION SYSTEM;**51,60,57**;Mar 15, 2001
3 ;
4 ; These routines print a version of the OMB approved VA10-10EZ form.
5 ; No local modifications to these routines will be made. Any changes
6 ; will be provided through the National Patch Module release process.
7 ;
8 ; This routine was copied from EASEZPF; if the version # of the 1010EZ
9 ; application is 6.0 or greater, then this routine will be executed.
10 ;
11EN ; Entry point to print 1010EZ, Version 6 or greater
12 N EALNE,EAINFO,EAABRT,EAADL,ERR,EAMULT
13 ;
14 D SETUP(.EALNE,.EAINFO,EASAPP,EASDFN)
15 ;
16 D PAGE1^EASEZP6U
17 D PAGE1^EASEZPU3
18 D EN^EASEZP61(.EALNE,.EAINFO)
19 ;
20 D PAGE2^EASEZPU2
21 D EN^EASEZP62(.EALNE,.EAINFO)
22 ;
23 D EN^EASEZP63(.EALNE,.EAINFO)
24 D EN^EASEZP64(.EALNE,.EAINFO) ;EAS*1.0*60
25 ;
26 ;Print additional insurance pages if more than 1 insurance company
27 F EAADL=1:1 D Q:$G(EAABRT)
28 . I '$D(^TMP("EZTEMP",$J,"IA",EAADL)) S EAABRT=1 Q
29 . S EAMULT=1
30 . D PAGEI^EASEZPU3(EAADL)
31 I $G(EAMULT) D EN^EASEZP6I(.EALNE,.EAINFO)
32 ;
33 ;Print additional dependent pages if more than 1 dependent
34 S (EAABRT,EAMULT)=0 F EAADL=1:1 D Q:$G(EAABRT)
35 . I '$D(^TMP("EZTEMP",$J,"IIB",EAADL)) S EAABRT=1 Q
36 . S EAMULT=1
37 . D PAGEN^EASEZPU3(EAADL)
38 I EAMULT D EN^EASEZP6D(.EALNE,.EAINFO)
39 ;
40 ;Print additional dependent financial pages if more
41 ;than 1 dependent, starting with the 2nd one
42 ;(since Child 1 info already displayed on pages 2 & 3)
43 S (EAABRT,EAMULT)=0 F EAADL=2:1 D Q:$G(EAABRT)
44 . I '$D(^TMP("EZTEMP",$J,"IIF",EAADL)) S EAABRT=1 Q
45 . S EAMULT=1
46 . D PAGEDFF^EASEZPU2(EAADL)
47 S EAABRT=0 F EAADL=2:1 D Q:$G(EAABRT)
48 . I '$D(^TMP("EZTEMP",$J,"IIG",EAADL)) S EAABRT=1 Q
49 . S EAMULT=1
50 . D PAGEDFG^EASEZPU2(EAADL)
51 I EAMULT D EN^EASEZP6M(.EALNE,.EAINFO)
52 ;
53ENQUIT ; Clean up temp globals after printing is complete
54 K ^TMP("EASEZ",$J)
55 K ^TMP("EZDATA",$J)
56 K ^TMP("EZINDEX",$J)
57 K ^TMP("EZTEMP",$J)
58 K ^TMP("EZDISP",$J)
59 Q
60 ;
61SETUP(EALNE,EAINFO,EASAPP,EASDFN) ; Set-up print variables
62 ; Input
63 ; EALNE - Line format array
64 ; EAINFO - Misc Data
65 ; ("CLRK") - Clerk's initials
66 ; ("ID") - Web ID from #712
67 ; ("PGE") - Page number
68 ; ("VET" ) - Veteran's name submitting the application
69 ; ("SSN") - Veteran's SSN
70 ; ("DISC") - Financial Disclosure status
71 ; EASAPP - IEN of applicant on the 1010EZ HOLDING File, #712
72 ; EASDFN - DFN of applicant in the PATIENT File, #2
73 ;
74 N X
75 ;
76 ; Build Line array for printout
77 S EALNE("ULC")=$S('($D(IOST)#2):"-",IOST["C-":"-",1:"_")
78 S EALNE("D")="",EALNE("DD")="",EALNE("UL")=""
79 S $P(EALNE("D"),"-",133)="",$P(EALNE("DD"),"=",133)="",$P(EALNE("UL"),EALNE("ULC"),133)=""
80 ;
81 ; Set up information array & get clerk's initials
82 S ZUSR=$G(ZUSR)
83 I +ZUSR>0 D
84 . S EAINFO("CLRK")=$$GET1^DIQ(200,ZUSR,1)
85 . I EAINFO("CLRK")']"" D
86 . . S X=$$GET1^DIQ(200,ZUSR,.01)
87 . . S EAINFO("CLRK")=$E($P(X,",",2),1)_$E($P(X,","),1)
88 E D
89 . S EAINFO("CLRK")="unk"
90 ;
91 ; Set data elements
92 S EAINFO("PGE")=0
93 S EAINFO("ID")=$$GET1^DIQ(712,EASAPP_",",.1)
94 S EAINFO("PD")=$$FMTE^XLFDT($$NOW^XLFDT)
95 S EAINFO("DISC")=$$GET1^DIQ(712,EASAPP_",",3.8)
96 S EAINFO("EASAPP")=EASAPP
97 S EAINFO("VET")=$$GET1^DIQ(712,EASAPP_",",1)
98 S EAINFO("SSN")=$$GET1^DIQ(712,EASAPP_",",2)
99 ;
100 ; Retrieve application data from holding file, #712
101 D EN^EASEZC1(EASAPP)
102 D SORT^EASEZC3(EASAPP)
103SETQ Q
104 ;
105HDRMAIN(EALNE) ; PRINT THE FIRST PAGE HEADER INFORMATION
106 W @IOF
107 W ?106,"OMB APPROVED NO. 2900-0091"
108 W !?103,"Estimated Burden Avg. 45 min."
109 W !?107,"Expiration Date 6/30/2007",!,EALNE("DD")
110 W !,"D E P A R T M E N T O F V E T E R A N S A F F A I R S",?80,"APPLICATION FOR HEALTH BENEFITS",!,EALNE("DD")
111 Q
112 ;
113HDR(EALNE,EAINFO) ; PRINT THE PAGE HEADER INFO FOR PAGES GREATER THAN 1
114 W @IOF
115 W "APPLICATION FOR HEALTH BENEFITS, Continued",?55,"| VETERAN'S NAME (Last, First, Middle)",?106,"| SOCIAL SECURITY NUMBER"
116 W !?55,"| ",EAINFO("VET"),?106,"| ",EAINFO("SSN")
117 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
118 Q
119 ;
120FT(EALNE,EAINFO) ; PRINT THE PAGE FOOTER INFORMATION
121 W !,EALNE("DD")
122 W !,"VA FORM 10-10EZ FEB 2005",?40,"PRINTED: ",EAINFO("PD")
123 W ?80,"Clerk: ",EAINFO("CLRK"),"/",EAINFO("ID")
124 W ?120,"PAGE " S EAINFO("PGE")=EAINFO("PGE")+1 W EAINFO("PGE")
125 Q
Note: See TracBrowser for help on using the repository browser.