source: FOIAVistA/trunk/r/INTEGRATED_BILLING-IB-PRQ--IBD--IBQ--PRQS/IBEPTC1.m@ 1306

Last change on this file since 1306 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 3.3 KB
Line 
1IBEPTC1 ;ALB/CPM/ARH - TP FLAG STOP CODES AND CLINICS (CON'T.) ; 23-JUL-93
2 ;;Version 2.0 ; INTEGRATED BILLING ;**55**; 21-MAR-94
3 ;;Per VHA Directive 10-93-142, this routine should not be modified.
4 ;
5REV ; Review selected entries and de-select if necessary.
6 W !!,"You have selected ",IBNUM," ",$P(IBINFO,";",3),"."
7 S DIR(0)="Y",DIR("A")="Would you like to review these selections",DIR("?")="^D HREV^IBEPTC1"
8 D ^DIR K DIR I 'Y!($D(DIRUT))!($D(DUOUT)) G REVQ
9 ;
10 ; - list selections and ask if user would like to de-select.
11 W ! D LIST W !
12 S DIR(0)="Y",DIR("A")="Would you like to de-select any entries"
13 S DIR("?")="Enter 'Y' to de-select entries, 'N' to continue, or '^' to quit."
14 D ^DIR K DIR I 'Y!($D(DIRUT))!($D(DUOUT)) G REVQ
15 ;
16 ; - allow de-selection and pull entries from the list.
17 S IBHIT=0 F D Q:Y<0
18 .S DIC=$P(IBINFO,";",5),DIC(0)="QEAMZ"
19 .S DIC("A")="De-select "_$S(IBHIT:"Next ",1:"")_$P(IBINFO,";",4)_": "
20 .S:$P(IBINFO,";",6)]"" DIC("S")=$P(IBINFO,";",6)
21 .D ^DIC K DIC Q:Y<0 S IBHIT=1
22 .I '$D(^TMP("IBEPTC",$J,+Y)) W !,"Please note that ",Y(0,0)," is not currently selected."
23 .E K ^TMP("IBEPTC",$J,+Y) S IBNUM=IBNUM-1
24 W !!,"You have selected a total of ",IBNUM," ",$P(IBINFO,";",$S(IBNUM=1:7,1:3)),"."
25REVQ S:$D(DIRUT)!($D(DUOUT)) IBQ=1
26 Q
27 ;
28FILE ; File all selected entries.
29 N IBI,IBIN,IBALR
30 S IBI=0 F S IBI=$O(^TMP("IBEPTC",$J,IBI)) Q:'IBI S IBIN=^(IBI) D
31 .K DD,DO,DIC,DR
32 .S DIC=$P(IBINFO,";",8),DIC(0)="",X=IBI,DLAYGO=$P(IBINFO,";",9)
33 .;
34 .; - has this entry already been filed for this date?
35 .S IBALR=$O(@(DIC_"""AIVDTT2"","_IBI_","_-IBDAT_",0)"))
36 .;
37 .; - add new entry if not yet on file for the specified date
38 .I 'IBALR D FILE^DICN I Y<0 W !,"Unable to file ",IBIN,"..",! Q
39 .S DIE=$P(IBINFO,";",8),DA=$S(IBALR:IBALR,1:+Y),DR=".02////"_IBDAT_";.04////2;.05////"_IBFILE_";.06////"_IBTPAB
40 .D ^DIE K DA,DR,DIE W "."
41 W " done!"
42 Q
43 ;
44LIST ; List all selected entries.
45 W ! S I=0 F S I=$O(^TMP("IBEPTC",$J,I)) Q:'I W:$X>40 ! W:$X>2 ?40 W ^(I)
46 Q
47 ;
48HACT ; Help for the Billing action prompt.
49 W !!,"For Third Party Billing, please enter:"
50 W !," 'Y' to flag ",$S(IBNUM=1:"this",1:"these")," ",$P(IBINFO,";",$S(IBNUM=1:7,1:3))," as non-billable."
51 W !," 'N' to flag ",$S(IBNUM=1:"this",1:"these")," ",$P(IBINFO,";",$S(IBNUM=1:7,1:3))," as billable."
52 W !," '^' to quit this option."
53 Q
54 ;
55HAUTO ; Help for the Auto Biller action prompt.
56 W !!,"For the Third Party Auto Biller, please enter:"
57 W !," 'Y' if bills should be created for ",$S(IBNUM=1:"this",1:"these")," billable ",$P(IBINFO,";",$S(IBNUM=1:7,1:3))
58 W !," 'N' if bills should NOT be created for ",$S(IBNUM=1:"this",1:"these")," billable ",$P(IBINFO,";",$S(IBNUM=1:7,1:3))
59 W !," '^' to quit this option."
60 Q
61 ;
62HSEL ; Help for the Billing characteristic prompt.
63 W !!,"For Third Party Billing, please enter:"
64 W !," 'S' to flag some Stop Codes as (non) billable or (not) auto billed"
65 W !," 'C' to flag some Clinics as (non) billable or (not) auto billed"
66 W !," 'A' to flag ALL Clinics for the auto biller"
67 W !," '^' to quit this option."
68 Q
69 ;
70HREV ; Help for the Request to Review prompt.
71 W !!,"Enter 'Y' to review the selections, 'N' to continue, or '^' to quit."
72 W !,"Please note that, if you choose to review the selections, you will have"
73 W !,"the opportunity to de-select incorrect entries from the list."
74 Q
Note: See TracBrowser for help on using the repository browser.