source: FOIAVistA/trunk/r/LAB_SERVICE-LR-LS/LRBARCFA.m@ 1742

Last change on this file since 1742 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 3.1 KB
Line 
1LRBARCFA ;DALOI/JMC - Lab Label Zebra Configuration Utility ;8/29/94 12:36
2 ;;5.2;LAB SERVICE;**218**;Sep 27, 1994
3 ;
4EN ;
5 N DA,DIR,DIRUT,DTOUT,DUOUT,LRY,X,Y
6 D ZIS
7 I POP D END Q
8 D USE^%ZISUTL("LRHOME")
9 S DIR(0)="SO^1:Configuration Update;2:Print Configuration Label;3:Adjust Tear Off Position;4:Label Top Position;5:Set Darkness;6:Mode Protection (Stripe printers only)"
10 S DIR("A")="Select Function",DIR("B")=1
11 D ^DIR
12 I $D(DIRUT) D END Q
13 S LRY=+Y
14 I LRY=1 D CU
15 I LRY=2 D CFL
16 I LRY=3 D TA
17 I LRY=4 D LT
18 I LRY=5 D SD
19 I LRY=6 D MP
20 D END
21 Q
22 ;
23CU ; Zebra Configuration Update.
24 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y
25 S DIR(0)="SO^F:Reload Factory Defaults;R:Recall Last Saved Values;S:Save Current Settings"
26 D USE^%ZISUTL("LRHOME")
27 D ^DIR Q:$D(DIRUT)
28 S LRY=Y
29 D USE^%ZISUTL("LRLABEL")
30 W "^XA^JU"_LRY_"^XZ" ; Set configuration update.
31 D CFL
32 Q
33 ;
34CFL ; Print Zebra Configuration Label.
35 D USE^%ZISUTL("LRLABEL")
36 W "~WC" ; Print configuration label.
37 D USE^%ZISUTL("LRHOME")
38 Q
39 ;
40TA ; Zebra Tear Off Adjust Position.
41 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y
42 S DIR(0)="NAO^-64:64:0",DIR("A")="Number of dots to adjust (Range -64 to +64): "
43 F D Q:$D(DIRUT)
44 . D USE^%ZISUTL("LRHOME")
45 . D ^DIR Q:$D(DIRUT)
46 . S LRY=+Y
47 . I LRY<0 S LRY="-"_$$RJ^XLFSTR($P(LRY,"-",2),2,"0")
48 . E S LRY="+"_$$RJ^XLFSTR(LRY,2,"0")
49 . D USE^%ZISUTL("LRLABEL")
50 . W "^XA~TA"_LRY_"^XZ^XA^JUS^XZ" ; Set tear off and save configuration
51 . D CFL
52 Q
53 ;
54LT ; Zebra Label Top Position adjustment
55 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y
56 S DIR(0)="NAO^-64:64:0",DIR("A")="Number of dots to adjust (Range -64 to +64): "
57 F D Q:$D(DIRUT)
58 . D USE^%ZISUTL("LRHOME")
59 . D ^DIR Q:$D(DIRUT)
60 . S LRY=+Y
61 . I LRY<0 S LRY="-"_$$RJ^XLFSTR($P(LRY,"-",2),2,"0")
62 . E S LRY="+"_$$RJ^XLFSTR(LRY,2,"0")
63 . D USE^%ZISUTL("LRLABEL")
64 . W "^XA^LT"_LRY_"^XZ^XA^JUS^XZ" ; Set label top and save configuration
65 . D CFL
66 Q
67 ;
68SD ; Zebra Set Darkness adjustment
69 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y
70 S DIR(0)="NAO^0:30:0",DIR("A")="Number of dots to adjust (Range 0 to 30): "
71 F D Q:$D(DIRUT)
72 . D USE^%ZISUTL("LRHOME")
73 . D ^DIR Q:$D(DIRUT)
74 . S LRY=+Y
75 . S LRY=$$RJ^XLFSTR(LRY,2,"0")
76 . D USE^%ZISUTL("LRLABEL")
77 . W "^XA~SD"_LRY_"^XZ^XA^JUS^XZ" ; Set darkness and save configuration
78 . D CFL
79 Q
80 ;
81MP ; Zebra Mode Protection (only applies to Stripe printers).
82 N LRY,DIR,DIRUT,DTOUT,DUOUT,X,Y
83 S DIR(0)="SO^E:Enable All Modes;D:Disable Darkness;P:Disable Position;C:Disable Calibration;S:Disable Save Permanent;W:Disable Pause Key;F:Disable Feed Key;X:Disable Cancel Key;M:Disable Menu Changes"
84 S DIR("A")="Select Mode to Change"
85 D USE^%ZISUTL("LRHOME")
86 D ^DIR Q:$D(DIRUT)
87 S LRY=Y
88 D USE^%ZISUTL("LRLABEL")
89 W "^XA^MP"_LRY_"^XZ" ; Set mode protection.
90 D CFL
91 Q
92 ;
93ZIS ; Device selection
94 D OPEN^%ZISUTL("LRHOME","HOME") ; Setup handle for user's "HOME" device.
95 S %ZIS="0",%ZIS("A")="Select ZEBRA Printer: ",%ZIS("B")=""
96 S %ZIS("S")="N LRY S LRY=$O(^LAB(69.9,1,3.6,""B"",Y,0)) I LRY,$P($G(^LAB(69.9,1,3.6,LRY,0)),U,2)=2"
97 D OPEN^%ZISUTL("LRLABEL",,.%ZIS) ; Setup handle for user's LABEL device.
98 Q
99 ;
100END ; Clean up.
101 I $D(ZTQUEUED) S ZTREQ="@"
102 E D
103 . D CLOSE^%ZISUTL("LRLABEL")
104 . D CLOSE^%ZISUTL("LRHOME")
105 Q
Note: See TracBrowser for help on using the repository browser.