source: FOIAVistA/trunk/r/ONCOLOGY-ONC/ONCNPC4.m@ 1582

Last change on this file since 1582 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 4.7 KB
Line 
1ONCNPC4 ;HIRMFO/GWB - PCE Study of Non-Hodgkin's Lymphoma - Table IV;4/18/97
2 ;;2.11;ONCOLOGY;**11,15,16,22**;Mar 07, 1995
3 K ONC,TABLE,HTABLE
4 S TABLE("DATE OF FIRST COURSE OF TREATMENT")="DOFCT^ONCNPC4"
5 S TABLE("SURGERY")="S^ONCNPC4"
6 S TABLE("RADIATION THERAPY")="R^ONCNPC4"
7 S TABLE("CHEMOTHERAPY")="C^ONCNPC4"
8 S TABLE("SYSTEMIC CHEMOTHERAPY")="SC^ONCNPC4A"
9 S TABLE("INTRATHECAL CHEMOTHERAPY")="IC^ONCNPC4A"
10 S TABLE("IMMUNOTHERAPY")="I^ONCNPC4A"
11 S HTABLE(1)="DATE OF FIRST COURSE OF TREATMENT"
12 S HTABLE(2)="SURGERY"
13 S HTABLE(3)="RADIATION THERAPY"
14 S HTABLE(4)="CHEMOTHERAPY"
15 S HTABLE(5)="SYSTEMIC CHEMOTHERAPY"
16 S HTABLE(6)="INTRATHECAL CHEMOTHERAPY"
17 S HTABLE(7)="IMMUNOTHERAPY"
18 S CHOICES=7
19 S D0=ONCONUM D DFC^ONCOCOM S DOFCT=Y
20 S DIC="^ONCO(165.5,",DR="50;51.2;53;53.2;58.2",DA=ONCONUM
21 S DIQ="ONC",DIQ(0)="IE" D EN^DIQ1
22 S CDS=ONC(165.5,ONCONUM,58.2,"E")
23 S RAD=ONC(165.5,ONCONUM,51.2,"I"),RADOT=ONC(165.5,ONCONUM,51.2,"E")
24 S CHEMO=ONC(165.5,ONCONUM,53.2,"I"),CHEMOT=ONC(165.5,ONCONUM,53.2,"E")
25 W @IOF D HEAD^ONCNPC0
26 W !?22,"TABLE IV - FIRST COURSE OF TREATMENT"
27 W !?22,"------------------------------------"
28 S DIE="^ONCO(165.5,",DA=ONCONUM
29DOFCT W !,"DATE OF FIRST COURSE OF TREATMENT.: ",DOFCT
30S W !!,"SURGERY"
31 W !,"-------"
32CDSDT S CDSDT=$P($G(^ONCO(165.5,ONCONUM,3)),U,1)
33 S Y=CDSDT D DATEOT^ONCOPCE S CDSDT=Y
34 S (CDS1,CDS2)="",LOS=$L(CDS) I LOS<46 S CDS1=CDS G CDS
35 S NOP=$L($E(CDS,1,46)," ")
36 S CDS1=$P(CDS," ",1,NOP-1),CDS2=$P(CDS," ",NOP,999)
37CDS W !," SURGERY OF PRIMARY SITE DATE....: ",CDSDT
38 W !," SURGERY OF PRIMARY SITE.........: ",CDS1 W:CDS2'="" !,?39,CDS2
39 I (CDS="")!($E(CDS,1,2)="00") D G:(Y=0)!(Y="") EXIT G R
40 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,10)="C888"
41 .W !," EXTRANODAL SURGERY SITE.........: None"
42 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,11)="00"
43 .W !," EXTRANODAL SURGICAL PROCEDURE...: 00 No additional surgical procedures"
44 .W ! K DIR S DIR(0)="E" D ^DIR Q:(Y=0)!(Y="") D HEAD^ONCNPC0
45 S DR="855 EXTRANODAL SURGERY SITE........." D ^DIE G:$D(Y) JUMP
46 S DR="856 EXTRANODAL SURGICAL PROCEDURE..." D ^DIE G:$D(Y) JUMP
47R W !!,"RADIATION THERAPY"
48 W !,"-----------------"
49 S RADDT=$P($G(^ONCO(165.5,ONCONUM,3)),U,4)
50 S Y=RADDT D DATEOT^ONCOPCE S RADDT=Y
51 W !," RADIATION DATE..................: ",RADDT
52 W !," RADIATION ......................: ",RADOT
53 I RAD=0 D G C
54 .W !!," IRRADIATED FIELDS:",!
55 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,12)=2
56 .W !," LYMPH NODES ABOVE DIAPHRAGM...: Not irradiated"
57 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,13)=2
58 .W !," LYMPH NODES BELOW DIAPHRAGM...: Not irradiated"
59 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,14)=2
60 .W !," BRAIN.........................: Not irradiated"
61 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,15)=2
62 .W !," OTHER EXTRANODAL SITE(S)......: Not irradiated"
63 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,16)=2
64 .W !," TOTAL BODY....................: Not irradiated"
65 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,17)=8
66 .W !!," RADIATION/CHEMOTHERAPY SEQUENCE.: NA, no radiation and/or no chemo given"
67 .W ! K DIR S DIR(0)="E" D ^DIR Q:(Y=0)!(Y="") D HEAD^ONCNPC0
68 I RAD=9 D G C
69 .W !!," IRRADIATED FIELDS:",!
70 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,12)=8
71 .W !," LYMPH NODES ABOVE DIAPHRAGM...: NA, unknown if radiation therapy given"
72 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,13)=8
73 .W !," LYMPH NODES BELOW DIAPHRAGM...: NA, unknown if radiation therapy given"
74 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,14)=8
75 .W !," BRAIN.........................: NA, unknown if radiation therapy given"
76 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,15)=8
77 .W !," OTHER EXTRANODAL SITE(S)......: NA, unknown if radiation therapy given"
78 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,16)=8
79 .W !," TOTAL BODY....................: NA, unknown if radiation therapy given"
80 .S $P(^ONCO(165.5,ONCONUM,"NHL2"),U,17)=7
81 .W !!," RADIATION/CHEMOTHERAPY SEQUENCE.: Unknown if radiation and/or chemo given"
82 W !!," IRRADIATED FIELDS:",!
83 S DR="857 LYMPH NODES ABOVE DIAPHRAGM..." D ^DIE G:$D(Y) JUMP
84 S DR="858 LYMPH NODES BELOW DIAPHRAGM..." D ^DIE G:$D(Y) JUMP
85 S DR="859 BRAIN........................." D ^DIE G:$D(Y) JUMP
86 S DR="860 OTHER EXTRANODAL SITE(S)......" D ^DIE G:$D(Y) JUMP
87 S DR="861 TOTAL BODY...................." D ^DIE G:$D(Y) JUMP W !
88 S DR="862 RADIATION/CHEMOTHERAPY SEQUENCE." D ^DIE G:$D(Y) JUMP W !
89C W !!,"CHEMOTHERAPY"
90 W !,"------------"
91 S DR="863 PROTOCOL........................" D ^DIE G:$D(Y) JUMP
92 D SC^ONCNPC4A
93 G EXIT
94JUMP ;Jump to prompts
95 S XX="" R !!,"GO TO: ",X:DTIME I (X="")!(X[U) S OUT="Y" G EXIT
96 I X["?" D G JUMP
97 .W !,"CHOOSE FROM:" F I=1:1:CHOICES W !,?5,HTABLE(I)
98 I '$D(TABLE(X)) S XX=X,X=$O(TABLE(X)) I ($P(X,XX,1)'="")!(X="") W *7,"??" D G JUMP
99 .W !,"CHOOSE FROM:" F I=1:1:CHOICES W !,?5,HTABLE(I)
100 S X=TABLE(X)
101 G @X
102EXIT K CHOICES,HTABLE,TABLE
103 K CDS,CDS1,CDS2,CDSDT,CHEMO,DOFCT,LOS,NOP,RAD,RADOT,RADDT,DIQ
104 Q
Note: See TracBrowser for help on using the repository browser.