source: Scheduling/trunk/m/BSDX07.m@ 996

Last change on this file since 996 was 996, checked in by Sam Habiel, 14 years ago

Fix restartable transactions. Unit tests. Errors now logged correctly in %ZTER.
File size: 13.1 KB
Line 
1BSDX07 ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 10/24/10 12:07am
2 ;;1.42;BSDX;;Sep 29, 2010
3 ;
4 ; Change Log:
5 ; UJO/SMH
6 ; v1.3 July 13 2010 - Add support i18n - Dates input as FM dates, not US.
7 ; v1.42 Oct 22 2010 - Transaction now restartable by providing arguments
8 ; thanks to Rick Marshall and Zach Gonzalez at Oroville.
9 ; v1.42 Oct 30 2010 - Extensive refactoring.
10 ;
11 ; Error Reference:
12 ; -1: Patient Record is locked. This means something is wrong!!!!
13 ; -2: Start Time is not a valid Fileman date
14 ; -3: End Time is not a valid Fileman date
15 ; -4: End Time does not have time inside of it.
16 ; -5: BSDXPATID is not numeric
17 ; -6: Patient Does not exist in ^DPT
18 ; -7: Resource Name does not exist in B index of BSDX RESOURCE
19 ; -8: Resouce doesn't exist in ^BSDXRES
20 ; -9: Couldn't add appointment to BSDX APPOINTMENT
21 ; -10: Couldn't add appointment to files 2 and/or 44
22 ; -100: Mumps Error
23
24APPADDD(BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID) ;EP
25 ;Entry point for debugging
26 D DEBUG^%Serenji("APPADD^BSDX07(.BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID)")
27 Q
28 ;
29UT ; Unit Tests
30 N ZZZ
31 ; Test for bad start date
32 D APPADD(.ZZZ,2100123,3100123.3,2,"Dr Office",30,"Sam's Note",1)
33 I +$P(^BSDXTMP($J,1),U,2)'=-2 W "Error in -2",!
34 ; Test for bad end date
35 D APPADD(.ZZZ,3100123,2100123.3,2,"Dr Office",30,"Sam's Note",1)
36 I +$P(^BSDXTMP($J,1),U,2)'=-3 W "Error in -3",!
37 ; Test for end date without time
38 D APPADD(.ZZZ,3100123.1,3100123,2,"Dr Office",30,"Sam's Note",1)
39 I +$P(^BSDXTMP($J,1),U,2)'=-4 W "Error in -4",!
40 ; Test for mumps error
41 S bsdxdie=1
42 D APPADD(.ZZZ,3100123.09,3100123.093,2,"Dr Office",30,"Sam's Note",1)
43 I +$P(^BSDXTMP($J,1),U,2)'=-100 W "Error in -100: M Error",!
44 K bsdxdie
45 ; Test for TRESTART
46 s bsdxrestart=1
47 D APPADD(.ZZZ,3100123.09,3100123.093,3,"Dr Office",30,"Sam's Note",1)
48 I +$P(^BSDXTMP($J,1),U,2)'=0&(+$P(^BSDXTMP($J,1),U,2)'=-10) W "Error in TRESTART",!
49 k bsdxrestart
50 ; Test for non-numeric patient
51 D APPADD(.ZZZ,3100123.09,3100123.093,"CAT,DOG","Dr Office",30,"Sam's Note",1)
52 I +$P(^BSDXTMP($J,1),U,2)'=-5 W "Error in -5",!
53 ; Test for a non-existent patient
54 D APPADD(.ZZZ,3100123.09,3100123.093,8989898989,"Dr Office",30,"Sam's Note",1)
55 I +$P(^BSDXTMP($J,1),U,2)'=-6 W "Error in -6",!
56 ; Test for a non-existent resource name
57 D APPADD(.ZZZ,3100123.09,3100123.093,3,"lkajsflkjsadf",30,"Sam's Note",1)
58 I +$P(^BSDXTMP($J,1),U,2)'=-7 W "Error in -7",!
59 ; Test for corrupted resource
60 ; Can't test for -8 since it requires DB corruption
61 ; Test for inability to add appointment to BSDX Appointment
62 ; Also requires something wrong in the DB
63 ; Test for inability to add appointment to 2,44
64 ; Test by creating a duplicate appointment
65 D APPADD(.ZZZ,3100123.09,3100123.093,3,"Dr Office",30,"Sam's Note",1)
66 D APPADD(.ZZZ,3100123.09,3100123.093,1,"Dr Office",30,"Sam's Note",1)
67 I +$P(^BSDXTMP($J,1),U,2)'=-10 W "Error in -10",!
68 QUIT
69 ;
70APPADD(BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID) ;EP
71 ;Called by RPC: BSDX ADD NEW APPOINTMENT
72 ;
73 ;Add new appointment to 3 files
74 ; - BSDX APPOINTMENT
75 ; - Hosp Location Appointment SubSubfile if Resource is linked to clinic
76 ; - Patient Appointment Subfile if Resource is linked to clinic
77 ;
78 ;Paramters:
79 ;BSDXY: Global Return (RPC must be set to Global Array)
80 ;BSDXSTART: FM Start Date
81 ;BSDXEND: FM End Date
82 ;BSDXPATID: Patient DFN
83 ;BSDXRES is ResourceName in BSDX RESOURCE file (not IEN)
84 ;BSDXLEN is the appointment duration in minutes
85 ;BSDXNOTE is the Appiontment Note
86 ;BSDXATID is used for 2 purposes:
87 ; if BSDXATID = "WALKIN" then BSDAPI is called to create a walkin appt.
88 ; if BSDXATID = a number, then it is the access type id (used for rebooking)
89 ;
90 ;Return:
91 ; ADO.net Recordset having fields:
92 ; AppointmentID and ErrorNumber
93 ;
94 ;Test lines:
95 ;BSDX ADD NEW APPOINTMENT^3091122.0930^3091122.1000^370^Dr Office^30^EXAM^WALKIN
96 ;
97 ; Return Array; set Return and clear array
98 S BSDXY=$NA(^BSDXTMP($J))
99 K ^BSDXTMP($J)
100 ; $ET
101 N $ET S $ET="G ETRAP^BSDX07"
102 ; Counter
103 N BSDXI S BSDXI=0
104 ; Lock BSDX node, only to synchronize access to the globals.
105 ; It's not expected that the error will ever happen as no filing
106 ; is supposed to take 5 seconds.
107 L +^BSDXAPPT(BSDXPATID):5 I '$T D ERR(BSDXI,"-1~Patient record is locked. Please contact technical support.") Q
108 ; Header Node
109 S ^BSDXTMP($J,BSDXI)="I00020APPOINTMENTID^T00020ERRORID"_$C(30)
110 ;Restartable Transaction; restore paramters when starting.
111 ; (Params restored are what's passed here + BSDXI)
112 TSTART (BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID,BSDXI):T="BSDX ADD NEW APPOINTMENT^BSDX07"
113 ;
114 ; Turn off SDAM APPT PROTOCOL BSDX Entries
115 N BSDXNOEV
116 S BSDXNOEV=1 ;Don't execute BSDX ADD APPOINTMENT protocol
117 ;
118 ; Set Error Message to be empty
119 N BSDXERR S BSDXERR=0
120 ;
121 ;;;test for error inside transaction. See if %ZTER works
122 I $G(bsdxdie) S X=1/0
123 ;;;test
124 ;;;test for TRESTART
125 I $G(bsdxrestart) K bsdxrestart TRESTART
126 ;;;test
127 ;
128 ; -- Start and End Date Processing --
129 ; If C# sends the dates with extra zeros, remove them
130 S BSDXSTART=+BSDXSTART,BSDXEND=+BSDXEND
131 ; Are the dates valid? Must be FM Dates > than 2010
132 I BSDXSTART'>3100000 D ERR(BSDXI,"-2~BSDX07 Error: Invalid Start Time") Q
133 I BSDXEND'>3100000 D ERR(BSDXI,"-3~BSDX07 Error: Invalid End Time") Q
134 ; If Ending date doesn't have a time, this is an error
135 I $L(BSDXEND,".")=1 D ERR(BSDXI,"-4~BSDX07 Error: Invalid End Time") Q
136 ; If the Start Date is greater than the end date, swap dates
137 N BSDXTMP
138 I BSDXSTART>BSDXEND S BSDXTMP=BSDXEND,BSDXEND=BSDXSTART,BSDXSTART=BSDXTMP
139 ;
140 ; Check if the patient exists:
141 ; - DFN valid number?
142 ; - Valid Patient in file 2?
143 I '+BSDXPATID D ERR(BSDXI,"-5~BSDX07 Error: Invalid Patient ID") Q
144 I '$D(^DPT(BSDXPATID,0)) D ERR(BSDXI,"-6~BSDX07 Error: Invalid Patient ID") Q
145 ;
146 ;Validate Resource entry
147 I '$D(^BSDXRES("B",BSDXRES)) D ERR(BSDXI,"-7~BSDX07 Error: Invalid Resource ID") Q
148 N BSDXRESD ; Resource IEN
149 S BSDXRESD=$O(^BSDXRES("B",BSDXRES,0))
150 N BSDXRNOD ; Resouce zero node
151 S BSDXRNOD=$G(^BSDXRES(BSDXRESD,0))
152 I BSDXRNOD="" D ERR(BSDXI,"-8~BSDX07 Error: invalid Resource entry.") Q
153 ;
154 ; Walk-in (Unscheduled) Appointment?
155 N BSDXWKIN S BSDXWKIN=0
156 I BSDXATID="WALKIN" S BSDXWKIN=1
157 ; Reset Access Type ID if it doesn't say "WALKIN" and isn't a number
158 I BSDXATID'?.N&(BSDXATID'="WALKIN") S BSDXATID=""
159 ;
160 ; Done with all checks, let's make appointment in BSDX APPOINTMENT
161 N BSDXAPPTID
162 S BSDXAPPTID=$$BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRESD,BSDXATID)
163 I 'BSDXAPPTID D ERR(BSDXI,"-9~BSDX07 Error: Unable to add appointment to BSDX APPOINTMENT file.") Q
164 I BSDXNOTE]"" D BSDXWP(BSDXAPPTID,BSDXNOTE)
165 ;
166 ; Then Create Subfiles in 2/44 Appointment
167 N BSDXSCD S BSDXSCD=$P(BSDXRNOD,U,4) ; Hosp Location IEN
168 ; Only if we have a valid Hosp Loc can we make an appointment
169 I +BSDXSCD,$D(^SC(BSDXSCD,0)) D I +BSDXERR D ERR(BSDXI,"-10~BSDX07 Error: ~MAKE^BSDAPI returned error code: "_BSDXERR) Q
170 . N BSDXC
171 . S BSDXC("PAT")=BSDXPATID
172 . S BSDXC("CLN")=BSDXSCD
173 . S BSDXC("TYP")=3 ;3 for scheduled appts, 4 for walkins
174 . S:BSDXWKIN BSDXC("TYP")=4
175 . S BSDXC("ADT")=BSDXSTART
176 . S BSDXC("LEN")=BSDXLEN
177 . S BSDXC("OI")=$E($G(BSDXNOTE),1,150) ;File 44 has 150 character limit on OTHER field
178 . S BSDXC("OI")=$TR(BSDXC("OI"),";"," ") ;No semicolons allowed by MAKE^BSDXAPI
179 . S BSDXC("OI")=$$STRIP(BSDXC("OI")) ;Strip control characters from note
180 . S BSDXC("USR")=DUZ
181 . S BSDXERR=$$MAKE^BSDXAPI(.BSDXC)
182 . Q:BSDXERR
183 . ;Update RPMS Clinic availability
184 . D AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN)
185 . Q
186 ;
187 ;Return Recordset
188 TCOMMIT
189 L -^BSDXAPPT(BSDXPATID)
190 S BSDXI=BSDXI+1
191 S ^BSDXTMP($J,BSDXI)=BSDXAPPTID_"^"_$C(30)
192 S BSDXI=BSDXI+1
193 S ^BSDXTMP($J,BSDXI)=$C(31)
194 Q
195BSDXDEL(BSDXAPPTID) ;Deletes appointment BSDXAPPTID from BSDXAPPOINTMETN
196 N DA,DIK
197 S DIK="^BSDXAPPT(",DA=BSDXAPPTID
198 D ^DIK
199 Q
200 ;
201STRIP(BSDXZ) ;Replace control characters with spaces
202 N BSDXI
203 F BSDXI=1:1:$L(BSDXZ) I (32>$A($E(BSDXZ,BSDXI))) S BSDXZ=$E(BSDXZ,1,BSDXI-1)_" "_$E(BSDXZ,BSDXI+1,999)
204 Q BSDXZ
205 ;
206BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRESD,BSDXATID) ;ADD BSDX APPOINTMENT ENTRY
207 ;Returns ien in BSDXAPPT or 0 if failed
208 ;Create entry in BSDX APPOINTMENT
209 N BSDXAPPTID
210 S BSDXFDA(9002018.4,"+1,",.01)=BSDXSTART
211 S BSDXFDA(9002018.4,"+1,",.02)=BSDXEND
212 S BSDXFDA(9002018.4,"+1,",.05)=BSDXPATID
213 S BSDXFDA(9002018.4,"+1,",.07)=BSDXRESD
214 S BSDXFDA(9002018.4,"+1,",.08)=$G(DUZ)
215 S BSDXFDA(9002018.4,"+1,",.09)=$$NOW^XLFDT
216 S:BSDXATID="WALKIN" BSDXFDA(9002018.4,"+1,",.13)="y"
217 S:BSDXATID?.N BSDXFDA(9002018.4,"+1,",.06)=BSDXATID
218 N BSDXIEN,BSDXMSG
219 D UPDATE^DIE("","BSDXFDA","BSDXIEN","BSDXMSG")
220 S BSDXAPPTID=+$G(BSDXIEN(1))
221 Q BSDXAPPTID
222 ;
223BSDXWP(BSDXAPPTID,BSDXNOTE) ;
224 ;Add WP field
225 I BSDXNOTE]"" S BSDXNOTE(.5)=BSDXNOTE,BSDXNOTE=""
226 I $D(BSDXNOTE(0)) S BSDXNOTE(.5)=BSDXNOTE(0) K BSDXNOTE(0)
227 I $D(BSDXNOTE(.5)) D
228 . D WP^DIE(9002018.4,BSDXAPPTID_",",1,"","BSDXNOTE","BSDXMSG")
229 Q
230 ;
231ADDEVT(BSDXPATID,BSDXSTART,BSDXSC,BSDXSCDA) ;EP
232 ;Called by BSDX ADD APPOINTMENT protocol
233 ;BSDXSC=IEN of clinic in ^SC
234 ;BSDXSCDA=IEN for ^SC(BSDXSC,"S",BSDXSTART,1,BSDXSCDA). Use to get Length & Note
235 ;
236 N BSDXNOD,BSDXLEN,BSDXAPPTID,BSDXNODP,BSDXWKIN,BSDXRES
237 Q:+$G(BSDXNOEV)
238 I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0))
239 E I $D(^BSDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0))
240 Q:'+$G(BSDXRES)
241 S BSDXNOD=$G(^SC(BSDXSC,"S",BSDXSTART,1,BSDXSCDA,0))
242 Q:BSDXNOD=""
243 S BSDXNODP=$G(^DPT(BSDXPATID,"S",BSDXSTART,0))
244 S BSDXWKIN=""
245 S:$P(BSDXNODP,U,7)=4 BSDXWKIN="WALKIN" ;Purpose of Visit field of DPT Appointment subfile
246 S BSDXLEN=$P(BSDXNOD,U,2)
247 Q:'+BSDXLEN
248 S BSDXEND=$$FMADD^XLFDT(BSDXSTART,0,0,BSDXLEN,0)
249 S BSDXAPPTID=$$BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXWKIN)
250 Q:'+BSDXAPPTID
251 S BSDXNOTE=$P(BSDXNOD,U,4)
252 I BSDXNOTE]"" D BSDXWP(BSDXAPPTID,BSDXNOTE)
253 D ADDEVT3(BSDXRES)
254 Q
255 ;
256ADDEVT3(BSDXRES) ;
257 ;Call RaiseEvent to notify GUI clients
258 N BSDXRESN
259 S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
260 Q:BSDXRESN=""
261 S BSDXRESN=$P(BSDXRESN,"^")
262 ;D EVENT^BSDX23("SCHEDULE-"_BSDXRESN,"","","")
263 D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
264 Q
265 ;
266ERR(BSDXI,BSDXERR) ;Error processing
267 S BSDXI=BSDXI+1
268 S BSDXERR=$TR(BSDXERR,"^","~")
269 I $TL>0 TROLLBACK
270 S ^BSDXTMP($J,BSDXI)="0^"_BSDXERR_$C(30)
271 S BSDXI=BSDXI+1
272 S ^BSDXTMP($J,BSDXI)=$C(31)
273 L -^BSDXAPPT(BSDXPATID)
274 Q
275 ;
276ETRAP ;EP Error trap entry
277 N $ET S $ET="D ^%ZTER HALT" ; Emergency Error Trap
278 ; Rollback, otherwise ^XTER will be empty from future rollback
279 I $TL>0 TROLLBACK
280 D ^%ZTER
281 S $EC="" ; Clear Error
282 ; Log error message and send to client
283 I '$D(BSDXI) N BSDXI S BSDXI=0
284 D ERR(BSDXI,"-100~BSDX07 Error: "_$G(%ZTERZE))
285 Q
286 ;
287DAY ;;^SUN^MON^TUES^WEDNES^THURS^FRI^SATUR
288 ;
289DOW S %=$E(X,1,3),Y=$E(X,4,5),Y=Y>2&'(%#4)+$E("144025036146",Y)
290 F %=%:-1:281 S Y=%#4=1+1+Y
291 S Y=$E(X,6,7)+Y#7
292 Q
293 ;
294AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN) ;Update RPMS Clinic availability
295 ;SEE SDM1
296 N Y,DFN
297 N SL,STARTDAY,X,SC,SB,HSI,SI,STR,SDDIF,SDMAX,SDDATE,SDDMAX,SDSDATE,CCXN,MXOK,COV,SDPROG
298 N X1,SDEDT,X2,SD,SM,SS,S,SDLOCK,ST,I
299 S Y=BSDXSCD,DFN=BSDXPATID
300 S SL=$G(^SC(+Y,"SL")),X=$P(SL,U,3),STARTDAY=$S($L(X):X,1:8),SC=Y,SB=STARTDAY-1/100,X=$P(SL,U,6),HSI=$S(X=1:X,X:X,1:4),SI=$S(X="":4,X<3:4,X:X,1:4),STR="#@!$* XXWVUTSRQPONMLKJIHGFEDCBA0123456789jklmnopqrstuvwxyz",SDDIF=$S(HSI<3:8/HSI,1:2) K Y
301 ;Determine maximum days for scheduling
302 S SDMAX(1)=$P($G(^SC(+SC,"SDP")),U,2) S:'SDMAX(1) SDMAX(1)=365
303 S (SDMAX,SDDMAX)=$$FMADD^XLFDT(DT,SDMAX(1))
304 S SDDATE=BSDXSTART
305 S SDSDATE=SDDATE,SDDATE=SDDATE\1
3061 ;L Q:$D(SDXXX) S CCXN=0 K MXOK,COV,SDPROT Q:DFN<0 S SC=+SC
307 Q:$D(SDXXX) S CCXN=0 K MXOK,COV,SDPROT Q:DFN<0 S SC=+SC
308 S X1=DT,SDEDT=365 S:$D(^SC(SC,"SDP")) SDEDT=$P(^SC(SC,"SDP"),"^",2)
309 S X2=SDEDT D C^%DTC S SDEDT=X
310 S Y=BSDXSTART
311EN1 S (X,SD)=Y,SM=0 D DOW
312S I '$D(^SC(SC,"ST",$P(SD,"."),1)) S SS=+$O(^SC(+SC,"T"_Y,SD)) Q:SS'>0 Q:^(SS,1)="" S ^SC(+SC,"ST",$P(SD,"."),1)=$E($P($T(DAY),U,Y+2),1,2)_" "_$E(SD,6,7)_$J("",SI+SI-6)_^(1),^(0)=$P(SD,".")
313 S S=BSDXLEN
314 ;Check if BSDXLEN evenly divisible by appointment length
315 S RPMSL=$P(SL,U)
316 I BSDXLEN<RPMSL S BSDXLEN=RPMSL
317 I BSDXLEN#RPMSL'=0 D
318 . S BSDXINC=BSDXLEN\RPMSL
319 . S BSDXINC=BSDXINC+1
320 . S BSDXLEN=RPMSL*BSDXINC
321 S SL=S_U_$P(SL,U,2,99)
322SC S SDLOCK=$S('$D(SDLOCK):1,1:SDLOCK+1) Q:SDLOCK>9
323 L +^SC(SC,"ST",$P(SD,"."),1):5 G:'$T SC
324 S SDLOCK=0,S=^SC(SC,"ST",$P(SD,"."),1)
325 S I=SD#1-SB*100,ST=I#1*SI\.6+($P(I,".")*SI),SS=SL*HSI/60*SDDIF+ST+ST
326 I (I<1!'$F(S,"["))&(S'["CAN") L -^SC(SC,"ST",$P(SD,"."),1) Q
327 I SM<7 S %=$F(S,"[",SS-1) S:'%!($P(SL,"^",6)<3) %=999 I $F(S,"]",SS)'<%!(SDDIF=2&$E(S,ST+ST+1,SS-1)["[") S SM=7
328 ;
329SP I ST+ST>$L(S),$L(S)<80 S S=S_" " G SP
330 S SDNOT=1
331 S ABORT=0
332 F I=ST+ST:SDDIF:SS-SDDIF D Q:ABORT
333 . S ST=$E(S,I+1) S:ST="" ST=" "
334 . S Y=$E(STR,$F(STR,ST)-2)
335 . I S["CAN"!(ST="X"&($D(^SC(+SC,"ST",$P(SD,"."),"CAN")))) S ABORT=1 Q
336 . I Y="" S ABORT=1 Q
337 . S:Y'?1NL&(SM<6) SM=6 S ST=$E(S,I+2,999) S:ST="" ST=" " S S=$E(S,1,I)_Y_ST
338 . Q
339 S ^SC(SC,"ST",$P(SD,"."),1)=S
340 L -^SC(SC,"ST",$P(SD,"."),1)
341 Q
Note: See TracBrowser for help on using the repository browser.