source: FOIAVistA/trunk/r/INTEGRATED_BILLING-IB-PRQ--IBD--IBQ--PRQS/IB20PT7.m@ 1801

Last change on this file since 1801 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 3.9 KB
Line 
1IB20PT7 ;ALB/ARH - ADD NEW ENTRIES TO TABLE FILES ; 12/20/93
2 ;;Version 2.0 ; INTEGRATED BILLING ;; 21-MAR-94
3 ;
4 D DS ; Add new discharge statuses for bills
5 D RT ; Add new Rate Types to file #399.3 for CHAMPVA
6 D RVC ; Add new revenue codes to file #399.2
7 D OSC ; Adding new Occurrence Span Codes
8 D VC ; Adding new Value Codes
9 Q
10 ;
11 ;
12DS ; Add new discharge statuses for bills
13 W !!,">>> Adding new discharge status for bills..."
14 F IBI=1:1 S IBX=$P($T(DSF+IBI),";;",2,999) Q:IBX="" D
15 . S IBJ=0 F S IBJ=$O(^DGCR(399.1,IBJ)) Q:'IBJ S IBY=$G(^DGCR(399.1,IBJ,0)) I $P(IBX,U,1)=$P(IBY,U,1),$P(IBX,U,2)=$P(IBY,U,2),$P(IBY,U,6) S IBY=1 Q
16 . Q:IBY K DA,DO S DIC="^DGCR(399.1,",DIC(0)="L",X=$P(IBX,U,1) D FILE^DICN K DA,DO Q:Y<0!('$P(Y,U,3))
17 . S DA=+Y,DIE=DIC,DR=".02////"_$P(IBX,U,2)_";.13////1" D ^DIE
18 K DIC,DIE,DA,DR,Y
19 Q
20 ;
21RT ; Add new Rate Types to file #399.3 for CHAMPVA
22 W !!,">>> Adding new entries to the Rate Type File - CHAMPVA ..."
23 F IBI=1:1 S IBX=$P($T(RTF+IBI),";;",2,999) Q:IBX="" D
24 . S IBY=$E($P(IBX,U,1),1,30) Q:$D(^DGCR(399.3,"B",IBY))
25 . K DD,DO S DIC="^DGCR(399.3,",DIC(0)="L",X=IBY D FILE^DICN K DA,DO Q:Y<0
26 . S DA=+Y,DIE=DIC,DR=".02////"_$P(IBX,U,2)_";.03////"_$P(IBX,U,3)_";.04////"_$P(IBX,U,4)_";.05////"_$P(IBX,U,5)_";.06////"_$P(IBX,U,6)_";.07////"_$P(IBX,U,7)_";.08////"_$P(IBX,U,8)_";.09////"_$P(IBX,U,9) D ^DIE
27 K DIC,DIE,DA,DR,Y
28 Q
29 ;
30RVC ; Add new revenue codes to file #399.2
31 W !!,">>> Adding new revenue codes..."
32 F IBI=1:1 S IBX=$P($T(RVCF+IBI),";;",2,999) Q:IBX="" D
33 . S IBY=$P(IBX,U,1),IBZ=$G(^DGCR(399.2,+IBY,0)) Q:(+IBY'=+IBZ)!($P(IBZ,U,2)'="*RESERVED")
34 . S DA=+IBY,DIE="^DGCR(399.2,",DR="1////"_$P(IBX,U,2)_";3////"_$P(IBX,U,4) D ^DIE
35 K DIC,DIE,DA,DR,Y
36 Q
37 ;
38OSC ; Adding new Occurrence Span Codes
39 W !!,">>> Adding Occurrence Span Codes..."
40 F IBI=1:1 S IBX=$P($T(OSCF+IBI),";;",2,999) Q:IBX="" D
41 . S IBJ=0 F S IBJ=$O(^DGCR(399.1,IBJ)) Q:'IBJ S IBY=$G(^DGCR(399.1,IBJ,0)) I $P(IBX,U,1)=$P(IBY,U,1),$P(IBX,U,2)=$P(IBY,U,2),$P(IBY,U,10) S IBY=1 Q
42 . Q:IBY K DA,DO S DIC="^DGCR(399.1,",DIC(0)="L",X=$P(IBX,U,1) D FILE^DICN K DA,DO Q:Y<0!('$P(Y,U,3))
43 . S DA=+Y,DIE=DIC,DR=".02////"_$P(IBX,U,2)_";.11////1;.17////1" D ^DIE
44 K DIC,DIE,DA,DR,Y
45 Q
46 ;
47VC ; Adding new Value Codes
48 W !!,">>> Adding Value Codes..."
49 F IBI=1:1 S IBX=$P($T(VCF+IBI),";;",2,999) Q:IBX="" D
50 . S IBJ=0 F S IBJ=$O(^DGCR(399.1,IBJ)) Q:'IBJ S IBY=$G(^DGCR(399.1,IBJ,0)) I $P(IBX,U,1)=$P(IBY,U,1),$P(IBX,U,2)=$P(IBY,U,2),$P(IBY,U,11) S IBY=1 Q
51 . Q:IBY K DA,DO S DIC="^DGCR(399.1,",DIC(0)="L",X=$P(IBX,U,1) D FILE^DICN K DA,DO Q:Y<0!('$P(Y,U,3))
52 . S DA=+Y,DIE=DIC,DR=".02////"_$P(IBX,U,2)_";.18////1;.19////"_$P(IBX,U,3) D ^DIE
53 K DIC,DIE,DA,DR,Y
54 Q
55 ;
56 ;
57DSF ; - new discharge status, 399.1
58 ;;DISCHARGED TO HOME UNDER CARE OF A HOME IV PROVIDER^08
59 ;
60 ;
61RTF ; - new rate type entries
62 ;;CHAMPVA REIMB. INS.^REIMBURSABLE INS.^1^REIM INS^1^^i^1^1
63 ;;CHAMPVA^CHAMPVA^1^CHAMPVA^1^^i^1^1
64 ;
65 ;
66RVCF ; - new revenue codes
67 ;;294^MED EQUIP/SUPPLIES/DRUGS^^SUPPLIES/DRUGS FOR DME EFFECTIVENESS HOME-HEALTH AGENCY ONLY
68 ;;404^PET SCAN^^POSITRON EMMISSION TOMOGROPHY
69 ;;547^AMBUL/PHARMACY^^PHARMACY
70 ;;548^AMBUL/TELEPHONIC EKG^^TELEPHONE TRANSMISSION EKG
71 ;;636^DRUGS/DETAIL CODE^^DRUGS REQUIRING DETAILED CODING
72 ;;761^TREATMENT RM^^TREATMENT ROOM
73 ;;762^OBSERVATION RM^^OBSERVATION ROOM
74 ;;882^HOME DIALYSIS AID VISIT^^HOME DIALYSIS AID VISIT
75 ;;947^CMPLX MED EQUIP-ANC^^COMPLEX MEDICAL EQUIPMENT - ANCILLARY
76 ;
77 ;
78OSCF ; - add occurrence span codes
79 ;;QUALIFYING STAY DATES FOR SNF USE ONLY^70
80 ;;PRIOR STAY DATES^71
81 ;;FIRST/LAST VISIT^72
82 ;;BENEFIT ELIGIBILITY PERIOD^73
83 ;;NONCOVERED LEVEL OF CARE^74
84 ;;SNF LEVEL OF CARE^75
85 ;;PATIENT LIABILITY^76
86 ;;PROVIDER LIABILITY PERIOD^77
87 ;;SNF PRIOR STAY DATES^78
88 ;;PAYER CODE^79
89 ;;PRO/UR APPROVED STAY DATES^M0
90 ;
91 ;
92VCF ; - add value codes
93 ;;INPATIENT PROFESSIONAL COMPONENT CHARGES, COMBINED BILLED^04
94 ;;NO FAULT, INCLUDING AUTO/OTHER^14^1
95 ;;WORKER'S COMPENSATION^15
96 ;;ACCIDENT HOUR^45
97 ;
Note: See TracBrowser for help on using the repository browser.