| 1 | DGPFRAL ;ALB/RBS - PRF ACTION NOT LINKED REPORT ; 7/26/05 3:18pm
|
|---|
| 2 | ;;5.3;Registration;**554**;Aug 13, 1993
|
|---|
| 3 | ;
|
|---|
| 4 | ;This routine will be used for selecting sort parameters to produce
|
|---|
| 5 | ;the DGPF ACTION NOT LINKED REPORT for Patient Record Flags.
|
|---|
| 6 | ;
|
|---|
| 7 | ; Selection options will provide the ability to report by:
|
|---|
| 8 | ; CATEGORY
|
|---|
| 9 | ; BEGINNING DATE
|
|---|
| 10 | ; ENDING DATE
|
|---|
| 11 | ;
|
|---|
| 12 | ; The following reporting sort array will be built by user prompts:
|
|---|
| 13 | ; DGSORT("DGCAT") = CATEGORY
|
|---|
| 14 | ; 1^Category I (National)
|
|---|
| 15 | ; 2^Category II (Local)
|
|---|
| 16 | ; 3^Both
|
|---|
| 17 | ; DGSORT("DGBEG") = BEGINNING DATE (internal FileMan date)
|
|---|
| 18 | ; DGSORT("DGEND") = ENDING DATE (internal FileMan date)
|
|---|
| 19 | ;
|
|---|
| 20 | ;-- no direct entry
|
|---|
| 21 | QUIT
|
|---|
| 22 | ;
|
|---|
| 23 | EN ;Entry point
|
|---|
| 24 | ;-- user prompts for report selection sorts
|
|---|
| 25 | ; Input: none
|
|---|
| 26 | ; Output: Report generated using user selected parameters
|
|---|
| 27 | ;
|
|---|
| 28 | N DGASK ;return value from $$ANSWER^DGPFUT call
|
|---|
| 29 | N DGCAT ;flag category to report on
|
|---|
| 30 | N DGDIRA ;DGDIRA - DIR("A") string
|
|---|
| 31 | N DGDIRB ;DGDIRB - DIR("B") string
|
|---|
| 32 | N DGDIRH ;DGDIRH - DIR("?") string
|
|---|
| 33 | N DGDIRO ;DGDIR0 - DIR(0) string
|
|---|
| 34 | N DGFIRST ;first assignment date
|
|---|
| 35 | N DGSEL ;help text var
|
|---|
| 36 | N DGSORT ;array or report parameters
|
|---|
| 37 | N ZTSAVE ;open array reference of input parameters used by tasking
|
|---|
| 38 | ;
|
|---|
| 39 | S DGFIRST=$P(+$O(^DGPF(26.14,"D","")),".") ;first assignment date
|
|---|
| 40 | I 'DGFIRST D Q
|
|---|
| 41 | . W !?2,">>> No Patient Record Flag Assignments have been found.",*7
|
|---|
| 42 | . I $$ANSWER^DGPFUT("Enter RETURN to continue","","E") ;pause
|
|---|
| 43 | ;
|
|---|
| 44 | ;-- prompt for selection of a flag category
|
|---|
| 45 | S DGDIRA="Select Flag Category"
|
|---|
| 46 | S DGDIRB=""
|
|---|
| 47 | S DGDIRH="Enter one of the category selections to report on"
|
|---|
| 48 | S DGDIRO="S^1:Category I (National);2:Category II (Local);3:Both"
|
|---|
| 49 | S DGASK=$$ANSWER^DGPFUT(DGDIRA,DGDIRB,DGDIRO,DGDIRH)
|
|---|
| 50 | Q:(DGASK<1)
|
|---|
| 51 | S DGCAT=DGASK,DGSORT("DGCAT")=DGASK_U_$S(DGCAT=1:"Category I (National)",DGCAT=2:"Category II (Local)",DGCAT=3:"Both",1:"")
|
|---|
| 52 | ;
|
|---|
| 53 | ;-- prompt for beginning date
|
|---|
| 54 | S DGDIRA="Select Beginning Date"
|
|---|
| 55 | S DGDIRB=""
|
|---|
| 56 | S DGDIRH="^D HELP^DGPFRAL(1)"
|
|---|
| 57 | S DGDIRO="D^"_DGFIRST_":DT:EX"
|
|---|
| 58 | S DGASK=$$ANSWER^DGPFUT(DGDIRA,DGDIRB,DGDIRO,DGDIRH)
|
|---|
| 59 | Q:(DGASK=-1)
|
|---|
| 60 | S DGSORT("DGBEG")=DGASK
|
|---|
| 61 | ;
|
|---|
| 62 | ;-- prompt for ending date
|
|---|
| 63 | S DGDIRA="Select Ending Date"
|
|---|
| 64 | S DGDIRB=""
|
|---|
| 65 | S DGDIRH="^D HELP^DGPFRAL(2)"
|
|---|
| 66 | S DGDIRO="D^"_DGSORT("DGBEG")_":DT:EX"
|
|---|
| 67 | S DGASK=$$ANSWER^DGPFUT(DGDIRA,DGDIRB,DGDIRO,DGDIRH)
|
|---|
| 68 | Q:(DGASK=-1)
|
|---|
| 69 | S DGSORT("DGEND")=DGASK
|
|---|
| 70 | ;
|
|---|
| 71 | K DGCAT,DGDIRA,DGDIRB,DGDIRO,DGDIRH,DGASK,DGFIRST
|
|---|
| 72 | ;
|
|---|
| 73 | ;-- prompt for device
|
|---|
| 74 | S ZTSAVE("DGSORT(")=""
|
|---|
| 75 | D EN^XUTMDEVQ("START^DGPFRAL1","Assignment Action Not Linked to a Progress Note Report",.ZTSAVE)
|
|---|
| 76 | D HOME^%ZIS
|
|---|
| 77 | Q
|
|---|
| 78 | ;
|
|---|
| 79 | HELP(DGSEL) ;provide extended DIR("?") help text.
|
|---|
| 80 | ;
|
|---|
| 81 | ; Input: DGSEL - prompt var for help text word selection
|
|---|
| 82 | ; Output: none
|
|---|
| 83 | ;
|
|---|
| 84 | W !," Enter the "_$S(DGSEL=1:"earliest",1:"latest")_" Assignment Action Date to include in the report."
|
|---|
| 85 | W !," Please enter a date from the specified date range displayed."
|
|---|
| 86 | Q
|
|---|
