source: FOIAVistA/trunk/r/LIST_MANAGER-VALM/VALMWB.m@ 1397

Last change on this file since 1397 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 4.1 KB
Line 
1VALMWB ;MJK/ALB;08:48 PM 17 Jan 1993;List Template Edit
2 ;;1;List Manager;;Aug 13, 1993
3 ;
4EN ; -- main entry point for edit tool
5 K VALMEVL,XQORS,^TMP("XQORS",$J)
6 D EN^VALM("VALM WORKBENCH")
7ENQ Q
8 ;
9HDR ; -- no header
10 S VALMHDR(1)="Template: "_$P($G(^SD(409.61,VALMIFN,0)),U)
11 Q
12 ;
13INIT ; -- entry code
14 I '$D(VALMIFN) W @IOF,!,IOINHI,?40," Welcome ",!,?36," to the ",!,?28," List Manager WorkBench ",IOINORM,!
15 N DIC,Y
16 S DIC=409.61,DIC(0)="AELMQ" D ^DIC K DIC
17 I Y<0 S VALMQUIT=1 G INITQ
18 S VALMIFN=+Y
19 I $P(Y,U,3) D EN^VALMW4(VALMIFN)
20 D BLD,HDR
21INITQ Q
22 ;
23BLD ; -- list builder
24 N I,DR,DIC,DIQ,VALME
25 D CLEAN^VALM10,KILL^VALM10()
26 F I=1:1:30 D BLANK(.I)
27 S DA=VALMIFN,DR=".01:107",DIQ(0)="E",DIC="^SD(409.61,",DIQ="VALME"
28 D EN^DIQ1
29 D DEMOS,REGION,PRTCL,MISC,CODE,CAP
30 S:VALMCNT<30 VALMCNT=30
31 Q
32 ;
33FNL ; -- exit code
34 K VALMIFN,VALMUMPS
35 D CLEAN^VALM10
36 Q
37 ;
38DEMOS ; -- demographics
39 N OFFSET,START
40 S OFFSET=2,START=1
41 D SET(START,OFFSET," Demographics ",IORVON,IORVOFF)
42 D SET(START+1,OFFSET,"Template Name: "_VALME(409.61,VALMIFN,.01,"E"))
43 D SET(START+2,OFFSET," Entity Name: "_VALME(409.61,VALMIFN,.09,"E"))
44 D SET(START+3,OFFSET," Screen Title: "_VALME(409.61,VALMIFN,.11,"E"))
45 Q
46 ;
47REGION ; -- list region
48 N OFFSET,START
49 S OFFSET=52,START=1
50 D SET(START,OFFSET," List Region ",IORVON,IORVOFF)
51 D SET(START+1,OFFSET," Top Margin: "_$J(VALME(409.61,VALMIFN,.05,"E"),3))
52 D SET(START+2,OFFSET,"Bottom "" : "_$J(VALME(409.61,VALMIFN,.06,"E"),3))
53 D SET(START+3,OFFSET," Right "" : "_$J(VALME(409.61,VALMIFN,.04,"E"),3))
54 Q
55 ;
56PRTCL ; -- protocol info
57 N OFFSET,START
58 S OFFSET=2,START=7
59 D SET(START,OFFSET," Protocol Information ",IORVON,IORVOFF)
60 D SET(START+1,OFFSET," Type of List: "_VALME(409.61,VALMIFN,.02,"E"))
61 D SET(START+2,OFFSET," Protocol Menu: "_VALME(409.61,VALMIFN,.1,"E"))
62 D SET(START+3,OFFSET,"Print Protocol: "_VALME(409.61,VALMIFN,1.01,"E"))
63 D SET(START+4,OFFSET," Hidden Menu: "_VALME(409.61,VALMIFN,1.02,"E"))
64 Q
65 ;
66CODE ; -- mumps code display
67 N OFFSET,START
68 S OFFSET=2,START=16
69 D SET(START,OFFSET," MUMPS Code Related ",IORVON,IORVOFF)
70 D SET(START+1,OFFSET,"Header: "_VALME(409.61,VALMIFN,100,"E"))
71 D SET(START+2,OFFSET," Entry: "_VALME(409.61,VALMIFN,106,"E"))
72 D SET(START+3,OFFSET," Exit: "_VALME(409.61,VALMIFN,105,"E"))
73 D SET(START+4,OFFSET,"Expand: "_VALME(409.61,VALMIFN,102,"E"))
74 D SET(START+5,OFFSET," Help: "_VALME(409.61,VALMIFN,103,"E"))
75 D SET(START+6,OFFSET," Array: "_VALME(409.61,VALMIFN,107,"E"))
76 Q
77 ;
78CAP ; -- caption display
79 N OFFSET,START
80 S OFFSET=2,START=24
81 D SET(START,OFFSET," Caption Line Information ",IORVON,IORVOFF)
82 D SET(START+1,OFFSET,"Name",IOUON,IOUOFF)
83 D SET(START+1,OFFSET+10,"Column",IOUON,IOUOFF)
84 D SET(START+1,OFFSET+20,"Width",IOUON,IOUOFF)
85 D SET(START+1,OFFSET+30,"Display Text",IOUON,IOUOFF)
86 D SET(START+1,OFFSET+60,"Video",IOUON,IOUOFF)
87 D SET(START+1,OFFSET+67,"Scroll Lock",IOUON,IOUOFF)
88 S CNT=1,I=0
89 F S I=$O(^SD(409.61,VALMIFN,"COL",I)) Q:'I S X=^(I,0) D
90 .S CNT=CNT+1
91 .D SET(START+CNT,OFFSET,$P(X,U))
92 .D SET(START+CNT,OFFSET+10,$J($P(X,U,2),3))
93 .D SET(START+CNT,OFFSET+20,$J($P(X,U,3),3))
94 .D SET(START+CNT,OFFSET+30,$E($P(X,U,4),1,30))
95 .D SET(START+CNT,OFFSET+60,$P(X,U,5))
96 .D SET(START+CNT,OFFSET+67,$S($P(X,U,6):"YES",1:"NO"))
97 S VALMCNT=START+CNT
98 Q
99 ;
100MISC ; -- other fields
101 N OFFSET,START
102 S OFFSET=45,START=7
103 D SET(START,OFFSET+7," Other Fields ",IORVON,IORVOFF)
104 D SET(START+1,OFFSET," OK to Transport?: "_VALME(409.61,VALMIFN,.07,"E"))
105 D SET(START+2,OFFSET," Use Cursor Control: "_VALME(409.61,VALMIFN,.08,"E"))
106 D SET(START+3,OFFSET,"Allowable Number of Actions: "_VALME(409.61,VALMIFN,.12,"E"))
107 D SET(START+4,OFFSET," Date Range Limit: "_VALME(409.61,VALMIFN,.13,"E"))
108 D SET(START+5,OFFSET," Automatic Defaults: "_VALME(409.61,VALMIFN,.14,"E"))
109 Q
110 ;
111SET(LINE,COL,TEXT,ON,OFF) ; -- set display info in array
112 D:'$D(@VALMAR@(LINE,0)) BLANK(.LINE)
113 D SET^VALM10(.LINE,$$SETSTR^VALM1(.TEXT,@VALMAR@(LINE,0),.COL,$L(TEXT)))
114 D:$G(ON)]""!($G(OFF)]"") CNTRL^VALM10(.LINE,.COL,$L(TEXT),$G(ON),$G(OFF))
115 W:'(LINE#5) "."
116 Q
117 ;
118BLANK(LINE) ; -- build blank line
119 D SET^VALM10(.LINE,$J("",80))
120 Q
Note: See TracBrowser for help on using the repository browser.