source: Scheduling/trunk/m/BSDX07.m@ 1450

Last change on this file since 1450 was 1450, checked in by Sam Habiel, 12 years ago

more changes
File size: 15.3 KB
Line 
1BSDX07 ; VW/UJO/SMH - WINDOWS SCHEDULING RPCS ; 6/18/12 5:12pm
2 ;;1.7T1;BSDX;;Aug 31, 2011;Build 18
3 ; Licensed under LGPL
4 ;
5 ; Change Log:
6 ; UJO/SMH
7 ; v1.3 July 13 2010 - Add support i18n - Dates input as FM dates, not US.
8 ; v1.42 Oct 22 2010 - Transaction now restartable by providing arguments
9 ; thanks to Rick Marshall and Zach Gonzalez at Oroville.
10 ; v1.42 Oct 30 2010 - Extensive refactoring.
11 ; v1.5 Mar 15 2011 - End time does not have to have time anymore.
12 ; It could be midnight of the next day
13 ; v1.6 Apr 11 2011 - Support for Scheduling Radiology Exams...
14 ;
15 ; Error Reference:
16 ; -1: Patient Record is locked. This means something is wrong!!!!
17 ; -2: Start Time is not a valid Fileman date
18 ; -3: End Time is not a valid Fileman date
19 ; v1.5:obsolete::-4: End Time does not have time inside of it.
20 ; -5: BSDXPATID is not numeric
21 ; -6: Patient Does not exist in ^DPT
22 ; -7: Resource Name does not exist in B index of BSDX RESOURCE
23 ; -8: Resouce doesn't exist in ^BSDXRES
24 ; -9: Couldn't add appointment to BSDX APPOINTMENT
25 ; -10: Couldn't add appointment to files 2 and/or 44
26 ; -100: Mumps Error
27 ;
28APPADDD(BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID) ;EP
29 ;Entry point for debugging
30 D DEBUG^%Serenji("APPADD^BSDX07(.BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID)")
31 Q
32 ;
33UT ; Unit Tests
34 ; Set-up - Create Clinics
35 N RESNAM S RESNAM="UTCLINIC"
36 N HLRESIENS ; holds output of UTCR^BSDX35 - HL IEN^Resource IEN
37 D
38 . N $ET S $ET="D ^%ZTER B"
39 . S HLRESIENS=$$UTCR^BSDX35(RESNAM)
40 . I HLRESIENS<0 S $EC=",U1," ; not supposed to happen
41 ;
42 N HLIEN,RESIEN
43 S HLIEN=$P(HLRESIENS,U)
44 S RESIEN=$P(HLRESIENS,U,2)
45 ;
46 ; Get start and end times
47 N TIMES S TIMES=$$TIMES^BSDX35 ; appt time^end time
48 N APPTTIME S APPTTIME=$P(TIMES,U)
49 N ENDTIME S ENDTIME=$P(TIMES,U,2)
50 ;
51 N ZZZ
52 ; Test for normality:
53 D APPADD(.ZZZ,APPTTIME,ENDTIME,3,RESNAM,30,"Sam's Note",1)
54 ; Does Appt exist?
55 N APPID S APPID=+$P(^BSDXTMP($J,1),U)
56 I 'APPID W "Error Making Appt-1" QUIT
57 I +^BSDXAPPT(APPID,0)'=APPTTIME W "Error Making Appt-2"
58 I '$D(^DPT(3,"S",APPTTIME)) W "Error Making Appt-3"
59 I '$D(^SC(HLIEN,"S",APPTTIME)) W "Error Making Appt-4"
60 ;
61 ; Do it again for a different patient
62 D APPADD(.ZZZ,APPTTIME,ENDTIME,2,RESNAM,30,"Sam's Note",1)
63 N APPID S APPID=+$P(^BSDXTMP($J,1),U) B
64 I 'APPID W "Error Making Appt-5" QUIT
65 I +^BSDXAPPT(APPID,0)'=APPTTIME W "Error Making Appt-6"
66 I '$D(^DPT(2,"S",APPTTIME)) W "Error Making Appt-7"
67 I '$D(^SC(HLIEN,"S",APPTTIME)) W "Error Making Appt-8"
68 ;
69 ; Test for bad start date
70 D APPADD(.ZZZ,2100123,3100123.3,2,RESNAM,30,"Sam's Note",1)
71 I +$P(^BSDXTMP($J,1),U,2)'=-2 W "Error in -2",!
72 ; Test for bad end date
73 D APPADD(.ZZZ,3100123,2100123.3,2,RESNAM,30,"Sam's Note",1)
74 I +$P(^BSDXTMP($J,1),U,2)'=-3 W "Error in -3",!
75 ; Test for end date without time - obsolete
76 ; D APPADD(.ZZZ,3100123.1,3100123,2,RESNAM,30,"Sam's Note",1)
77 ; I +$P(^BSDXTMP($J,1),U,2)'=-4 W "Error in -4",!
78 ; Test for mumps error
79 S BSDXDIE=1
80 D APPADD(.ZZZ,APPTTIME,ENDTIME,1,RESNAM,30,"Sam's Note",1)
81 I +$P(^BSDXTMP($J,1),U,2)'=-100 W "Error in -100: M Error",!
82 K BSDXDIE
83 ; Test for TRESTART
84 s BSDXRESTART=1
85 D APPADD(.ZZZ,APPTTIME,ENDTIME,3,RESNAM,30,"Sam's Note",1)
86 I +$P(^BSDXTMP($J,1),U,2)'=0&(+$P(^BSDXTMP($J,1),U,2)'=-10) W "Error in TRESTART",!
87 k BSDXRESTART
88 ; Test for non-numeric patient
89 D APPADD(.ZZZ,APPTTIME,ENDTIME,"CAT,DOG",RESNAM,30,"Sam's Note",1)
90 I +$P(^BSDXTMP($J,1),U,2)'=-5 W "Error in -5",!
91 ; Test for a non-existent patient
92 D APPADD(.ZZZ,APPTTIME,ENDTIME,8989898989,RESNAM,30,"Sam's Note",1)
93 I +$P(^BSDXTMP($J,1),U,2)'=-6 W "Error in -6",!
94 ; Test for a non-existent resource name
95 D APPADD(.ZZZ,APPTTIME,ENDTIME,3,"lkajsflkjsadf",30,"Sam's Note",1)
96 I +$P(^BSDXTMP($J,1),U,2)'=-7 W "Error in -7",!
97 ; Test for corrupted resource
98 ; Can't test for -8 since it requires DB corruption
99 ; Test for inability to add appointment to BSDX Appointment
100 ; Also requires something wrong in the DB
101 ; Test for inability to add appointment to 2,44
102 ; Test by creating a duplicate appointment
103 ; Get start and end times
104 N TIMES S TIMES=$$TIMES^BSDX35 ; appt time^end time
105 N APPTTIME S APPTTIME=$P(TIMES,U)
106 N ENDTIME S ENDTIME=$P(TIMES,U,2)
107 D APPADD(.ZZZ,APPTTIME,ENDTIME,3,RESNAM,30,"Sam's Note",1)
108 D APPADD(.ZZZ,APPTTIME,ENDTIME,3,RESNAM,30,"Sam's Note",1)
109 I +$P(^BSDXTMP($J,1),U,2)'=-10 W "Error in -10",!
110 QUIT
111 ;
112APPADD(BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID,BSDXRADEXAM) ;EP
113 ;
114 ;Called by RPC: BSDX ADD NEW APPOINTMENT
115 ;
116 ;Add new appointment to 3 files
117 ; - BSDX APPOINTMENT
118 ; - Hosp Location Appointment SubSubfile if Resource is linked to clinic
119 ; - Patient Appointment Subfile if Resource is linked to clinic
120 ;
121 ;Paramters:
122 ;BSDXY: Global Return (RPC must be set to Global Array)
123 ;BSDXSTART: FM Start Date
124 ;BSDXEND: FM End Date
125 ;BSDXPATID: Patient DFN
126 ;BSDXRES is ResourceName in BSDX RESOURCE file (not IEN)
127 ;BSDXLEN is the appointment duration in minutes
128 ;BSDXNOTE is the Appiontment Note
129 ;BSDXATID is used for 2 purposes:
130 ; if BSDXATID = "WALKIN" then BSDAPI is called to create a walkin appt.
131 ; if BSDXATID = a number, then it is the access type id (used for rebooking)
132 ;BSDXRADEXAM is used to store the Radiology Exam to which this appointment is tied to (optional)
133 ;
134 ;Return:
135 ; ADO.net Recordset having fields:
136 ; AppointmentID and ErrorNumber
137 ;
138 ;Test lines:
139 ;BSDX ADD NEW APPOINTMENT^3091122.0930^3091122.1000^370^Dr Office^30^EXAM^WALKIN
140 ;
141 ; Deal with optional arguments
142 S BSDXRADEXAM=$G(BSDXRADEXAM)
143 ; Return Array; set Return and clear array
144 S BSDXY=$NA(^BSDXTMP($J))
145 K ^BSDXTMP($J)
146 ; $ET
147 N $ET S $ET="G ETRAP^BSDX07"
148 ; Counter
149 N BSDXI S BSDXI=0
150 ; Lock BSDX node, only to synchronize access to the globals.
151 ; It's not expected that the error will ever happen as no filing
152 ; is supposed to take 5 seconds.
153 L +^BSDXAPPT(BSDXPATID):5 I '$T D ERR(BSDXI,"-1~Patient record is locked. Please contact technical support.") Q
154 ; Header Node
155 S ^BSDXTMP($J,BSDXI)="I00020APPOINTMENTID^T00100ERRORID"_$C(30)
156 ;Restartable Transaction; restore paramters when starting.
157 ; (Params restored are what's passed here + BSDXI)
158 TSTART (BSDXY,BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXLEN,BSDXNOTE,BSDXATID,BSDXI):T="BSDX ADD NEW APPOINTMENT^BSDX07"
159 ;
160 ; Turn off SDAM APPT PROTOCOL BSDX Entries
161 N BSDXNOEV
162 S BSDXNOEV=1 ;Don't execute BSDX ADD APPOINTMENT protocol
163 ;
164 ; Set Error Message to be empty
165 N BSDXERR S BSDXERR=0
166 ;
167 ;;;test for error inside transaction. See if %ZTER works
168 I $G(BSDXDIE) S X=1/0
169 ;;;test
170 ;;;test for TRESTART
171 I $G(BSDXRESTART) K BSDXRESTART TRESTART
172 ;;;test
173 ;
174 ; -- Start and End Date Processing --
175 ; If C# sends the dates with extra zeros, remove them
176 S BSDXSTART=+BSDXSTART,BSDXEND=+BSDXEND
177 ; Are the dates valid? Must be FM Dates > than 2010
178 I BSDXSTART'>3100000 D ERR(BSDXI,"-2~BSDX07 Error: Invalid Start Time") Q
179 I BSDXEND'>3100000 D ERR(BSDXI,"-3~BSDX07 Error: Invalid End Time") Q
180 ;
181 ;; If Ending date doesn't have a time, this is an error --rm 1.5
182 ; I $L(BSDXEND,".")=1 D ERR(BSDXI,"-4~BSDX07 Error: Invalid End Time") Q
183 ;
184 ; If the Start Date is greater than the end date, swap dates
185 N BSDXTMP
186 I BSDXSTART>BSDXEND S BSDXTMP=BSDXEND,BSDXEND=BSDXSTART,BSDXSTART=BSDXTMP
187 ;
188 ; Check if the patient exists:
189 ; - DFN valid number?
190 ; - Valid Patient in file 2?
191 I '+BSDXPATID D ERR(BSDXI,"-5~BSDX07 Error: Invalid Patient ID") Q
192 I '$D(^DPT(BSDXPATID,0)) D ERR(BSDXI,"-6~BSDX07 Error: Invalid Patient ID") Q
193 ;
194 ;Validate Resource entry
195 I '$D(^BSDXRES("B",BSDXRES)) D ERR(BSDXI,"-7~BSDX07 Error: Invalid Resource ID") Q
196 N BSDXRESD ; Resource IEN
197 S BSDXRESD=$O(^BSDXRES("B",BSDXRES,0))
198 N BSDXRNOD ; Resouce zero node
199 S BSDXRNOD=$G(^BSDXRES(BSDXRESD,0))
200 I BSDXRNOD="" D ERR(BSDXI,"-8~BSDX07 Error: invalid Resource entry.") Q
201 ;
202 ; Walk-in (Unscheduled) Appointment?
203 N BSDXWKIN S BSDXWKIN=0
204 I BSDXATID="WALKIN" S BSDXWKIN=1
205 ; Reset Access Type ID if it doesn't say "WALKIN" and isn't a number
206 I BSDXATID'?.N&(BSDXATID'="WALKIN") S BSDXATID=""
207 ;
208 ; Done with all checks, let's make appointment in BSDX APPOINTMENT
209 N BSDXAPPTID
210 S BSDXAPPTID=$$BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRESD,BSDXATID,BSDXRADEXAM)
211 I 'BSDXAPPTID D ERR(BSDXI,"-9~BSDX07 Error: Unable to add appointment to BSDX APPOINTMENT file.") Q
212 I BSDXNOTE]"" D BSDXWP(BSDXAPPTID,BSDXNOTE)
213 ;
214 ; Then Create Subfiles in 2/44 Appointment
215 N BSDXSCD S BSDXSCD=$P(BSDXRNOD,U,4) ; Hosp Location IEN
216 ; Only if we have a valid Hosp Loc can we make an appointment
217 I +BSDXSCD,$D(^SC(BSDXSCD,0)) D I +BSDXERR D ERR(BSDXI,"-10~BSDX07 Error: MAKE^BSDXAPI returned error code: "_BSDXERR) Q
218 . N BSDXC
219 . S BSDXC("PAT")=BSDXPATID
220 . S BSDXC("CLN")=BSDXSCD
221 . S BSDXC("TYP")=3 ;3 for scheduled appts, 4 for walkins
222 . S:BSDXWKIN BSDXC("TYP")=4
223 . S BSDXC("ADT")=BSDXSTART
224 . S BSDXC("LEN")=BSDXLEN
225 . S BSDXC("OI")=$E($G(BSDXNOTE),1,150) ;File 44 has 150 character limit on OTHER field
226 . S BSDXC("OI")=$TR(BSDXC("OI"),";"," ") ;No semicolons allowed by MAKE^BSDXAPI
227 . S BSDXC("OI")=$$STRIP(BSDXC("OI")) ;Strip control characters from note
228 . S BSDXC("USR")=DUZ
229 . S BSDXERR=$$MAKE^BSDXAPI(.BSDXC)
230 . Q:BSDXERR
231 . ;Update RPMS Clinic availability
232 . D AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN)
233 . Q
234 ;
235 ;Return Recordset
236 TCOMMIT
237 L -^BSDXAPPT(BSDXPATID)
238 S BSDXI=BSDXI+1
239 S ^BSDXTMP($J,BSDXI)=BSDXAPPTID_"^"_$C(30)
240 S BSDXI=BSDXI+1
241 S ^BSDXTMP($J,BSDXI)=$C(31)
242 Q
243BSDXDEL(BSDXAPPTID) ;Deletes appointment BSDXAPPTID from BSDXAPPOINTMETN
244 N DA,DIK
245 S DIK="^BSDXAPPT(",DA=BSDXAPPTID
246 D ^DIK
247 Q
248 ;
249STRIP(BSDXZ) ;Replace control characters with spaces
250 N BSDXI
251 F BSDXI=1:1:$L(BSDXZ) I (32>$A($E(BSDXZ,BSDXI))) S BSDXZ=$E(BSDXZ,1,BSDXI-1)_" "_$E(BSDXZ,BSDXI+1,999)
252 Q BSDXZ
253 ;
254BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRESD,BSDXATID,BSDXRADEXAM) ;ADD BSDX APPOINTMENT ENTRY
255 ;Returns ien in BSDXAPPT or 0 if failed
256 ;Create entry in BSDX APPOINTMENT
257 N BSDXAPPTID
258 S BSDXFDA(9002018.4,"+1,",.01)=BSDXSTART
259 S BSDXFDA(9002018.4,"+1,",.02)=BSDXEND
260 S BSDXFDA(9002018.4,"+1,",.05)=BSDXPATID
261 S BSDXFDA(9002018.4,"+1,",.07)=BSDXRESD
262 S BSDXFDA(9002018.4,"+1,",.08)=$G(DUZ)
263 S BSDXFDA(9002018.4,"+1,",.09)=$$NOW^XLFDT
264 S:BSDXATID="WALKIN" BSDXFDA(9002018.4,"+1,",.13)="y"
265 S:BSDXATID?.N BSDXFDA(9002018.4,"+1,",.06)=BSDXATID
266 S BSDXFDA(9002018.4,"+1,",.14)=$G(BSDXRADEXAM)
267 N BSDXIEN,BSDXMSG
268 D UPDATE^DIE("","BSDXFDA","BSDXIEN","BSDXMSG")
269 S BSDXAPPTID=+$G(BSDXIEN(1))
270 Q BSDXAPPTID
271 ;
272BSDXWP(BSDXAPPTID,BSDXNOTE) ;
273 ;Add WP field
274 I BSDXNOTE]"" S BSDXNOTE(.5)=BSDXNOTE,BSDXNOTE=""
275 I $D(BSDXNOTE(0)) S BSDXNOTE(.5)=BSDXNOTE(0) K BSDXNOTE(0)
276 I $D(BSDXNOTE(.5)) D
277 . D WP^DIE(9002018.4,BSDXAPPTID_",",1,"","BSDXNOTE","BSDXMSG")
278 Q
279 ;
280ADDEVT(BSDXPATID,BSDXSTART,BSDXSC,BSDXSCDA) ;EP
281 ;Called by BSDX ADD APPOINTMENT protocol
282 ;BSDXSC=IEN of clinic in ^SC
283 ;BSDXSCDA=IEN for ^SC(BSDXSC,"S",BSDXSTART,1,BSDXSCDA). Use to get Length & Note
284 ;
285 N BSDXNOD,BSDXLEN,BSDXAPPTID,BSDXNODP,BSDXWKIN,BSDXRES
286 Q:+$G(BSDXNOEV)
287 I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0))
288 E I $D(^BSDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0))
289 Q:'+$G(BSDXRES)
290 S BSDXNOD=$G(^SC(BSDXSC,"S",BSDXSTART,1,BSDXSCDA,0))
291 Q:BSDXNOD=""
292 S BSDXNODP=$G(^DPT(BSDXPATID,"S",BSDXSTART,0))
293 S BSDXWKIN=""
294 S:$P(BSDXNODP,U,7)=4 BSDXWKIN="WALKIN" ;Purpose of Visit field of DPT Appointment subfile
295 S BSDXLEN=$P(BSDXNOD,U,2)
296 Q:'+BSDXLEN
297 S BSDXEND=$$FMADD^XLFDT(BSDXSTART,0,0,BSDXLEN,0)
298 S BSDXAPPTID=$$BSDXADD(BSDXSTART,BSDXEND,BSDXPATID,BSDXRES,BSDXWKIN)
299 Q:'+BSDXAPPTID
300 S BSDXNOTE=$P(BSDXNOD,U,4)
301 I BSDXNOTE]"" D BSDXWP(BSDXAPPTID,BSDXNOTE)
302 D ADDEVT3(BSDXRES)
303 Q
304 ;
305ADDEVT3(BSDXRES) ;
306 ;Call RaiseEvent to notify GUI clients
307 N BSDXRESN
308 S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
309 Q:BSDXRESN=""
310 S BSDXRESN=$P(BSDXRESN,"^")
311 ;D EVENT^BSDX23("SCHEDULE-"_BSDXRESN,"","","")
312 D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
313 Q
314 ;
315ERR(BSDXI,BSDXERR) ;Error processing
316 S BSDXI=BSDXI+1
317 S BSDXERR=$TR(BSDXERR,"^","~")
318 I $TL>0 TROLLBACK
319 S ^BSDXTMP($J,BSDXI)="0^"_BSDXERR_$C(30)
320 S BSDXI=BSDXI+1
321 S ^BSDXTMP($J,BSDXI)=$C(31)
322 L -^BSDXAPPT(BSDXPATID)
323 Q
324 ;
325ETRAP ;EP Error trap entry
326 N $ET S $ET="D ^%ZTER HALT" ; Emergency Error Trap
327 ; Rollback, otherwise ^XTER will be empty from future rollback
328 I $TL>0 TROLLBACK
329 D ^%ZTER
330 S $EC="" ; Clear Error
331 ; Log error message and send to client
332 I '$D(BSDXI) N BSDXI S BSDXI=0
333 D ERR(BSDXI,"-100~BSDX07 Error: "_$G(%ZTERZE))
334 Q
335 ;
336DAY ;;^SUN^MON^TUES^WEDNES^THURS^FRI^SATUR
337 ;
338DOW S %=$E(X,1,3),Y=$E(X,4,5),Y=Y>2&'(%#4)+$E("144025036146",Y)
339 F %=%:-1:281 S Y=%#4=1+1+Y
340 S Y=$E(X,6,7)+Y#7
341 Q
342 ;
343AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN) ;Update RPMS Clinic availability
344 ;SEE SDM1
345 N Y,DFN
346 N SL,STARTDAY,X,SC,SB,HSI,SI,STR,SDDIF,SDMAX,SDDATE,SDDMAX,SDSDATE,CCXN,MXOK,COV,SDPROG
347 N X1,SDEDT,X2,SD,SM,SS,S,SDLOCK,ST,I
348 S Y=BSDXSCD,DFN=BSDXPATID
349 S SL=$G(^SC(+Y,"SL")),X=$P(SL,U,3),STARTDAY=$S($L(X):X,1:8),SC=Y,SB=STARTDAY-1/100,X=$P(SL,U,6),HSI=$S(X=1:X,X:X,1:4),SI=$S(X="":4,X<3:4,X:X,1:4),STR="#@!$* XXWVUTSRQPONMLKJIHGFEDCBA0123456789jklmnopqrstuvwxyz",SDDIF=$S(HSI<3:8/HSI,1:2) K Y
350 ;Determine maximum days for scheduling
351 S SDMAX(1)=$P($G(^SC(+SC,"SDP")),U,2) S:'SDMAX(1) SDMAX(1)=365
352 S (SDMAX,SDDMAX)=$$FMADD^XLFDT(DT,SDMAX(1))
353 S SDDATE=BSDXSTART
354 S SDSDATE=SDDATE,SDDATE=SDDATE\1
3551 ;L Q:$D(SDXXX) S CCXN=0 K MXOK,COV,SDPROT Q:DFN<0 S SC=+SC
356 Q:$D(SDXXX) S CCXN=0 K MXOK,COV,SDPROT Q:DFN<0 S SC=+SC
357 S X1=DT,SDEDT=365 S:$D(^SC(SC,"SDP")) SDEDT=$P(^SC(SC,"SDP"),"^",2)
358 S X2=SDEDT D C^%DTC S SDEDT=X
359 S Y=BSDXSTART
360EN1 S (X,SD)=Y,SM=0 D DOW
361S I '$D(^SC(SC,"ST",$P(SD,"."),1)) S SS=+$O(^SC(+SC,"T"_Y,SD)) Q:SS'>0 Q:^(SS,1)="" S ^SC(+SC,"ST",$P(SD,"."),1)=$E($P($T(DAY),U,Y+2),1,2)_" "_$E(SD,6,7)_$J("",SI+SI-6)_^(1),^(0)=$P(SD,".")
362 S S=BSDXLEN
363 ;Check if BSDXLEN evenly divisible by appointment length
364 S RPMSL=$P(SL,U)
365 I BSDXLEN<RPMSL S BSDXLEN=RPMSL
366 I BSDXLEN#RPMSL'=0 D
367 . S BSDXINC=BSDXLEN\RPMSL
368 . S BSDXINC=BSDXINC+1
369 . S BSDXLEN=RPMSL*BSDXINC
370 S SL=S_U_$P(SL,U,2,99)
371SC S SDLOCK=$S('$D(SDLOCK):1,1:SDLOCK+1) Q:SDLOCK>9
372 L +^SC(SC,"ST",$P(SD,"."),1):5 G:'$T SC
373 S SDLOCK=0,S=^SC(SC,"ST",$P(SD,"."),1)
374 S I=SD#1-SB*100,ST=I#1*SI\.6+($P(I,".")*SI),SS=SL*HSI/60*SDDIF+ST+ST
375 I (I<1!'$F(S,"["))&(S'["CAN") L -^SC(SC,"ST",$P(SD,"."),1) Q
376 I SM<7 S %=$F(S,"[",SS-1) S:'%!($P(SL,"^",6)<3) %=999 I $F(S,"]",SS)'<%!(SDDIF=2&$E(S,ST+ST+1,SS-1)["[") S SM=7
377 ;
378SP I ST+ST>$L(S),$L(S)<80 S S=S_" " G SP
379 S SDNOT=1
380 S ABORT=0
381 F I=ST+ST:SDDIF:SS-SDDIF D Q:ABORT
382 . S ST=$E(S,I+1) S:ST="" ST=" "
383 . S Y=$E(STR,$F(STR,ST)-2)
384 . I S["CAN"!(ST="X"&($D(^SC(+SC,"ST",$P(SD,"."),"CAN")))) S ABORT=1 Q
385 . I Y="" S ABORT=1 Q
386 . S:Y'?1NL&(SM<6) SM=6 S ST=$E(S,I+2,999) S:ST="" ST=" " S S=$E(S,1,I)_Y_ST
387 . Q
388 S ^SC(SC,"ST",$P(SD,"."),1)=S
389 L -^SC(SC,"ST",$P(SD,"."),1)
390 Q
Note: See TracBrowser for help on using the repository browser.