source: FOIAVistA/trunk/r/ENROLLMENT_APPLICATION_SYSTEM-EAS/EASEZP6M.m@ 1751

Last change on this file since 1751 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 5.0 KB
Line 
1EASEZP6M ;ALB/AMA - Print 1010EZ, Version 6 or greater, Cont., Other Dependent Financial Pages ; 10/19/2000
2 ;;1.0;ENROLLMENT APPLICATION SYSTEM;**51,60,57**;Mar 15, 2001
3 ;
4 ;New page, to print multiple dependent financial information
5EN(EALNE,EAINFO,EASDG) ;Entry point, called from EN^EASEZP6F
6 ; Input
7 ; EALNE - Array of line formats for output
8 ; EAINFO - Application Data array, see SETUP^EASEZP6F
9 ; EASDG - Flag variable to signify request to print from DG options
10 ;
11 N FNP,GNP ;MAX NO. ENTRIES PER PAGE FOR EACH SECTION
12 N EASF,EASG ;VARS FOR INDIRECT ^TMP GLOBAL REFERENCE
13 N DEPF,DEPG ;VARS TO LOOP THROUGH ^TMP GLOBALS
14 N DFCNT,DGCNT ;COUNTERS OF NO. DEPENDENTS
15 N NEWPG,SECOND ;VARS TO DETERMINE WHEN NEW PAGE SHOULD OCCUR
16 ;
17 ;Assuming 55 print lines per page, 5 lines per IIF entry, 6 lines
18 ;per IIG entry, plus lines for titles and blank dividing lines:
19 S FNP=9 ;can fit 9 dependents on one page for Section IIF
20 S GNP=7 ;can fit 7 dependents on one page for Section IIG
21 ;
22 ;Find additional dependents from Section IIF
23 S EASF=$NA(^TMP("EASEZ",$J,"DFF"))
24 I $O(@EASF@(1)) D BEGINF
25 ;
26 ;Start printing with 2nd dependent
27 S DEPF=1,DFCNT=0 F S DEPF=$O(@EASF@(DEPF)) Q:'DEPF D
28 . S DFCNT=DFCNT+1
29 . ;Check to see if a new page is needed
30 . I (DFCNT>1),'((DFCNT-1)#FNP) D
31 . . D FT^EASEZP6F(.EALNE,.EAINFO)
32 . . D BEGINF
33 . I (DFCNT#FNP)'=1 W !?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
34 . D ADFF
35 ;
36 ;Find additional dependents from Section IIG
37 S EASG=$NA(^TMP("EASEZ",$J,"DFG"))
38 I $O(@EASG@(1)) D
39 . I $O(@EASF@(1)) D I 1
40 . . I ((DFCNT#FNP)'=0),((DFCNT#FNP)'=GNP) W !!,?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
41 . . ;At the end of IIF, to find when to jump to the next page,
42 . . ;55 print lines, minus 3 lines for Section IIG title header,
43 . . ;minus the number of lines already used on current page,
44 . . ;divided by the number of lines for a Section IIG entry
45 . . S NEWPG=(51-((DFCNT#FNP)*6))\7
46 . . I '(DFCNT#FNP)!'NEWPG!(NEWPG=GNP) S NEWPG=GNP D FT^EASEZP6F(.EALNE,.EAINFO)
47 . E S NEWPG=GNP
48 . D BEGING
49 ;
50 ;Start printing with 2nd dependent
51 S DEPG=1,DGCNT=0 F S DEPG=$O(@EASG@(DEPG)) Q:'DEPG D
52 . S DGCNT=DGCNT+1
53 . ;Check to see if a new page is needed
54 . I (DGCNT>1),'((DGCNT-$G(SECOND)-1)#NEWPG) D
55 . . D FT^EASEZP6F(.EALNE,.EAINFO)
56 . . I NEWPG'=GNP S SECOND=NEWPG,NEWPG=GNP
57 . . D BEGING
58 . I (DGCNT-$G(SECOND))#GNP'=1 W !?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
59 . D ADFG
60 ;
61 D FT^EASEZP6F(.EALNE,.EAINFO)
62 Q
63 ;
64BEGINF ; Print page header info
65 ;
66 D HDR^EASEZP6F(.EALNE,.EAINFO)
67 I $G(EASDG) D I 1
68 . N EZINYR
69 . S EZINYR=^TMP("EASEZ",$J,2,999)
70 . W !!?9,"SECTION VIII - PREVIOUS CALENDAR YEAR GROSS ANNUAL INCOME OF ADDITIONAL DEPENDENT CHILD(REN) (INCOME YEAR: ",EZINYR,")"
71 E W !!?20,"SECTION VIII - PREVIOUS CALENDAR YEAR GROSS ANNUAL INCOME OF ADDITIONAL DEPENDENT CHILD(REN)"
72 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
73 Q
74 ;
75BEGING ; Print page header info
76 ;
77 I NEWPG=GNP D HDR^EASEZP6F(.EALNE,.EAINFO)
78 I $G(EASDG) D I 1
79 . N EZINYR
80 . S EZINYR=^TMP("EASEZ",$J,2,999)
81 . W !!?14,"SECTION X - PREVIOUS CALENDAR YEAR NET WORTH FOR ADDITIONAL DEPENDENT CHILD(REN) (INCOME YEAR: ",EZINYR,")"
82 E W !!?25,"SECTION X - PREVIOUS CALENDAR YEAR NET WORTH FOR ADDITIONAL DEPENDENT CHILD(REN)"
83 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
84 Q
85 ;
86ADFF ; Print out VA 10-10EZ Section VIII, Gross Annual Income information - Additional Dependents
87 ;
88 W !,"1. GROSS ANNUAL INCOME FROM EMPLOYMENT (wages, bonuses, tips, etc.)",?90,"| $ ",$P(@EASF@(DEPF,7),U,2)
89 W !,"EXCLUDING INCOME FROM YOUR FARM, RANCH, PROPERTY OR BUSINESS -- ",$P(@EASF@(DEPF,7),U),?90,"|"
90 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
91 ;
92 W !,"2. NET INCOME FROM YOUR FARM, RANCH, PROPERTY OR BUSINESS -- ",$P(@EASF@(DEPF,7),U),?90,"| $ ",$P(@EASF@(DEPF,7),U,3)
93 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
94 ;
95 W !,"3. LIST OTHER INCOME AMOUNTS (Social Security, compensation,",?90,"| $ ",$P(@EASF@(DEPF,7),U,4)
96 W !,"pension, interest, dividends.) EXCLUDE WELFARE. -- ",$P(@EASF@(DEPF,7),U),?90,"|"
97 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
98 Q
99 ;
100ADFG ; Print SECTION X - PREVIOUS CALENDAR YEAR NET WORTH - ADDITIONAL DEPENDENTS
101 ;
102 W !,"1. CASH, AMOUNT IN BANK ACCOUNTS (e.g., checking and savings accounts,",?116,"| $ ",$P(@EASG@(DEPG,9),U,2)
103 W !,"certificates of deposit, individual retirement accounts, stocks and bonds) -- ",$P(@EASG@(DEPG,9),U),?116,"|"
104 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
105 ;
106 W !,"2. MARKET VALUE OF LAND AND BUILDINGS MINUS MORTGAGES AND LIENS (e.g., second",?116,"| $ ",$P(@EASG@(DEPG,9),U,3)
107 W !,"homes and non-income-producing property. Do not count your primary home.) -- ",$P(@EASG@(DEPG,9),U),?116,"|"
108 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
109 ;
110 W !,"3. VALUE OF OTHER PROPERTY OR ASSETS (e.g., art, rare coins, collectibles) MINUS THE AMOUNT YOU OWE ON THESE ITEMS.",?116,"| $ ",$P(@EASG@(DEPG,9),U,4)
111 W !,"INCLUDE VALUE OF FARM, RANCH, OR BUSINESS ASSETS. Exclude household effects and family vehicles. -- ",$P(@EASG@(DEPG,9),U),?116,"|"
112 W ?131,$C(13) W:EALNE("ULC")="-" ! W EALNE("UL")
113 Q
Note: See TracBrowser for help on using the repository browser.