source: FOIAVistA/trunk/r/PAID-PRS/PRSATH.m@ 1410

Last change on this file since 1410 was 628, checked in by George Lilly, 15 years ago

initial load of FOIAVistA 6/30/08 version
File size: 1.6 KB
Line 
1PRSATH ; HISC/FPT-Transmission History ;12/16/92 14:06
2 ;;4.0;PAID;;Sep 21, 1995
3 ;
4 ; ACKNOW = Number of messages acknowledged by Austin
5 ; PPIEN = Pay period internal entry number
6 ; MSGIEN = MailMan message internal entry number
7 ; TRANS = Number of messages transmitted to Austin
8 ;
9 K DIC S DIC="^PRST(458,",DIC(0)="AEMQZ" S PPIEN=$P($G(^PRST(458,0)),U,3) I PPIEN<1 D KILL Q
10 S DIC("B")=$P(^PRST(458,PPIEN,0),U,1) D ^DIC K DIC I +Y<1 D KILL Q
11 S PPIEN=+Y
12 W:$Y>0 @IOF,!!?21,"Transmission History for Pay Period ",$P($P(^PRST(458,PPIEN,0),U),"-",2),!
13 S X=$G(^PRST(458,PPIEN,0))
14 W !,"Transmitting Clerk: ",?50 S Y=$P(X,"^",2) W $P($G(^VA(200,+Y,0)),U)
15 W !,"Transmitting Date/Time: ",?50 S Y=$P(X,"^",3) D DT
16 W !!,"Total Number of Employees Transmitted: ",?50,$P(X,"^",4)
17 W !,"Total Number of Records Transmitted: ",?50,$P(X,"^",5),!
18MSGIEN ; count messages transmitted to and acknowledged by Austin
19 S (ACKNOW,MSGIEN,TRANS)=0
20 F S MSGIEN=$O(^PRST(458,PPIEN,"X",MSGIEN)) Q:MSGIEN<1 S TRANS=TRANS+1 D
21 .S X=+$O(^XMB(3.9,MSGIEN,1,"C","XXX@Q-TAB.VA.GOV",0)) I X<1!('$D(^XMB(3.9,MSGIEN,1,X,0))) W !,"MESSAGE# ",MSGIEN," NO LONGER EXISTS",*7 Q
22 .S:$P(^XMB(3.9,MSGIEN,1,X,0),"^",4)'="" ACKNOW=ACKNOW+1
23 W !!,"Total Number of Messages for Transmission: ",?50,TRANS
24 W !,"Number of Messages Acknowledged by Austin: ",?50,ACKNOW
25 W ! K DIR S DIR(0)="E",DIR("A")="Press RETURN to Continue" D ^DIR
26KILL K %,DIR,DIROUT,DIRUT,DTOUT,DUOUT,ACKNOW,MSGIEN,PPIEN,TRANS,X,Y Q
27 ;
28DT ; Date/time converter
29 I Y W $P("JAN^FEB^MAR^APR^MAY^JUN^JUL^AUG^SEP^OCT^NOV^DEC",U,$E(Y,4,5))_" " W:Y#100 $J(Y#100\1,2)_"," W Y\10000+1700 W:Y#1 " "_$E(Y_0,9,10)_":"_$E(Y_"000",11,12)
30 Q
Note: See TracBrowser for help on using the repository browser.