source: Scheduling/trunk/m/BSDX01.m@ 962

Last change on this file since 962 was 962, checked in by Sam Habiel, 14 years ago

First draft of division separation for Scheduling GUI
File size: 9.7 KB
Line 
1BSDX01 ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 9/16/10 9:54am
2 ;;1.4;BSDX;;Sep 07, 2010
3 ;
4 ;
5SUINFOD(BSDXY,BSDXDUZ) ;EP Debugging entry point
6 ;
7 ;
8 ;D DEBUG^%Serenji("SUINFO^BSDX01(.BSDXY,BSDXDUZ)")
9 ;
10 Q
11 ;
12SUINFO(BSDXY,BSDXDUZ) ;EP
13 ;Called by BSDX SCHEDULING USER INFO
14 ;Returns ADO Recordset having column MANAGER
15 ;MANAGER = YES if user has keys BSDXZMGR or XUPROGMODE
16 ;
17 N BSDXMGR,BSDXERR
18 K ^BSDXTMP($J)
19 S BSDXY="^BSDXTMP("_$J_")"
20 S BSDXI=0
21 S BSDXERR=""
22 S ^BSDXTMP($J,BSDXI)="T00010MANAGER"_$C(30)
23 ;Check SECURITY KEY file for BSDXZMGR or XUPROGMODE keys
24 I '+BSDXDUZ S BSDXDUZ=DUZ
25 S BSDXMGR=$$APSEC("BSDXZMGR",BSDXDUZ)
26 S BSDXMGR=$S(BSDXMGR=1:"YES",1:"NO")
27 S BSDXI=BSDXI+1
28 S ^BSDXTMP($J,BSDXI)=BSDXMGR_$C(30)
29 S ^BSDXTMP($J,BSDXI+1)=$C(31)_BSDXERR
30 Q
31DEPUSRD(BSDXY,BSDXDUZ) ;EP Debugging entry point
32 ;
33 ;
34 ;D DEBUG^%Serenji("DEPUSR^BSDX01(.BSDXY,BSDXDUZ)")
35 ;
36 Q
37 ;
38DEPUSR(BSDXY,BSDXDUZ) ;EP
39 ;Called by BSDX RESOURCE GROUPS BY USER
40 ;Returns ADO Recordset with all ACTIVE resource group names to which user has access
41 ;based on entries in BSDX RESOURCE USER file
42 ;If BSDXDUZ=0 then returns all department names for current DUZ
43 ;If user BSDXDUZ possesses the key BSDXZMGR or XUPROGMODE
44 ;then ALL resource group names are returned regardless of whether any active resources
45 ;are associated with the group or not.
46 ;
47 ;
48 N BSDXERR,BSDXRET,BSDXIEN,BSDXRES,BSDXDEP,BSDXDDR,BSDXDEPN,BSDXRDAT,BSDXRNOD,BSDXI
49 N BSDXMGR,BSDXNOD
50 K ^BSDXTEMP($J)
51 K ^BSDXTMP($J)
52 S BSDXY="^BSDXTMP("_$J_")"
53 S BSDXI=0
54 S BSDXERR=""
55 S ^BSDXTMP($J,BSDXI)="I00020RESOURCE_GROUPID^T00030RESOURCE_GROUP"_$C(30)
56 I '+BSDXDUZ S BSDXDUZ=DUZ
57 ;Check SECURITY KEY file for BSDXZMGR or XUPROGMODE keys
58 S BSDXMGR=$$APSEC("BSDXZMGR",BSDXDUZ)
59 ;
60 ;User does not have BSDXZMGR or XUPROGMODE keys, so
61 ;$O THRU AC XREF OF BSDX RESOURCE USER
62 I 'BSDXMGR,$D(^BSDXRSU("AC",BSDXDUZ)) S BSDXIEN=0 F S BSDXIEN=$O(^BSDXRSU("AC",BSDXDUZ,BSDXIEN)) Q:'+BSDXIEN D
63 . S BSDXRES=$P(^BSDXRSU(BSDXIEN,0),U)
64 . Q:'$D(^BSDXDEPT("AB",BSDXRES))
65 . S BSDXRNOD=^BSDXRES(BSDXRES,0)
66 . ;QUIT if the resource is inactive
67 . Q:$P(BSDXRNOD,U,2)=1
68 . S BSDXDEP=0 F S BSDXDEP=$O(^BSDXDEPT("AB",BSDXRES,BSDXDEP)) Q:'+BSDXDEP D
69 . . Q:'$D(^BSDXDEPT(BSDXDEP,0))
70 . . Q:$D(^BSDXTEMP($J,BSDXDEP))
71 . . S ^BSDXTEMP($J,BSDXDEP)=""
72 . . S BSDXDEPN=$P(^BSDXDEPT(BSDXDEP,0),U)
73 . . S BSDXI=BSDXI+1
74 . . S ^BSDXTMP($J,BSDXI)=BSDXDEP_U_BSDXDEPN_$C(30)
75 . . Q
76 . Q
77 ;
78 ;User does have BSDXZMGR or XUPROGMODE keys, so
79 ;$O THRU BSDX RESOURCE GROUP file directly
80 I BSDXMGR S BSDXIEN=0 F S BSDXIEN=$O(^BSDXDEPT(BSDXIEN)) Q:'+BSDXIEN D
81 . Q:'$D(^BSDXDEPT(BSDXIEN,0))
82 . S BSDXNOD=^BSDXDEPT(BSDXIEN,0)
83 . S BSDXDEPN=$P(BSDXNOD,U)
84 . S BSDXI=BSDXI+1
85 . S ^BSDXTMP($J,BSDXI)=BSDXIEN_U_BSDXDEPN_$C(30)
86 . Q
87 ;
88 S ^BSDXTMP($J,BSDXI+1)=$C(31)_BSDXERR
89 Q
90 ;
91 ;
92RESUSRD(BSDXY,BSDXDUZ) ;EP Debugging entry point
93 ;
94 ;
95 ;D DEBUG^%Serenji("RESUSR^BSDX01(.BSDXY,BSDXDUZ)")
96 ;
97 Q
98 ;
99RESUSR(BSDXY,BSDXDUZ) ;EP
100 ;Returns ADO Recordset with ALL RESOURCE names
101 ;Inactive RESOURCES are NOT filtered out
102 ;Called by BSDX RESOURCES BY USER
103 ;
104 N BSDXERR,BSDXRET,BSDXIEN,BSDXRES,BSDXDEP,BSDXDDR,BSDXDEPN,BSDXRDAT,BSDXRNOD,BSDXI,BSDX,BSDXLTR
105 N BSDXNOS,BSDXCAN
106 K ^BSDXTMP($J)
107 S BSDXY="^BSDXTMP("_$J_")"
108 S BSDXI=0
109 S BSDXERR=""
110 S ^BSDXTMP($J,BSDXI)="I00010RESOURCEID^T00030RESOURCE_NAME^T00010INACTIVE^I00010TIMESCALE^I00010HOSPITAL_LOCATION_ID^T00030LETTER_TEXT^T00030NO_SHOW_LETTER"
111 S ^BSDXTMP($J,BSDXI)=^(BSDXI)_"^T00030CLINIC_CANCELLATION_LETTER^I00010VIEW^I00010OVERBOOK^I00010MODIFY_SCHEDULE^I00010MODIFY_APPOINTMENTS"_$C(30)
112 I '+BSDXDUZ S BSDXDUZ=DUZ
113 ;$O THRU AC XREF OF BSDX RESOURCE USER
114 ;Rmoved these lines in order to just return all resource names
115 ;I $D(^BSDXRSU("AC",BSDXDUZ)) S BSDXIEN=0 F S BSDXIEN=$O(^BSDXRSU("AC",BSDXDUZ,BSDXIEN)) Q:'+BSDXIEN D
116 ;. S BSDXRES=$P(^BSDXRSU(BSDXIEN,0),U)
117 ;
118 ;$O THRU BSDX RESOURCE File
119 S BSDXRES=0 F S BSDXRES=$O(^BSDXRES(BSDXRES)) Q:'+BSDXRES D
120 . Q:'$D(^BSDXRES(BSDXRES,0))
121 . S BSDXRNOD=^BSDXRES(BSDXRES,0)
122 . N BSDXSC S BSDXSC=$P(BSDXRNOD,U,4) ; Hospital Location
123 . ;Q:$P(BSDXRNOD,U,2)=1 ;Inactive resources not filtered
124 . ;S BSDXRDAT=$P(BSDXRNOD,U,1,4)
125 . I '$$INDIV(BSDXSC) QUIT ; If not in division, quit
126 . K BSDXRDAT
127 . F BSDX=1:1:4 S $P(BSDXRDAT,U,BSDX)=$P(BSDXRNOD,U,BSDX)
128 . S BSDXRDAT=BSDXRES_U_BSDXRDAT
129 . ;Get letter text from wp field
130 . S BSDXLTR=""
131 . I $D(^BSDXRES(BSDXRES,1)) D
132 . . S BSDXIEN=0
133 . . F S BSDXIEN=$O(^BSDXRES(BSDXRES,1,BSDXIEN)) Q:'+BSDXIEN D
134 . . . S BSDXLTR=BSDXLTR_$G(^BSDXRES(BSDXRES,1,BSDXIEN,0))
135 . . . S BSDXLTR=BSDXLTR_$C(13)_$C(10)
136 . S BSDXNOS=""
137 . I $D(^BSDXRES(BSDXRES,12)) D
138 . . S BSDXIEN=0 F S BSDXIEN=$O(^BSDXRES(BSDXRES,12,BSDXIEN)) Q:'+BSDXIEN D
139 . . . S BSDXNOS=BSDXNOS_$G(^BSDXRES(BSDXRES,12,BSDXIEN,0))
140 . . . S BSDXNOS=BSDXNOS_$C(13)_$C(10)
141 . S BSDXCAN=""
142 . I $D(^BSDXRES(BSDXRES,13)) D
143 . . S BSDXIEN=0 F S BSDXIEN=$O(^BSDXRES(BSDXRES,13,BSDXIEN)) Q:'+BSDXIEN D
144 . . . S BSDXCAN=BSDXCAN_$G(^BSDXRES(BSDXRES,13,BSDXIEN,0))
145 . . . S BSDXCAN=BSDXCAN_$C(13)_$C(10)
146 . N BSDXACC,BSDXMGR
147 . S BSDXACC="0^0^0^0"
148 . S BSDXMGR=$O(^DIC(19.1,"B","BSDXZMGR",0))
149 . I +BSDXMGR,$D(^VA(200,BSDXDUZ,51,BSDXMGR)) S BSDXACC="1^1^1^1"
150 . S BSDXMGR=$O(^DIC(19.1,"B","XUPROGMODE",0))
151 . I +BSDXMGR,$D(^VA(200,BSDXDUZ,51,BSDXMGR)) S BSDXACC="1^1^1^1"
152 . I BSDXACC="0^0^0^0" D
153 . . N BSDXNOD,BSDXRUID
154 . . S BSDXRUID=0
155 . . ;Get entry for this user and resource
156 . . F S BSDXRUID=$O(^BSDXRSU("AC",BSDXDUZ,BSDXRUID)) Q:'+BSDXRUID I $D(^BSDXRSU(BSDXRUID,0)),$P(^(0),U)=BSDXRES Q
157 . . Q:'+BSDXRUID
158 . . S $P(BSDXACC,U)=1
159 . . S BSDXNOD=$G(^BSDXRSU(BSDXRUID,0))
160 . . S $P(BSDXACC,U,2)=+$P(BSDXNOD,U,3)
161 . . S $P(BSDXACC,U,3)=+$P(BSDXNOD,U,4)
162 . . S $P(BSDXACC,U,4)=+$P(BSDXNOD,U,5)
163 . S BSDXRDAT=BSDXRDAT_U_BSDXLTR_U_BSDXNOS_U_BSDXCAN_U_BSDXACC
164 . S BSDXI=BSDXI+1
165 . S ^BSDXTMP($J,BSDXI)=BSDXRDAT_$C(30)
166 S ^BSDXTMP($J,BSDXI+1)=$C(31)_BSDXERR
167 Q
168 ;
169DEPRESD(BSDXY,BSDXDUZ) ;EP Debugging entry point
170 ;
171 ;
172 ;D DEBUG^%Serenji("DEPRES^BSDX01(.BSDXY,BSDXDUZ)")
173 ;
174 Q
175 ;
176DEPRES(BSDXY,BSDXDUZ) ;EP
177 ;Called by BSDX GROUP RESOURCE
178 ;Returns ADO Recordset with all ACTIVE GROUP/RESOURCE combinations
179 ;to which user has access based on entries in BSDX RESOURCE USER file
180 ;If BSDXDUZ=0 then returns all ACTIVE GROUP/RESOURCE combinations for current DUZ
181 ;If user BSDXDUZ possesses the key BSDXZMGR or XUPROGMODE
182 ;then ALL ACTIVE resource group names are returned
183 ;
184 N BSDXERR,BSDXRET,BSDXIEN,BSDXRES,BSDXDEP,BSDXDDR,BSDXDEPN,BSDXRDAT,BSDXRNOD,BSDXI
185 N BSDXRESN,BSDXMGR,BSDXRESD,BSDXNOD,BSDXSUBID
186 K ^BSDXTEMP($J)
187 K ^BSDXTMP($J)
188 S BSDXY="^BSDXTMP("_$J_")"
189 S BSDXI=0
190 S BSDXERR=""
191 S ^BSDXTMP($J,BSDXI)="I00020RESOURCE_GROUPID^T00030RESOURCE_GROUP^I00020RESOURCE_GROUP_ITEMID^T00030RESOURCE_NAME^I00020RESOURCEID"_$C(30)
192 I '+BSDXDUZ S BSDXDUZ=DUZ
193 ;Check SECURITY KEY file for BSDXZMGR or XUPROGMODE keys
194 S BSDXMGR=$$APSEC("BSDXZMGR",BSDXDUZ)
195 ;
196 ;User does not have BSDXZMGR or XUPROGMODE keys, so
197 ;$O THRU AC XREF OF BSDX RESOURCE USER
198 I 'BSDXMGR,$D(^BSDXRSU("AC",BSDXDUZ)) S BSDXIEN=0 F S BSDXIEN=$O(^BSDXRSU("AC",BSDXDUZ,BSDXIEN)) Q:'+BSDXIEN D
199 . S BSDXRES=$P(^BSDXRSU(BSDXIEN,0),U)
200 . Q:'$D(^BSDXDEPT("AB",BSDXRES))
201 . S BSDXRNOD=$G(^BSDXRES(BSDXRES,0))
202 . Q:BSDXRNOD=""
203 . ;QUIT if the resource is inactive
204 . Q:$P(BSDXRNOD,U,2)=1
205 . S BSDXRESN=$P(BSDXRNOD,U)
206 . S BSDXDEP=0 F S BSDXDEP=$O(^BSDXDEPT("AB",BSDXRES,BSDXDEP)) Q:'+BSDXDEP D
207 . . Q:'$D(^BSDXDEPT(BSDXDEP,0))
208 . . S BSDXDEPN=$P(^BSDXDEPT(BSDXDEP,0),U)
209 . . S BSDXSUBID=$O(^BSDXDEPT(BSDXDEP,1,"B",BSDXRES,0))
210 . . S BSDXI=BSDXI+1
211 . . S ^BSDXTMP($J,BSDXI)=BSDXDEP_U_BSDXDEPN_U_BSDXSUBID_U_BSDXRESN_U_BSDXRES_$C(30)
212 . Q
213 ;
214 ;User does have BSDXZMGR or XUPROGMODE keys, so
215 ;$O THRU BSDX RESOURCE GROUP file directly
216 I BSDXMGR S BSDXIEN=0 F S BSDXIEN=$O(^BSDXDEPT(BSDXIEN)) Q:'+BSDXIEN D
217 . Q:'$D(^BSDXDEPT(BSDXIEN,0))
218 . S BSDXNOD=^BSDXDEPT(BSDXIEN,0)
219 . S BSDXDEPN=$P(BSDXNOD,U)
220 . S BSDXRES=0 F S BSDXRES=$O(^BSDXDEPT(BSDXIEN,1,BSDXRES)) Q:'+BSDXRES D
221 . . N BSDXRESD
222 . . Q:'$D(^BSDXDEPT(BSDXIEN,1,BSDXRES,0))
223 . . S BSDXRESD=$P(^BSDXDEPT(BSDXIEN,1,BSDXRES,0),"^")
224 . . Q:'$D(^BSDXRES(BSDXRESD,0))
225 . . S BSDXRNOD=$G(^BSDXRES(BSDXRESD,0))
226 . . Q:BSDXRNOD=""
227 . . ;QUIT if the resource is inactive
228 . . Q:$P(BSDXRNOD,U,2)=1
229 . . S BSDXRESN=$P(BSDXRNOD,U)
230 . . S BSDXI=BSDXI+1
231 . . S ^BSDXTMP($J,BSDXI)=BSDXIEN_U_BSDXDEPN_U_BSDXRES_U_BSDXRESN_U_BSDXRESD_$C(30)
232 . . Q
233 . Q
234 ;
235 S ^BSDXTMP($J,BSDXI+1)=$C(31)_BSDXERR
236 Q
237 ;
238APSEC(BSDXKEY,BSDXDUZ) ;EP - Return TRUE (1) if user has keys BSDXKEY or XUPROGMODE, otherwise, returns FALSE (0)
239 ;
240 N BSDXIEN,BSDXPROG,BSDXPKEY
241 I '$G(BSDXDUZ) Q 0
242 ;
243 ;Test for programmer mode key
244 S BSDXPROG=0
245 I $D(^DIC(19.1,"B","XUPROGMODE")) D
246 . S BSDXPKEY=$O(^DIC(19.1,"B","XUPROGMODE",0))
247 . I '+BSDXPKEY Q
248 . I '$D(^VA(200,BSDXDUZ,51,BSDXPKEY,0)) Q
249 . S BSDXPROG=1
250 I BSDXPROG Q 1
251 ;
252 I BSDXKEY="" Q 0
253 I '$D(^DIC(19.1,"B",BSDXKEY)) Q 0
254 S BSDXIEN=$O(^DIC(19.1,"B",BSDXKEY,0))
255 I '+BSDXIEN Q 0
256 I '$D(^VA(200,BSDXDUZ,51,BSDXIEN,0)) Q 0
257 Q 1
258INDIV(BSDXSC) ; PEP - Is ^SC clinic in the same DUZ(2) as user?
259 I '+BSDXSC QUIT 1 ;If not tied to clinic, yes
260 I '$D(^SC(BSDXSC,0)) QUIT 1 ; If Clinic does not exist, yes
261 ; Jump to Division:Medical Center Division:Inst File Pointer for
262 ; Institution IEN (and get its internal value)
263 N DIV S DIV=$$GET1^DIQ(44,BSDXSC_",","3.5:.07","I")
264 I DIV="" Q 1 ; If clinic has no division, consider it avial to user.
265 I DIV=DUZ(2) Q 1 ; If same, then User is in same Div as Clinic
266 E Q 0 ; Otherwise, no
267 QUIT
268UnitTestINDIV
269 W "Testing if they are the same",!
270 S DUZ(2)=67
271 I '$$INDIV(1) W "ERROR",!
272 I '$$INDIV(2) W "ERROR",!
273 W "Testing if Div not defined in 44, should be true",!
274 I '$$INDIV(3) W "ERROR",!
275 W "Testing empty string. Should be true",!
276 I '$$INDIV("") W "ERROR",!
277 W "Testing if they are different",!
278 S DUZ(2)=899
279 I $$INDIV(1) W "ERROR",!
280 I $$INDIV(2) W "ERROR",!
281 QUIT
Note: See TracBrowser for help on using the repository browser.