| [1007] | 1 | BSDX08 ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 11/16/10 7:12am
|
|---|
| 2 | ;;1.42;BSDX;;Sep 29, 2010
|
|---|
| 3 | ;
|
|---|
| 4 | ; Original by HMW. New Written by Sam Habiel. Licensed under LGPL.
|
|---|
| 5 | ;
|
|---|
| 6 | ; Change History
|
|---|
| 7 | ; 3101022 UJO/SMH v1.42
|
|---|
| 8 | ; - Transaction now restartable. Thanks to
|
|---|
| 9 | ; --> Zach Gonzalez and Rick Marshall for fix.
|
|---|
| 10 | ; - Extra TROLLBACK in Lock Statement when lock fails.
|
|---|
| 11 | ; --> Removed--Rollback is already in ERR tag.
|
|---|
| 12 | ; - Added new statements to old SD code in AVUPDT to obviate
|
|---|
| 13 | ; --> need to restore variables in transaction
|
|---|
| 14 | ; - Refactored this chunk of code. Don't really know whether it
|
|---|
| 15 | ; --> worked in the first place. Waiting for bug report to know.
|
|---|
| 16 | ; - Refactored all of APPDEL.
|
|---|
| 17 | ;
|
|---|
| 18 | ; Error Reference:
|
|---|
| 19 | ; -1~BSDX08: Appt record is locked. Please contact technical support.
|
|---|
| 20 | ; -2~BSDX08: Invalid Appointment ID
|
|---|
| 21 | ; -3~BSDX08: Invalid Appointment ID
|
|---|
| 22 | ; -4~BSDX08: Cancelled appointment does not have a Resouce ID
|
|---|
| 23 | ; -5~BSDX08: Resouce ID does not exist in BSDX RESOURCE
|
|---|
| 24 | ; -6~BSDX08: Invalid Hosp Location stored in Database
|
|---|
| 25 | ; -7~BSDX08: Patient does not have an appointment in PIMS Clinic
|
|---|
| 26 | ; -8^BSDX08: Unable to find associated PIMS appointment for this patient
|
|---|
| 27 | ; -9^BSDX08: BSDXAPI returned an error: (error)
|
|---|
| 28 | ; -100~BSDX08 Error: (Mumps Error)
|
|---|
| [614] | 29 | ;
|
|---|
| 30 | APPDELD(BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT) ;EP
|
|---|
| 31 | ;Entry point for debugging
|
|---|
| [1007] | 32 | D DEBUG^%Serenji("APPDEL^BSDX08(.BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT)")
|
|---|
| [614] | 33 | Q
|
|---|
| 34 | ;
|
|---|
| [1007] | 35 | UT ; Unit Tests
|
|---|
| 36 | ; Test 1: Make normal appointment and cancel it. See if every thing works
|
|---|
| 37 | N ZZZ
|
|---|
| 38 | D APPADD^BSDX07(.ZZZ,3110123.2,3110123.3,4,"Dr Office",10,"Sam's Note",1)
|
|---|
| 39 | S APPID=+$P(^BSDXTMP($J,1),U)
|
|---|
| 40 | D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Sam's Cancel Note")
|
|---|
| 41 | I $P(^BSDXAPPT(APPID,0),U,12)'>0 W "Error in Cancellation-1"
|
|---|
| 42 | I $O(^SC(2,"S",3110123.2,1,0))]"" W "Error in Cancellation-2"
|
|---|
| 43 | I $P(^DPT(4,"S",3110123.2,0),U,2)'="PC" W "Error in Cancellation-3"
|
|---|
| 44 | I ^DPT(4,"S",3110123.2,"R")'="Sam's Cancel Note" W "Error in Cancellation-4"
|
|---|
| 45 | ;
|
|---|
| 46 | ; Test 2: Check for -1
|
|---|
| 47 | ; Make appt
|
|---|
| 48 | D APPADD^BSDX07(.ZZZ,3110125.2,3110125.3,4,"Dr Office",10,"Sam's Note",1)
|
|---|
| 49 | ; Lock the node in another job
|
|---|
| 50 | S APPID=+$P(^BSDXTMP($J,1),U)
|
|---|
| 51 | ; W "Lock ^BSDXAPPT("_APPID_") in another session. You have 10 seconds." H 10
|
|---|
| 52 | D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Sam's Cancel Note")
|
|---|
| 53 | ;
|
|---|
| 54 | ; Test 3: Check for -100
|
|---|
| 55 | S bsdxdie=1
|
|---|
| 56 | D APPADD^BSDX07(.ZZZ,3110126.2,3110126.3,4,"Dr Office",10,"Sam's Note",1)
|
|---|
| 57 | S APPID=+$P(^BSDXTMP($J,1),U)
|
|---|
| 58 | D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Reasons")
|
|---|
| 59 | I $P(^BSDXTMP($J,1),"~")'=-100 W "Error in -100",!
|
|---|
| 60 | K bsdxdie
|
|---|
| 61 | ;
|
|---|
| 62 | ; Test 4: Restartable transaction
|
|---|
| 63 | S bsdxrestart=1
|
|---|
| 64 | D APPADD^BSDX07(.ZZZ,3110128.2,3110128.3,4,"Dr Office",10,"Sam's Note",1)
|
|---|
| 65 | S APPID=+$P(^BSDXTMP($J,1),U)
|
|---|
| 66 | D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Reasons")
|
|---|
| 67 | I $P(^DPT(4,"S",3110128.2,0),U,2)'="PC" W "Error in Restartable Transaction",!
|
|---|
| 68 | ;
|
|---|
| 69 | ; Test 5: for invalid Appointment ID (-2 and -3)
|
|---|
| 70 | D APPDEL^BSDX08(.ZZZ,0,"PC",1,"Reasons")
|
|---|
| 71 | I $P(^BSDXTMP($J,1),"~")'=-2 W "Error in -2",!
|
|---|
| 72 | D APPDEL^BSDX08(.ZZZ,999999,"PC",1,"Reasons")
|
|---|
| 73 | I $P(^BSDXTMP($J,1),"~")'=-3 W "Error in -3",!
|
|---|
| 74 | QUIT
|
|---|
| 75 | ; Lock the node in another job for testing.
|
|---|
| 76 | UTL(APPID) L +^BSDXAPPT(APPID) HANG 10 QUIT
|
|---|
| 77 | ;
|
|---|
| [614] | 78 | APPDEL(BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT) ;EP
|
|---|
| [1007] | 79 | ;Called by RPC: BSDX CANCEL APPOINTMENT
|
|---|
| 80 | ;Cancels existing appointment in BSDX APPOINTMENT and 44/2 subfiles
|
|---|
| 81 | ;Input Parameters:
|
|---|
| 82 | ; - BSDXAPTID is entry number in BSDX APPOINTMENT file
|
|---|
| 83 | ; - BSDXTYP is C for clinic-cancelled and PC for patient cancelled
|
|---|
| 84 | ; - BSDXCR is pointer to CANCELLATION REASON File (409.2)
|
|---|
| 85 | ; - BSDXNOT is user note
|
|---|
| [614] | 86 | ;
|
|---|
| [1007] | 87 | ; Returns error code in recordset field ERRORID. Zero is success.
|
|---|
| 88 | ; Returns Global Array. Must use this type in RPC.
|
|---|
| [614] | 89 | ;
|
|---|
| [1007] | 90 | ; Return Array: set Return and clear array
|
|---|
| 91 | S BSDXY=$NA(^BSDXTMP($J))
|
|---|
| 92 | K ^BSDXTMP($J)
|
|---|
| 93 | ;
|
|---|
| 94 | ; Set min DUZ vars if they don't exist
|
|---|
| 95 | D ^XBKVAR
|
|---|
| 96 | ;
|
|---|
| 97 | ; $ET
|
|---|
| 98 | N $ET S $ET="G ETRAP^BSDX08"
|
|---|
| 99 | ;
|
|---|
| 100 | ; Counter
|
|---|
| 101 | N BSDXI S BSDXI=0
|
|---|
| 102 | ; Header Node
|
|---|
| 103 | S ^BSDXTMP($J,BSDXI)="T00030ERRORID"_$C(30)
|
|---|
| 104 | ;
|
|---|
| 105 | ; Lock BSDX node, only to synchronize access to the globals.
|
|---|
| 106 | ; It's not expected that the error will ever happen as no filing
|
|---|
| 107 | ; is supposed to take 5 seconds.
|
|---|
| 108 | L +^BSDXAPPT(BSDXAPTID):5 I '$T D ERR(BSDXI,"-1~BSDX08: Appt record is locked. Please contact technical support.") Q
|
|---|
| 109 | ;
|
|---|
| 110 | ;Restartable Transaction; restore paramters when starting.
|
|---|
| 111 | ; (Params restored are what's passed here + BSDXI)
|
|---|
| 112 | TSTART (BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT,BSDXI):T="BSDX CANCEL APPOINTEMENT^BSDX08"
|
|---|
| 113 | ;
|
|---|
| 114 | ; Turn off SDAM APPT PROTOCOL BSDX Entries
|
|---|
| [614] | 115 | N BSDXNOEV
|
|---|
| 116 | S BSDXNOEV=1 ;Don't execute BSDX CANCEL APPOINTMENT protocol
|
|---|
| 117 | ;
|
|---|
| [1007] | 118 | ;;;test for error inside transaction. See if %ZTER works
|
|---|
| 119 | I $G(bsdxdie) S X=1/0
|
|---|
| 120 | ;;;test
|
|---|
| 121 | ;;;test for TRESTART
|
|---|
| 122 | I $G(bsdxrestart) K bsdxrestart TRESTART
|
|---|
| 123 | ;;;test
|
|---|
| 124 | ;
|
|---|
| 125 | ; Check appointment ID and whether it exists
|
|---|
| 126 | I '+BSDXAPTID D ERR(BSDXI,"-2~BSDX08: Invalid Appointment ID") Q
|
|---|
| 127 | I '$D(^BSDXAPPT(BSDXAPTID,0)) D ERR(BSDXI,"-3~BSDX08: Invalid Appointment ID") Q
|
|---|
| [614] | 128 | ;
|
|---|
| [1007] | 129 | ; Start Processing:
|
|---|
| 130 | ; First, add cancellation date to appt entry in BSDX APPOINTMENT
|
|---|
| 131 | N BSDXNOD S BSDXNOD=^BSDXAPPT(BSDXAPTID,0) ; BSDX Appt Node
|
|---|
| 132 | N BSDXPATID S BSDXPATID=$P(BSDXNOD,U,5) ; Patient ID
|
|---|
| 133 | N BSDXSTART S BSDXSTART=$P(BSDXNOD,U) ; Start Time
|
|---|
| 134 | D BSDXCAN(BSDXAPTID) ; Add a cancellation date in BSDX APPOINTMENT
|
|---|
| [614] | 135 | ;
|
|---|
| [1007] | 136 | ; Second, cancel appt in "S" nodes in file 2 and 44, then update Legacy PIMS Availability
|
|---|
| 137 | N BSDXSC1 S BSDXSC1=$P(BSDXNOD,U,7) ;RESOURCEID
|
|---|
| 138 | ; If the resouce id doesn't exist...
|
|---|
| 139 | I BSDXSC1="" D ERR(BSDXI,"-4~BSDX08: Cancelled appointment does not have a Resouce ID") QUIT
|
|---|
| 140 | I '$D(^BSDXRES(BSDXSC1,0)) D ERR(BSDXI,"-5~BSDX08: Resouce ID does not exist in BSDX RESOURCE") QUIT
|
|---|
| 141 | ; Get zero node of resouce
|
|---|
| 142 | S BSDXNOD=^BSDXRES(BSDXSC1,0)
|
|---|
| 143 | ; Get Hosp location
|
|---|
| 144 | N BSDXLOC S BSDXLOC=$P(BSDXNOD,U,4)
|
|---|
| 145 | ; Error indicator for Hosp Location filing for getting out of routine
|
|---|
| 146 | N BSDXERR S BSDXERR=0
|
|---|
| 147 | ; Only file in 2/44 if there is an associated hospital location
|
|---|
| 148 | I BSDXLOC D QUIT:BSDXERR
|
|---|
| 149 | . I '$D(^SC(BSDXLOC,0)) S BSDXERR=1 D ERR(BSDXI,"-6~BSDX08: Invalid Hosp Location stored in Database") QUIT
|
|---|
| 150 | . ; Get the IEN of the appointment in the "S" node of ^SC
|
|---|
| 151 | . N BSDXSCIEN
|
|---|
| 152 | . S BSDXSCIEN=$$SCIEN^BSDXAPI(BSDXPATID,BSDXLOC,BSDXSTART)
|
|---|
| 153 | . I BSDXSCIEN="" S BSDXERR=1 D ERR(BSDXI,"-7~BSDX08: Patient does not have an appointment in PIMS Clinic") QUIT
|
|---|
| 154 | . ; Get the appointment node
|
|---|
| 155 | . S BSDXNOD=$G(^SC(BSDXLOC,"S",BSDXSTART,1,BSDXSCIEN,0))
|
|---|
| 156 | . I BSDXNOD="" S BSDXERR=1 D ERR(BSDXI,"-8^BSDX08: Unable to find associated PIMS appointment for this patient") QUIT
|
|---|
| 157 | . N BSDXLEN S BSDXLEN=$P(BSDXNOD,U,2)
|
|---|
| 158 | . ; Cancel through BSDXAPI
|
|---|
| 159 | . N BSDXZ
|
|---|
| 160 | . D APCAN(.BSDXZ,BSDXLOC,BSDXPATID,BSDXSTART)
|
|---|
| 161 | . I +BSDXZ>0 S BSDXERR=1 D ERR(BSDXI,"-9^BSDX08: BSDXAPI returned an error: "_$P(BSDXZ,U,2)) QUIT
|
|---|
| 162 | . ; Update Legacy PIMS clinic Availability
|
|---|
| [614] | 163 | . D AVUPDT(BSDXLOC,BSDXSTART,BSDXLEN)
|
|---|
| 164 | ;
|
|---|
| 165 | TCOMMIT
|
|---|
| [1007] | 166 | L -^BSDXAPPT(BSDXAPTID)
|
|---|
| [614] | 167 | S BSDXI=BSDXI+1
|
|---|
| 168 | S ^BSDXTMP($J,BSDXI)=""_$C(30)
|
|---|
| 169 | S BSDXI=BSDXI+1
|
|---|
| 170 | S ^BSDXTMP($J,BSDXI)=$C(31)
|
|---|
| 171 | Q
|
|---|
| 172 | ;
|
|---|
| [1007] | 173 | AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN) ;Update Legacy PIMS Clinic availability
|
|---|
| [614] | 174 | ;See SDCNP0
|
|---|
| [1007] | 175 | N SD,S ; Start Date
|
|---|
| 176 | S (SD,S)=BSDXSTART
|
|---|
| 177 | N I ; Clinic IEN in 44
|
|---|
| [614] | 178 | S I=BSDXSCD
|
|---|
| [1007] | 179 | ; if day has no schedule in legacy PIMS, forget about this update.
|
|---|
| [614] | 180 | Q:'$D(^SC(I,"ST",SD\1,1))
|
|---|
| [1007] | 181 | N SL ; Clinic characteristics node (length of appt, when appts start etc)
|
|---|
| 182 | S SL=^SC(I,"SL")
|
|---|
| 183 | N X ; Hour Clinic Display Begins
|
|---|
| 184 | S X=$P(SL,U,3)
|
|---|
| 185 | N STARTDAY ; When does the day start?
|
|---|
| 186 | S STARTDAY=$S($L(X):X,1:8) ; If defined, use it; otherwise, 8am
|
|---|
| 187 | N SB ; ?? Who knows? Day Start - 1 divided by 100.
|
|---|
| 188 | S SB=STARTDAY-1/100
|
|---|
| 189 | S X=$P(SL,U,6) ; Now X is Display increments per hour
|
|---|
| 190 | N HSI ; Slots per hour, try 1
|
|---|
| 191 | S HSI=$S(X:X,1:4) ; if defined, use it; otherwise, 4
|
|---|
| 192 | N SI ; Slots per hour, try 2
|
|---|
| 193 | S SI=$S(X="":4,X<3:4,X:X,1:4) ; If slots "", or less than 3, then 4
|
|---|
| 194 | N STR ; ??
|
|---|
| 195 | S STR="#@!$* XXWVUTSRQPONMLKJIHGFEDCBA0123456789jklmnopqrstuvwxyz"
|
|---|
| 196 | N SDDIF ; Slots per hour diff??
|
|---|
| 197 | S SDDIF=$S(HSI<3:8/HSI,1:2)
|
|---|
| 198 | S SL=BSDXLEN ; Dammit, reusing variable; SL now Appt Length from GUI
|
|---|
| 199 | S S=^SC(I,"ST",SD\1,1) ; reusing var again; S now Day Pattern from PIMS
|
|---|
| 200 | N Y ; Hours since start of Date
|
|---|
| 201 | S Y=SD#1-SB*100 ;SD#1=FM Time portion; -SB minus start of day; conv to hrs
|
|---|
| 202 | N ST ; ??
|
|---|
| 203 | ; Y#1 -> Minutes; *SI -> * Slots per hour; \.6 trunc min to hour
|
|---|
| 204 | ; Y\1 -> Hours since start of day; * SI: * slots
|
|---|
| 205 | S ST=Y#1*SI\.6+(Y\1*SI)
|
|---|
| 206 | N SS ; how many slots are supposed to be taken by appointment
|
|---|
| 207 | S SS=SL*HSI/60 ; (nb: try SL: 30 min; HSI: 4 slots)
|
|---|
| 208 | N I
|
|---|
| 209 | I Y'<1 D ; If Hours since start of Date is greater than 1
|
|---|
| 210 | . ; loop through pattern. Tired of documenting.
|
|---|
| 211 | . F I=ST+ST:SDDIF D Q:Y="" Q:SS'>0
|
|---|
| 212 | . . S Y=$E(STR,$F(STR,$E(S,I+1))) Q:Y=""
|
|---|
| 213 | . . S S=$E(S,1,I)_Y_$E(S,I+2,999)
|
|---|
| 214 | . . S SS=SS-1
|
|---|
| 215 | . . Q:SS'>0
|
|---|
| 216 | S ^SC(BSDXSCD,"ST",SD\1,1)=S ; new pattern; global set
|
|---|
| [614] | 217 | Q
|
|---|
| 218 | ;
|
|---|
| 219 | APCAN(BSDXZ,BSDXLOC,BSDXDFN,BSDXSD) ;
|
|---|
| 220 | ;Cancel appointment for patient BSDXDFN in clinic BSDXSC1
|
|---|
| 221 | ;at time BSDXSD
|
|---|
| 222 | N BSDXC,%H
|
|---|
| 223 | S BSDXC("PAT")=BSDXPATID
|
|---|
| 224 | S BSDXC("CLN")=BSDXLOC
|
|---|
| 225 | S BSDXC("TYP")=BSDXTYP
|
|---|
| 226 | S BSDXC("ADT")=BSDXSD
|
|---|
| 227 | S %H=$H D YMD^%DTC
|
|---|
| 228 | S BSDXC("CDT")=X+%
|
|---|
| 229 | S BSDXC("NOT")=BSDXNOT
|
|---|
| [951] | 230 | S:'+$G(BSDXCR) BSDXCR=11 ;Other
|
|---|
| [614] | 231 | S BSDXC("CR")=BSDXCR
|
|---|
| 232 | S BSDXC("USR")=DUZ
|
|---|
| 233 | ;
|
|---|
| 234 | S BSDXZ=$$CANCEL^BSDXAPI(.BSDXC)
|
|---|
| 235 | Q
|
|---|
| 236 | ;
|
|---|
| 237 | BSDXCAN(BSDXAPTID) ;
|
|---|
| 238 | ;Cancel BSDX APPOINTMENT entry
|
|---|
| 239 | N %DT,X,BSDXDATE,Y,BSDXIENS,BSDXFDA,BSDXMSG
|
|---|
| 240 | S %DT="XT",X="NOW" D ^%DT ; X ^DD("DD")
|
|---|
| 241 | S BSDXDATE=Y
|
|---|
| 242 | S BSDXIENS=BSDXAPTID_","
|
|---|
| 243 | S BSDXFDA(9002018.4,BSDXIENS,.12)=BSDXDATE
|
|---|
| 244 | K BSDXMSG
|
|---|
| 245 | D FILE^DIE("","BSDXFDA","BSDXMSG")
|
|---|
| 246 | Q
|
|---|
| 247 | ;
|
|---|
| 248 | CANEVT(BSDXPAT,BSDXSTART,BSDXSC) ;EP Called by BSDX CANCEL APPOINTMENT event
|
|---|
| 249 | ;when appointments cancelled via PIMS interface.
|
|---|
| 250 | ;Propagates cancellation to BSDXAPPT and raises refresh event to running GUI clients
|
|---|
| 251 | N BSDXFOUND,BSDXRES
|
|---|
| 252 | Q:+$G(BSDXNOEV)
|
|---|
| 253 | Q:'+$G(BSDXSC)
|
|---|
| 254 | S BSDXFOUND=0
|
|---|
| 255 | I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0)) S BSDXFOUND=$$CANEVT1(BSDXRES,BSDXSTART,BSDXPAT)
|
|---|
| 256 | I BSDXFOUND D CANEVT3(BSDXRES) Q
|
|---|
| 257 | I $D(^BXDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0)) S BSDXFOUND=$$CANEVT1(BSDXRES,BSDXSTART,BSDXPAT)
|
|---|
| 258 | I BSDXFOUND D CANEVT3(BSDXRES)
|
|---|
| 259 | Q
|
|---|
| 260 | ;
|
|---|
| 261 | CANEVT1(BSDXRES,BSDXSTART,BSDXPAT) ;
|
|---|
| 262 | ;Get appointment id in BSDXAPT
|
|---|
| 263 | ;If found, call BSDXCAN(BSDXAPPT) and return 1
|
|---|
| 264 | ;else return 0
|
|---|
| 265 | N BSDXFOUND,BSDXAPPT
|
|---|
| 266 | S BSDXFOUND=0
|
|---|
| 267 | Q:'+BSDXRES BSDXFOUND
|
|---|
| 268 | Q:'$D(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART)) BSDXFOUND
|
|---|
| 269 | S BSDXAPPT=0 F S BSDXAPPT=$O(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART,BSDXAPPT)) Q:'+BSDXAPPT D Q:BSDXFOUND
|
|---|
| 270 | . S BSDXNOD=$G(^BSDXAPPT(BSDXAPPT,0)) Q:BSDXNOD=""
|
|---|
| 271 | . I $P(BSDXNOD,U,5)=BSDXPAT,$P(BSDXNOD,U,12)="" S BSDXFOUND=1 Q
|
|---|
| 272 | I BSDXFOUND,+$G(BSDXAPPT) D BSDXCAN(BSDXAPPT)
|
|---|
| 273 | Q BSDXFOUND
|
|---|
| 274 | ;
|
|---|
| 275 | CANEVT3(BSDXRES) ;
|
|---|
| 276 | ;Call RaiseEvent to notify GUI clients
|
|---|
| 277 | ;
|
|---|
| 278 | N BSDXRESN
|
|---|
| 279 | S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
|
|---|
| 280 | Q:BSDXRESN=""
|
|---|
| 281 | S BSDXRESN=$P(BSDXRESN,"^")
|
|---|
| 282 | ;D EVENT^BSDX23("SCHEDULE-"_BSDXRESN,"","","")
|
|---|
| 283 | D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
|
|---|
| 284 | Q
|
|---|
| 285 | ;
|
|---|
| 286 | ERR(BSDXI,BSDXERR) ;Error processing
|
|---|
| 287 | S BSDXI=BSDXI+1
|
|---|
| 288 | S BSDXERR=$TR(BSDXERR,"^","~")
|
|---|
| [1007] | 289 | I $TL>0 TROLLBACK
|
|---|
| [614] | 290 | S ^BSDXTMP($J,BSDXI)=BSDXERR_$C(30)
|
|---|
| 291 | S BSDXI=BSDXI+1
|
|---|
| 292 | S ^BSDXTMP($J,BSDXI)=$C(31)
|
|---|
| [1007] | 293 | L -^BSDXAPPT(BSDXAPTID)
|
|---|
| 294 | QUIT
|
|---|
| [614] | 295 | ;
|
|---|
| 296 | ETRAP ;EP Error trap entry
|
|---|
| [1007] | 297 | N $ET S $ET="D ^%ZTER HALT" ; Emergency Error Trap
|
|---|
| 298 | ; Rollback, otherwise ^XTER will be empty from future rollback
|
|---|
| 299 | I $TL>0 TROLLBACK
|
|---|
| 300 | D ^%ZTER
|
|---|
| 301 | S $EC="" ; Clear Error
|
|---|
| 302 | ; Log error message and send to client
|
|---|
| 303 | I '$D(BSDXI) N BSDXI S BSDXI=0
|
|---|
| 304 | D ERR(BSDXI,"-100~BSDX08 Error: "_$G(%ZTERZE))
|
|---|
| 305 | QUIT
|
|---|
| 306 | ;
|
|---|
| 307 | ;;;NB: This is code that is unused in both original and port.
|
|---|
| 308 | ; ; If not appt in the "S" node is found in ^SC then check associated RPMS Clinic Multiple
|
|---|
| 309 | ; I BSDXSCIEN="" D I 'BSDXZ Q ;Q:BSDXZ
|
|---|
| 310 | ; . S BSDXERR="BSDX08: Unable to find associated RPMS appointment for this patient. "
|
|---|
| 311 | ; . S BSDXZ=1
|
|---|
| 312 | ; . ; Check if there are associated RPMS clinics. (not currently used) Does the multiple exist? No, then quit
|
|---|
| 313 | ; . I '$D(^BSDXRES(BSDXSC1,20)) S BSDXZ=0 QUIT
|
|---|
| 314 | ; . ; Loop through the multiple. Get Location and then the ^SC "S" node IEN.
|
|---|
| 315 | ; . N BSDX1 S BSDX1=0
|
|---|
| 316 | ; . F S BSDX1=$O(^BSDXRES(BSDXSC1,20,BSDX1)) Q:'+BSDX1 Q:BSDXZ=0 D
|
|---|
| 317 | ; . . Q:'$D(^BSDXRES(BSDXSC1,20,BSDX1,0))
|
|---|
| 318 | ; . . S BSDXLOC=$P(^BSDXRES(BSDXSC1,20,BSDX1,0),U)
|
|---|
| 319 | . ; . . S BSDXSCIEN=$$SCIEN^BSDXAPI(BSDXPATID,BSDXLOC,BSDXSTART) I +BSDXSCIEN S BSDXZ=0 Q
|
|---|
