source: FOIAVistA/trunk/r/INTEGRATED_BILLING-IB-PRQ--IBD--IBQ--PRQS/IB20P337.m@ 868

Last change on this file since 868 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 3.0 KB
Line 
1IB20P337 ;ALB/CXW-FY06 DSS CLINIC STOP CODES IB*2.0*337 POST INIT ;15-FEB-06
2 ;;2.0;INTEGRATED BILLING;**337**;21-MAR-94
3 ;;Per VHA Directive 10-93-142, this routine should not be modified.
4 ;
5POST ;
6 N IBEFFDT,U
7 S U="^",IBEFFDT=3051001 ;effective date OCT 1st, 2005
8 D START,ADD(IBEFFDT),UPDATE(IBEFFDT),FINISH
9 Q
10 ;
11START D MES^XPDUTL("")
12 D MES^XPDUTL("FY06 DSS Clinic Stop Codes, Post-Install Starting")
13 Q
14 ;
15FINISH ;
16 D MES^XPDUTL("")
17 D MES^XPDUTL("FY06 DSS Clinic Stop Codes, Post-Install Complete")
18 Q
19 ;
20MESS(IBSTR) ;
21 N IBA
22 S IBA(2)=IBSTR
23 S (IBA(1),IBA(3))=""
24 D MES^XPDUTL(.IBA)
25 Q
26 ;
27ADD(IBEFFDT) ;
28 ;add a new code
29 N Y,IBC,IBT,IBX,IBCODE,IBTYPE,IBDES,IBOVER
30 D MESS(" Adding new codes to file 352.5")
31 S IBC=0
32 F IBX=1:1 S IBT=$P($T(NCODE+IBX),";",3) Q:'$L(IBT) D
33 . S IBCODE=+$P(IBT,U)
34 . I $D(^IBE(352.5,"AEFFDT",IBCODE,-IBEFFDT)) D Q
35 . . D BMES^XPDUTL(" Duplication of non-billable type code "_IBCODE)
36 . S IBTYPE=$P(IBT,U,2)
37 . S IBDES=$E($P(IBT,U,3),1,30)
38 . S IBOVER=$P(IBT,U,4)
39 . S Y=+$$ADD3525(IBCODE,IBEFFDT,IBTYPE,IBDES,IBOVER) S:Y>0 IBC=IBC+1
40 D MESS(" "_IBC_$S(IBC<2:" entry",1:" entries")_" added to 352.5")
41 Q
42 ;
43UPDATE(IBEFFDT) ;
44 ;update an old code
45 N Y,IB1,IBC,IBT,IBX,IBCODE,IBTYPE,IBDES,IBOVER,IBLSTDT
46 D MESS(" Updating description and override flag in file 352.5")
47 S IBC=0
48 F IBX=1:1 S IBT=$P($T(OCODE+IBX),";",3) Q:'$L(IBT) D
49 . S IBCODE=+$P(IBT,U)
50 . I $D(^IBE(352.5,"AEFFDT",IBCODE,-IBEFFDT)) D Q
51 . . D BMES^XPDUTL(" Duplication of non-billable type code "_IBCODE)
52 . S IBLSTDT=$O(^IBE(352.5,"AEFFDT",IBCODE,-9999999))
53 . I +IBLSTDT=0 D Q
54 . . D BMES^XPDUTL(" Code "_IBCODE_" not found for non-billable update")
55 . S IB1=$O(^IBE(352.5,"AEFFDT",IBCODE,IBLSTDT,0))
56 . S IBTYPE=$P($G(^IBE(352.5,IB1,0)),U,3)
57 . S IBDES=$E($P(IBT,U,2),1,30)
58 . S IBOVER=$P(IBT,U,3)
59 . S Y=+$$ADD3525(IBCODE,IBEFFDT,IBTYPE,IBDES,IBOVER) S:Y>0 IBC=IBC+1
60 D MES^XPDUTL("")
61 D MES^XPDUTL(" "_IBC_$S(IBC<2:" update",1:" updates")_" added to file 352.5")
62 Q
63 ;
64ADD3525(IBCODE,IBEFFDT,IBTYPE,IBDES,IBOVER) ;
65 ;add a new entry
66 D BMES^XPDUTL(" "_IBCODE_" "_IBDES)
67 N IBIENS,IBFDA,IBER,IBRET
68 S IBRET=""
69 S IBIENS="+1,"
70 S IBFDA(352.5,IBIENS,.01)=IBCODE
71 S IBFDA(352.5,IBIENS,.02)=IBEFFDT
72 S IBFDA(352.5,IBIENS,.03)=IBTYPE
73 S IBFDA(352.5,IBIENS,.04)=IBDES
74 S:IBOVER IBFDA(352.5,IBIENS,.05)=1
75 D UPDATE^DIE("","IBFDA","IBRET","IBER")
76 I $D(IBER) D BMES^XPDUTL(IBER("DIERR",1,"TEXT",1))
77 Q $G(IBRET(1))
78 ;
79 ;new non-billable type data
80NCODE ;;code^billable type^description^override flag
81 ;;142^0^ENTEROSTOMAL TX, WOUND OR SKIN CARE^1
82 ;;143^0^SLEEP STUDY^1
83 ;;191^0^COMMUNITY ADULT DAY HEALTH CARE FOLLOW-UP^1
84 ;;229^0^TELEPHONE/BLIND REHAB PROGRAM^1
85 ;;437^0^VISUAL IMPAIRMENT CENTER TO OPTIMIZE REMAINING SIGHT (VICTORS)^1
86 ;;439^0^LOW VISION CARE^1
87 ;;694^0^STORE-AND-FORWARD TELEHEALTH^1
88 ;;695^0^STORE-AND-FORWARD TELEHEALTH SAME STATION^1
89 ;;696^0^STORE-AND-FORWARD TELEHEALTH NOT SAME STATION^1
90 ;
91 ;description and override flag updates
92OCODE ;;code^description^override flag
93 ;;683^NON-VIDEO MONITORING ONLY^1
94 ;
Note: See TracBrowser for help on using the repository browser.