source: Scheduling/branches/Radiology-Support/m/BSDX07.m@ 1150

Last change on this file since 1150 was 1141, checked in by Sam Habiel, 14 years ago

BSDX32: Hospital Location has extra column IS_RADIOLOGY_LOCATION to link if that HL is tied to the Radiology Package
BDDX01: GETRADEX: Get Radiology Exams for a Patient in a specific HL;
BSDX01: SCHRAEX: Schedule Radiology Exam
BSDX01: HOLDRAEX: Hold Radiology Exam
BSDX02: Added Radiology Exam Field, to retrieve Radiology Exam associated with appt
BSDX07: Support for adding Radiology Exams to Appointment. BSDX APPOINTMENT file now has a Radiology Exam that points to file 75.1 (RAD/NUC MED ORDERS)
BSDX28: Added support for searching by DFN from Scheduling GUI by accent grave notation.
File size: 14.5 KB
Line 
1BSDX07 ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 4/11/11 12:12pm
2 ;;1.6;BSDX;;Mar 16, 2011
3 ;
4 ; Change Log:
5 ; UJO/SMH
6 ; v1.3 July 13 2010 - Add support i18n - Dates input as FM dates, not US.
7 ; v1.42 Oct 22 2010 - Transaction now restartable by providing arguments
8 ; thanks to Rick Marshall and Zach Gonzalez at Oroville.
9 ; v1.42 Oct 30 2010 - Extensive refactoring.
10 ; v1.5 Mar 15 2011 - End time does not have to have time anymore.
11 ; It could be midnight of the next day
12 ; v1.6 Apr 11 2011 - Support for Scheduling Radiology Exams...
13 ;
14 ; Error Reference:
15 ; -1: Patient Record is locked. This means something is wrong!!!!
16 ; -2: Start Time is not a valid Fileman date
17 ; -3: End Time is not a valid Fileman date
18 ; v1.5:obsolete::-4: End Time does not have time inside of it.
19 ; -5: BSDXPATID is not numeric
20 ; -6: Patient Does not exist in ^DPT
21 ; -7: Resource Name does not exist in B index of BSDX RESOURCE
22 ; -8: Resouce doesn't exist in ^BSDXRES
23 ; -9: Couldn't add appointment to BSDX APPOINTMENT
24 ; -10: Couldn't add appointment to files 2 and/or 44
25 ; -100: Mumps Error
26
27APPADDD(BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID) ;EP
28 ;Entry point for debugging
29 D DEBUG^%Serenji("APPADD^BSDX07(.BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID)")
30 Q
31 ;
32UT ; Unit Tests
33 N ZZZ
34 ; Test for bad start date
35 D APPADD(.ZZZ,2100123,3100123.3,2,"Dr Office",30,"Sam's Note",1)
36 I +$P(^BSDXTMP($J,1),U,2)'=-2 W "Error in -2",!
37 ; Test for bad end date
38 D APPADD(.ZZZ,3100123,2100123.3,2,"Dr Office",30,"Sam's Note",1)
39 I +$P(^BSDXTMP($J,1),U,2)'=-3 W "Error in -3",!
40 ; Test for end date without time
41 D APPADD(.ZZZ,3100123.1,3100123,2,"Dr Office",30,"Sam's Note",1)
42 I +$P(^BSDXTMP($J,1),U,2)'=-4 W "Error in -4",!
43 ; Test for mumps error
44 S bsdxdie=1
45 D APPADD(.ZZZ,3100123.09,3100123.093,2,"Dr Office",30,"Sam's Note",1)
46 I +$P(^BSDXTMP($J,1),U,2)'=-100 W "Error in -100: M Error",!
47 K bsdxdie
48 ; Test for TRESTART
49 s bsdxrestart=1
50 D APPADD(.ZZZ,3100123.09,3100123.093,3,"Dr Office",30,"Sam's Note",1)
51 I +$P(^BSDXTMP($J,1),U,2)'=0&(+$P(^BSDXTMP($J,1),U,2)'=-10) W "Error in TRESTART",!
52 k bsdxrestart
53 ; Test for non-numeric patient
54 D APPADD(.ZZZ,3100123.09,3100123.093,"CAT,DOG","Dr Office",30,"Sam's Note",1)
55 I +$P(^BSDXTMP($J,1),U,2)'=-5 W "Error in -5",!
56 ; Test for a non-existent patient
57 D APPADD(.ZZZ,3100123.09,3100123.093,8989898989,"Dr Office",30,"Sam's Note",1)
58 I +$P(^BSDXTMP($J,1),U,2)'=-6 W "Error in -6",!
59 ; Test for a non-existent resource name
60 D APPADD(.ZZZ,3100123.09,3100123.093,3,"lkajsflkjsadf",30,"Sam's Note",1)
61 I +$P(^BSDXTMP($J,1),U,2)'=-7 W "Error in -7",!
62 ; Test for corrupted resource
63 ; Can't test for -8 since it requires DB corruption
64 ; Test for inability to add appointment to BSDX Appointment
65 ; Also requires something wrong in the DB
66 ; Test for inability to add appointment to 2,44
67 ; Test by creating a duplicate appointment
68 D APPADD(.ZZZ,3100123.09,3100123.093,3,"Dr Office",30,"Sam's Note",1)
69 D APPADD(.ZZZ,3100123.09,3100123.093,3,"Dr Office",30,"Sam's Note",1)
70 I +$P(^BSDXTMP($J,1),U,2)'=-10 W "Error in -10",!
71 ; Test for normality:
72 D APPADD(.ZZZ,3110123.09,3110123.093,3,"Dr Office",30,"Sam's Note",1)
73 ; Does Appt exist?
74 N APPID S APPID=+$P(^BSDXTMP($J,1),U)
75 I 'APPID W "Error Making Appt-1" QUIT
76 I +^BSDXAPPT(APPID,0)'=3110123.09 W "Error Making Appt-2"
77 I '$D(^DPT(3,"S",3110123.09)) W "Error Making Appt-3"
78 I '$D(^SC(2,"S",3110123.09)) W "Error Making Appt-4"
79 QUIT
80 ;
81APPADD(BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID,BSDXRADEXAM) ;EP
82 ;
83 ;Called by RPC: BSDX ADD NEW APPOINTMENT
84 ;
85 ;Add new appointment to 3 files
86 ; - BSDX APPOINTMENT
87 ; - Hosp Location Appointment SubSubfile if Resource is linked to clinic
88 ; - Patient Appointment Subfile if Resource is linked to clinic
89 ;
90 ;Paramters:
91 ;BSDXY: Global Return (RPC must be set to Global Array)
92 ;BSDXSTART: FM Start Date
93 ;BSDXEND: FM End Date
94 ;BSDXPATID: Patient DFN
95 ;BSDXRES is ResourceName in BSDX RESOURCE file (not IEN)
96 ;BSDXLEN is the appointment duration in minutes
97 ;BSDXNOTE is the Appiontment Note
98 ;BSDXATID is used for 2 purposes:
99 ; if BSDXATID = "WALKIN" then BSDAPI is called to create a walkin appt.
100 ; if BSDXATID = a number, then it is the access type id (used for rebooking)
101 ;BSDXRADEXAM is used to store the Radiology Exam to which this appointment is tied to (optional)
102 ;
103 ;Return:
104 ; ADO.net Recordset having fields:
105 ; AppointmentID and ErrorNumber
106 ;
107 ;Test lines:
108 ;BSDX ADD NEW APPOINTMENT^3091122.0930^3091122.1000^370^Dr Office^30^EXAM^WALKIN
109 ;
110 ; Deal with optional arguments
111 S BSDXRADEXAM=$G(BSDXRADEXAM)
112 ; Return Array; set Return and clear array
113 S BSDXY=$NA(^BSDXTMP($J))
114 K ^BSDXTMP($J)
115 ; $ET
116 N $ET S $ET="G ETRAP^BSDX07"
117 ; Counter
118 N BSDXI S BSDXI=0
119 ; Lock BSDX node, only to synchronize access to the globals.
120 ; It's not expected that the error will ever happen as no filing
121 ; is supposed to take 5 seconds.
122 L +^BSDXAPPT(BSDXPATID):5 I '$T D ERR(BSDXI,"-1~Patient record is locked. Please contact technical support.") Q
123 ; Header Node
124 S ^BSDXTMP($J,BSDXI)="I00020APPOINTMENTID^T00100ERRORID"_$C(30)
125 ;Restartable Transaction; restore paramters when starting.
126 ; (Params restored are what's passed here + BSDXI)
127 TSTART (BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID,BSDXI):T="BSDX ADD NEW APPOINTMENT^BSDX07"
128 ;
129 ; Turn off SDAM APPT PROTOCOL BSDX Entries
130 N BSDXNOEV
131 S BSDXNOEV=1 ;Don't execute BSDX ADD APPOINTMENT protocol
132 ;
133 ; Set Error Message to be empty
134 N BSDXERR S BSDXERR=0
135 ;
136 ;;;test for error inside transaction. See if %ZTER works
137 I $G(bsdxdie) S X=1/0
138 ;;;test
139 ;;;test for TRESTART
140 I $G(bsdxrestart) K bsdxrestart TRESTART
141 ;;;test
142 ;
143 ; -- Start and End Date Processing --
144 ; If C# sends the dates with extra zeros, remove them
145 S BSDXSTART=+BSDXSTART,BSDXEND=+BSDXEND
146 ; Are the dates valid? Must be FM Dates > than 2010
147 I BSDXSTART'>3100000 D ERR(BSDXI,"-2~BSDX07 Error: Invalid Start Time") Q
148 I BSDXEND'>3100000 D ERR(BSDXI,"-3~BSDX07 Error: Invalid End Time") Q
149 ;
150 ;; If Ending date doesn't have a time, this is an error --rm 1.5
151 ; I $L(BSDXEND,".")=1 D ERR(BSDXI,"-4~BSDX07 Error: Invalid End Time") Q
152 ;
153 ; If the Start Date is greater than the end date, swap dates
154 N BSDXTMP
155 I BSDXSTART>BSDXEND S BSDXTMP=BSDXEND,BSDXEND=BSDXSTART,BSDXSTART=BSDXTMP
156 ;
157 ; Check if the patient exists:
158 ; - DFN valid number?
159 ; - Valid Patient in file 2?
160 I '+BSDXPATID D ERR(BSDXI,"-5~BSDX07 Error: Invalid Patient ID") Q
161 I '$D(^DPT(BSDXPATID,0)) D ERR(BSDXI,"-6~BSDX07 Error: Invalid Patient ID") Q
162 ;
163 ;Validate Resource entry
164 I '$D(^BSDXRES("B",BSDXRES)) D ERR(BSDXI,"-7~BSDX07 Error: Invalid Resource ID") Q
165 N BSDXRESD ; Resource IEN
166 S BSDXRESD=$O(^BSDXRES("B",BSDXRES,0))
167 N BSDXRNOD ; Resouce zero node
168 S BSDXRNOD=$G(^BSDXRES(BSDXRESD,0))
169 I BSDXRNOD="" D ERR(BSDXI,"-8~BSDX07 Error: invalid Resource entry.") Q
170 ;
171 ; Walk-in (Unscheduled) Appointment?
172 N BSDXWKIN S BSDXWKIN=0
173 I BSDXATID="WALKIN" S BSDXWKIN=1
174 ; Reset Access Type ID if it doesn't say "WALKIN" and isn't a number
175 I BSDXATID'?.N&(BSDXATID'="WALKIN") S BSDXATID=""
176 ;
177 ; Done with all checks, let's make appointment in BSDX APPOINTMENT
178 N BSDXAPPTID
179 S BSDXAPPTID=$$BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRESD,BSDXATID,BSDXRADEXAM)
180 I 'BSDXAPPTID D ERR(BSDXI,"-9~BSDX07 Error: Unable to add appointment to BSDX APPOINTMENT file.") Q
181 I BSDXNOTE]"" D BSDXWP(BSDXAPPTID,BSDXNOTE)
182 ;
183 ; Then Create Subfiles in 2/44 Appointment
184 N BSDXSCD S BSDXSCD=$P(BSDXRNOD,U,4) ; Hosp Location IEN
185 ; Only if we have a valid Hosp Loc can we make an appointment
186 I +BSDXSCD,$D(^SC(BSDXSCD,0)) D I +BSDXERR D ERR(BSDXI,"-10~BSDX07 Error: MAKE^BSDXAPI returned error code: "_BSDXERR) Q
187 . N BSDXC
188 . S BSDXC("PAT")=BSDXPATID
189 . S BSDXC("CLN")=BSDXSCD
190 . S BSDXC("TYP")=3 ;3 for scheduled appts, 4 for walkins
191 . S:BSDXWKIN BSDXC("TYP")=4
192 . S BSDXC("ADT")=BSDXSTART
193 . S BSDXC("LEN")=BSDXLEN
194 . S BSDXC("OI")=$E($G(BSDXNOTE),1,150) ;File 44 has 150 character limit on OTHER field
195 . S BSDXC("OI")=$TR(BSDXC("OI"),";"," ") ;No semicolons allowed by MAKE^BSDXAPI
196 . S BSDXC("OI")=$$STRIP(BSDXC("OI")) ;Strip control characters from note
197 . S BSDXC("USR")=DUZ
198 . S BSDXERR=$$MAKE^BSDXAPI(.BSDXC)
199 . Q:BSDXERR
200 . ;Update RPMS Clinic availability
201 . D AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN)
202 . Q
203 ;
204 ;Return Recordset
205 TCOMMIT
206 L -^BSDXAPPT(BSDXPATID)
207 S BSDXI=BSDXI+1
208 S ^BSDXTMP($J,BSDXI)=BSDXAPPTID_"^"_$C(30)
209 S BSDXI=BSDXI+1
210 S ^BSDXTMP($J,BSDXI)=$C(31)
211 Q
212BSDXDEL(BSDXAPPTID) ;Deletes appointment BSDXAPPTID from BSDXAPPOINTMETN
213 N DA,DIK
214 S DIK="^BSDXAPPT(",DA=BSDXAPPTID
215 D ^DIK
216 Q
217 ;
218STRIP(BSDXZ) ;Replace control characters with spaces
219 N BSDXI
220 F BSDXI=1:1:$L(BSDXZ) I (32>$A($E(BSDXZ,BSDXI))) S BSDXZ=$E(BSDXZ,1,BSDXI-1)_" "_$E(BSDXZ,BSDXI+1,999)
221 Q BSDXZ
222 ;
223BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRESD,BSDXATID,BSDXRADEXAM) ;ADD BSDX APPOINTMENT ENTRY
224 ;Returns ien in BSDXAPPT or 0 if failed
225 ;Create entry in BSDX APPOINTMENT
226 N BSDXAPPTID
227 S BSDXFDA(9002018.4,"+1,",.01)=BSDXSTART
228 S BSDXFDA(9002018.4,"+1,",.02)=BSDXEND
229 S BSDXFDA(9002018.4,"+1,",.05)=BSDXPATID
230 S BSDXFDA(9002018.4,"+1,",.07)=BSDXRESD
231 S BSDXFDA(9002018.4,"+1,",.08)=$G(DUZ)
232 S BSDXFDA(9002018.4,"+1,",.09)=$$NOW^XLFDT
233 S:BSDXATID="WALKIN" BSDXFDA(9002018.4,"+1,",.13)="y"
234 S:BSDXATID?.N BSDXFDA(9002018.4,"+1,",.06)=BSDXATID
235 S BSDXFDA(9002018.4,"+1,",.14)=BSDXRADEXAM
236 N BSDXIEN,BSDXMSG
237 D UPDATE^DIE("","BSDXFDA","BSDXIEN","BSDXMSG")
238 S BSDXAPPTID=+$G(BSDXIEN(1))
239 Q BSDXAPPTID
240 ;
241BSDXWP(BSDXAPPTID,BSDXNOTE) ;
242 ;Add WP field
243 I BSDXNOTE]"" S BSDXNOTE(.5)=BSDXNOTE,BSDXNOTE=""
244 I $D(BSDXNOTE(0)) S BSDXNOTE(.5)=BSDXNOTE(0) K BSDXNOTE(0)
245 I $D(BSDXNOTE(.5)) D
246 . D WP^DIE(9002018.4,BSDXAPPTID_",",1,"","BSDXNOTE","BSDXMSG")
247 Q
248 ;
249ADDEVT(BSDXPATID,BSDXSTART,BSDXSC,BSDXSCDA) ;EP
250 ;Called by BSDX ADD APPOINTMENT protocol
251 ;BSDXSC=IEN of clinic in ^SC
252 ;BSDXSCDA=IEN for ^SC(BSDXSC,"S",BSDXSTART,1,BSDXSCDA). Use to get Length & Note
253 ;
254 N BSDXNOD,BSDXLEN,BSDXAPPTID,BSDXNODP,BSDXWKIN,BSDXRES
255 Q:+$G(BSDXNOEV)
256 I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0))
257 E I $D(^BSDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0))
258 Q:'+$G(BSDXRES)
259 S BSDXNOD=$G(^SC(BSDXSC,"S",BSDXSTART,1,BSDXSCDA,0))
260 Q:BSDXNOD=""
261 S BSDXNODP=$G(^DPT(BSDXPATID,"S",BSDXSTART,0))
262 S BSDXWKIN=""
263 S:$P(BSDXNODP,U,7)=4 BSDXWKIN="WALKIN" ;Purpose of Visit field of DPT Appointment subfile
264 S BSDXLEN=$P(BSDXNOD,U,2)
265 Q:'+BSDXLEN
266 S BSDXEND=$$FMADD^XLFDT(BSDXSTART,0,0,BSDXLEN,0)
267 S BSDXAPPTID=$$BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXWKIN)
268 Q:'+BSDXAPPTID
269 S BSDXNOTE=$P(BSDXNOD,U,4)
270 I BSDXNOTE]"" D BSDXWP(BSDXAPPTID,BSDXNOTE)
271 D ADDEVT3(BSDXRES)
272 Q
273 ;
274ADDEVT3(BSDXRES) ;
275 ;Call RaiseEvent to notify GUI clients
276 N BSDXRESN
277 S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
278 Q:BSDXRESN=""
279 S BSDXRESN=$P(BSDXRESN,"^")
280 ;D EVENT^BSDX23("SCHEDULE-"_BSDXRESN,"","","")
281 D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
282 Q
283 ;
284ERR(BSDXI,BSDXERR) ;Error processing
285 S BSDXI=BSDXI+1
286 S BSDXERR=$TR(BSDXERR,"^","~")
287 I $TL>0 TROLLBACK
288 S ^BSDXTMP($J,BSDXI)="0^"_BSDXERR_$C(30)
289 S BSDXI=BSDXI+1
290 S ^BSDXTMP($J,BSDXI)=$C(31)
291 L -^BSDXAPPT(BSDXPATID)
292 Q
293 ;
294ETRAP ;EP Error trap entry
295 N $ET S $ET="D ^%ZTER HALT" ; Emergency Error Trap
296 ; Rollback, otherwise ^XTER will be empty from future rollback
297 I $TL>0 TROLLBACK
298 D ^%ZTER
299 S $EC="" ; Clear Error
300 ; Log error message and send to client
301 I '$D(BSDXI) N BSDXI S BSDXI=0
302 D ERR(BSDXI,"-100~BSDX07 Error: "_$G(%ZTERZE))
303 Q
304 ;
305DAY ;;^SUN^MON^TUES^WEDNES^THURS^FRI^SATUR
306 ;
307DOW S %=$E(X,1,3),Y=$E(X,4,5),Y=Y>2&'(%#4)+$E("144025036146",Y)
308 F %=%:-1:281 S Y=%#4=1+1+Y
309 S Y=$E(X,6,7)+Y#7
310 Q
311 ;
312AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN) ;Update RPMS Clinic availability
313 ;SEE SDM1
314 N Y,DFN
315 N SL,STARTDAY,X,SC,SB,HSI,SI,STR,SDDIF,SDMAX,SDDATE,SDDMAX,SDSDATE,CCXN,MXOK,COV,SDPROG
316 N X1,SDEDT,X2,SD,SM,SS,S,SDLOCK,ST,I
317 S Y=BSDXSCD,DFN=BSDXPATID
318 S SL=$G(^SC(+Y,"SL")),X=$P(SL,U,3),STARTDAY=$S($L(X):X,1:8),SC=Y,SB=STARTDAY-1/100,X=$P(SL,U,6),HSI=$S(X=1:X,X:X,1:4),SI=$S(X="":4,X<3:4,X:X,1:4),STR="#@!$* XXWVUTSRQPONMLKJIHGFEDCBA0123456789jklmnopqrstuvwxyz",SDDIF=$S(HSI<3:8/HSI,1:2) K Y
319 ;Determine maximum days for scheduling
320 S SDMAX(1)=$P($G(^SC(+SC,"SDP")),U,2) S:'SDMAX(1) SDMAX(1)=365
321 S (SDMAX,SDDMAX)=$$FMADD^XLFDT(DT,SDMAX(1))
322 S SDDATE=BSDXSTART
323 S SDSDATE=SDDATE,SDDATE=SDDATE\1
3241 ;L Q:$D(SDXXX) S CCXN=0 K MXOK,COV,SDPROT Q:DFN<0 S SC=+SC
325 Q:$D(SDXXX) S CCXN=0 K MXOK,COV,SDPROT Q:DFN<0 S SC=+SC
326 S X1=DT,SDEDT=365 S:$D(^SC(SC,"SDP")) SDEDT=$P(^SC(SC,"SDP"),"^",2)
327 S X2=SDEDT D C^%DTC S SDEDT=X
328 S Y=BSDXSTART
329EN1 S (X,SD)=Y,SM=0 D DOW
330S I '$D(^SC(SC,"ST",$P(SD,"."),1)) S SS=+$O(^SC(+SC,"T"_Y,SD)) Q:SS'>0 Q:^(SS,1)="" S ^SC(+SC,"ST",$P(SD,"."),1)=$E($P($T(DAY),U,Y+2),1,2)_" "_$E(SD,6,7)_$J("",SI+SI-6)_^(1),^(0)=$P(SD,".")
331 S S=BSDXLEN
332 ;Check if BSDXLEN evenly divisible by appointment length
333 S RPMSL=$P(SL,U)
334 I BSDXLEN<RPMSL S BSDXLEN=RPMSL
335 I BSDXLEN#RPMSL'=0 D
336 . S BSDXINC=BSDXLEN\RPMSL
337 . S BSDXINC=BSDXINC+1
338 . S BSDXLEN=RPMSL*BSDXINC
339 S SL=S_U_$P(SL,U,2,99)
340SC S SDLOCK=$S('$D(SDLOCK):1,1:SDLOCK+1) Q:SDLOCK>9
341 L +^SC(SC,"ST",$P(SD,"."),1):5 G:'$T SC
342 S SDLOCK=0,S=^SC(SC,"ST",$P(SD,"."),1)
343 S I=SD#1-SB*100,ST=I#1*SI\.6+($P(I,".")*SI),SS=SL*HSI/60*SDDIF+ST+ST
344 I (I<1!'$F(S,"["))&(S'["CAN") L -^SC(SC,"ST",$P(SD,"."),1) Q
345 I SM<7 S %=$F(S,"[",SS-1) S:'%!($P(SL,"^",6)<3) %=999 I $F(S,"]",SS)'<%!(SDDIF=2&$E(S,ST+ST+1,SS-1)["[") S SM=7
346 ;
347SP I ST+ST>$L(S),$L(S)<80 S S=S_" " G SP
348 S SDNOT=1
349 S ABORT=0
350 F I=ST+ST:SDDIF:SS-SDDIF D Q:ABORT
351 . S ST=$E(S,I+1) S:ST="" ST=" "
352 . S Y=$E(STR,$F(STR,ST)-2)
353 . I S["CAN"!(ST="X"&($D(^SC(+SC,"ST",$P(SD,"."),"CAN")))) S ABORT=1 Q
354 . I Y="" S ABORT=1 Q
355 . S:Y'?1NL&(SM<6) SM=6 S ST=$E(S,I+2,999) S:ST="" ST=" " S S=$E(S,1,I)_Y_ST
356 . Q
357 S ^SC(SC,"ST",$P(SD,"."),1)=S
358 L -^SC(SC,"ST",$P(SD,"."),1)
359 Q
Note: See TracBrowser for help on using the repository browser.