source: Scheduling/trunk/m/BSDX08.m@ 1076

Last change on this file since 1076 was 1076, checked in by Sam Habiel, 13 years ago

Updates to M routines to support deletion of check-in
File size: 12.5 KB
Line 
1BSDX08 ; IHS/OIT/HMW - WINDOWS SCHEDULING RPCS ; 12/6/10 12:35pm
2 ;;1.42;BSDX;;Dec 07, 2010
3 ;
4 ; Original by HMW. New Written by Sam Habiel. Licensed under LGPL.
5 ;
6 ; Change History
7 ; 3101022 UJO/SMH v1.42
8 ; - Transaction now restartable. Thanks to
9 ; --> Zach Gonzalez and Rick Marshall for fix.
10 ; - Extra TROLLBACK in Lock Statement when lock fails.
11 ; --> Removed--Rollback is already in ERR tag.
12 ; - Added new statements to old SD code in AVUPDT to obviate
13 ; --> need to restore variables in transaction
14 ; - Refactored this chunk of code. Don't really know whether it
15 ; --> worked in the first place. Waiting for bug report to know.
16 ; - Refactored all of APPDEL.
17 ;
18 ; Error Reference:
19 ; -1~BSDX08: Appt record is locked. Please contact technical support.
20 ; -2~BSDX08: Invalid Appointment ID
21 ; -3~BSDX08: Invalid Appointment ID
22 ; -4~BSDX08: Cancelled appointment does not have a Resouce ID
23 ; -5~BSDX08: Resouce ID does not exist in BSDX RESOURCE
24 ; -6~BSDX08: Invalid Hosp Location stored in Database
25 ; -7~BSDX08: Patient does not have an appointment in PIMS Clinic
26 ; -8^BSDX08: Unable to find associated PIMS appointment for this patient
27 ; -9^BSDX08: BSDXAPI returned an error: (error)
28 ; -100~BSDX08 Error: (Mumps Error)
29 ;
30APPDELD(BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT) ;EP
31 ;Entry point for debugging
32 D DEBUG^%Serenji("APPDEL^BSDX08(.BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT)")
33 Q
34 ;
35UT ; Unit Tests
36 ; Test 1: Make normal appointment and cancel it. See if every thing works
37 N ZZZ
38 D APPADD^BSDX07(.ZZZ,3110123.2,3110123.3,4,"Dr Office",10,"Sam's Note",1)
39 S APPID=+$P(^BSDXTMP($J,1),U)
40 D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Sam's Cancel Note")
41 I $P(^BSDXAPPT(APPID,0),U,12)'>0 W "Error in Cancellation-1"
42 I $O(^SC(2,"S",3110123.2,1,0))]"" W "Error in Cancellation-2"
43 I $P(^DPT(4,"S",3110123.2,0),U,2)'="PC" W "Error in Cancellation-3"
44 I ^DPT(4,"S",3110123.2,"R")'="Sam's Cancel Note" W "Error in Cancellation-4"
45 ;
46 ; Test 2: Check for -1
47 ; Make appt
48 D APPADD^BSDX07(.ZZZ,3110125.2,3110125.3,4,"Dr Office",10,"Sam's Note",1)
49 ; Lock the node in another job
50 S APPID=+$P(^BSDXTMP($J,1),U)
51 ; W "Lock ^BSDXAPPT("_APPID_") in another session. You have 10 seconds." H 10
52 D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Sam's Cancel Note")
53 ;
54 ; Test 3: Check for -100
55 S bsdxdie=1
56 D APPADD^BSDX07(.ZZZ,3110126.2,3110126.3,4,"Dr Office",10,"Sam's Note",1)
57 S APPID=+$P(^BSDXTMP($J,1),U)
58 D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Reasons")
59 I $P(^BSDXTMP($J,1),"~")'=-100 W "Error in -100",!
60 K bsdxdie
61 ;
62 ; Test 4: Restartable transaction
63 S bsdxrestart=1
64 D APPADD^BSDX07(.ZZZ,3110128.2,3110128.3,4,"Dr Office",10,"Sam's Note",1)
65 S APPID=+$P(^BSDXTMP($J,1),U)
66 D APPDEL^BSDX08(.ZZZ,APPID,"PC",1,"Reasons")
67 I $P(^DPT(4,"S",3110128.2,0),U,2)'="PC" W "Error in Restartable Transaction",!
68 ;
69 ; Test 5: for invalid Appointment ID (-2 and -3)
70 D APPDEL^BSDX08(.ZZZ,0,"PC",1,"Reasons")
71 I $P(^BSDXTMP($J,1),"~")'=-2 W "Error in -2",!
72 D APPDEL^BSDX08(.ZZZ,999999,"PC",1,"Reasons")
73 I $P(^BSDXTMP($J,1),"~")'=-3 W "Error in -3",!
74 ;
75 ; Test 6: for Cancelling walkin and checked-in appointments.
76 S BSDXSTART=$E($$NOW^XLFDT,1,12),BSDXEND=BSDXSTART+.0001
77 D APPADD^BSDX07(.ZZZ,BSDXSTART,BSDXEND,4,"Dr Office",10,"Sam's Note",1)
78 S APPID=+$P(^BSDXTMP($J,1),U)
79 B
80 D CHECKIN^BSDX25(.ZZZ,APPID,$$NOW^XLFDT)
81 B
82 D APPDEL^BSDX08(.ZZZ,APPID,"PC",10,"Cancel Note")
83 QUIT
84 ; Lock the node in another job for testing.
85UTL(APPID) L +^BSDXAPPT(APPID) HANG 10 QUIT
86 ;
87APPDEL(BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT) ;EP
88 ;Called by RPC: BSDX CANCEL APPOINTMENT
89 ;Cancels existing appointment in BSDX APPOINTMENT and 44/2 subfiles
90 ;Input Parameters:
91 ; - BSDXAPTID is entry number in BSDX APPOINTMENT file
92 ; - BSDXTYP is C for clinic-cancelled and PC for patient cancelled
93 ; - BSDXCR is pointer to CANCELLATION REASON File (409.2)
94 ; - BSDXNOT is user note
95 ;
96 ; Returns error code in recordset field ERRORID. Zero is success.
97 ; Returns Global Array. Must use this type in RPC.
98 ;
99 ; Return Array: set Return and clear array
100 S BSDXY=$NA(^BSDXTMP($J))
101 K ^BSDXTMP($J)
102 ;
103 ; Set min DUZ vars if they don't exist
104 D ^XBKVAR
105 ;
106 ; $ET
107 N $ET S $ET="G ETRAP^BSDX08"
108 ;
109 ; Counter
110 N BSDXI S BSDXI=0
111 ; Header Node
112 S ^BSDXTMP($J,BSDXI)="T00100ERRORID"_$C(30)
113 ;
114 ; Lock BSDX node, only to synchronize access to the globals.
115 ; It's not expected that the error will ever happen as no filing
116 ; is supposed to take 5 seconds.
117 L +^BSDXAPPT(BSDXAPTID):5 I '$T D ERR(BSDXI,"-1~BSDX08: Appt record is locked. Please contact technical support.") Q
118 ;
119 ;Restartable Transaction; restore paramters when starting.
120 ; (Params restored are what's passed here + BSDXI)
121 TSTART (BSDXY,BSDXAPTID,BSDXTYP,BSDXCR,BSDXNOT,BSDXI):T="BSDX CANCEL APPOINTEMENT^BSDX08"
122 ;
123 ; Turn off SDAM APPT PROTOCOL BSDX Entries
124 N BSDXNOEV
125 S BSDXNOEV=1 ;Don't execute BSDX CANCEL APPOINTMENT protocol
126 ;
127 ;;;test for error inside transaction. See if %ZTER works
128 I $G(bsdxdie) S X=1/0
129 ;;;test
130 ;;;test for TRESTART
131 I $G(bsdxrestart) K bsdxrestart TRESTART
132 ;;;test
133 ;
134 ; Check appointment ID and whether it exists
135 I '+BSDXAPTID D ERR(BSDXI,"-2~BSDX08: Invalid Appointment ID") Q
136 I '$D(^BSDXAPPT(BSDXAPTID,0)) D ERR(BSDXI,"-3~BSDX08: Invalid Appointment ID") Q
137 ;
138 ; Start Processing:
139 ; First, add cancellation date to appt entry in BSDX APPOINTMENT
140 N BSDXNOD S BSDXNOD=^BSDXAPPT(BSDXAPTID,0) ; BSDX Appt Node
141 N BSDXPATID S BSDXPATID=$P(BSDXNOD,U,5) ; Patient ID
142 N BSDXSTART S BSDXSTART=$P(BSDXNOD,U) ; Start Time
143 D BSDXCAN(BSDXAPTID) ; Add a cancellation date in BSDX APPOINTMENT
144 ;
145 ; Second, cancel appt in "S" nodes in file 2 and 44, then update Legacy PIMS Availability
146 N BSDXSC1 S BSDXSC1=$P(BSDXNOD,U,7) ;RESOURCEID
147 ; If the resouce id doesn't exist...
148 I BSDXSC1="" D ERR(BSDXI,"-4~BSDX08: Cancelled appointment does not have a Resouce ID") QUIT
149 I '$D(^BSDXRES(BSDXSC1,0)) D ERR(BSDXI,"-5~BSDX08: Resouce ID does not exist in BSDX RESOURCE") QUIT
150 ; Get zero node of resouce
151 S BSDXNOD=^BSDXRES(BSDXSC1,0)
152 ; Get Hosp location
153 N BSDXLOC S BSDXLOC=$P(BSDXNOD,U,4)
154 ; Error indicator for Hosp Location filing for getting out of routine
155 N BSDXERR S BSDXERR=0
156 ; Only file in 2/44 if there is an associated hospital location
157 I BSDXLOC D QUIT:BSDXERR
158 . I '$D(^SC(BSDXLOC,0)) S BSDXERR=1 D ERR(BSDXI,"-6~BSDX08: Invalid Hosp Location stored in Database") QUIT
159 . ; Get the IEN of the appointment in the "S" node of ^SC
160 . N BSDXSCIEN
161 . S BSDXSCIEN=$$SCIEN^BSDXAPI(BSDXPATID,BSDXLOC,BSDXSTART)
162 . I BSDXSCIEN="" S BSDXERR=1 D ERR(BSDXI,"-7~BSDX08: Patient does not have an appointment in PIMS Clinic") QUIT
163 . ; Get the appointment node
164 . S BSDXNOD=$G(^SC(BSDXLOC,"S",BSDXSTART,1,BSDXSCIEN,0))
165 . I BSDXNOD="" S BSDXERR=1 D ERR(BSDXI,"-8^BSDX08: Unable to find associated PIMS appointment for this patient") QUIT
166 . N BSDXLEN S BSDXLEN=$P(BSDXNOD,U,2)
167 . ; Cancel through BSDXAPI
168 . N BSDXZ
169 . D APCAN(.BSDXZ,BSDXLOC,BSDXPATID,BSDXSTART)
170 . I +BSDXZ>0 S BSDXERR=1 D ERR(BSDXI,"-9^BSDX08: BSDXAPI returned an error: "_$P(BSDXZ,U,2)) QUIT
171 . ; Update Legacy PIMS clinic Availability
172 . D AVUPDT(BSDXLOC,BSDXSTART,BSDXLEN)
173 ;
174 TCOMMIT
175 L -^BSDXAPPT(BSDXAPTID)
176 S BSDXI=BSDXI+1
177 S ^BSDXTMP($J,BSDXI)=""_$C(30)
178 S BSDXI=BSDXI+1
179 S ^BSDXTMP($J,BSDXI)=$C(31)
180 Q
181 ;
182AVUPDT(BSDXSCD,BSDXSTART,BSDXLEN) ;Update Legacy PIMS Clinic availability
183 ;See SDCNP0
184 N SD,S ; Start Date
185 S (SD,S)=BSDXSTART
186 N I ; Clinic IEN in 44
187 S I=BSDXSCD
188 ; if day has no schedule in legacy PIMS, forget about this update.
189 Q:'$D(^SC(I,"ST",SD\1,1))
190 N SL ; Clinic characteristics node (length of appt, when appts start etc)
191 S SL=^SC(I,"SL")
192 N X ; Hour Clinic Display Begins
193 S X=$P(SL,U,3)
194 N STARTDAY ; When does the day start?
195 S STARTDAY=$S($L(X):X,1:8) ; If defined, use it; otherwise, 8am
196 N SB ; ?? Who knows? Day Start - 1 divided by 100.
197 S SB=STARTDAY-1/100
198 S X=$P(SL,U,6) ; Now X is Display increments per hour
199 N HSI ; Slots per hour, try 1
200 S HSI=$S(X:X,1:4) ; if defined, use it; otherwise, 4
201 N SI ; Slots per hour, try 2
202 S SI=$S(X="":4,X<3:4,X:X,1:4) ; If slots "", or less than 3, then 4
203 N STR ; ??
204 S STR="#@!$* XXWVUTSRQPONMLKJIHGFEDCBA0123456789jklmnopqrstuvwxyz"
205 N SDDIF ; Slots per hour diff??
206 S SDDIF=$S(HSI<3:8/HSI,1:2)
207 S SL=BSDXLEN ; Dammit, reusing variable; SL now Appt Length from GUI
208 S S=^SC(I,"ST",SD\1,1) ; reusing var again; S now Day Pattern from PIMS
209 N Y ; Hours since start of Date
210 S Y=SD#1-SB*100 ;SD#1=FM Time portion; -SB minus start of day; conv to hrs
211 N ST ; ??
212 ; Y#1 -> Minutes; *SI -> * Slots per hour; \.6 trunc min to hour
213 ; Y\1 -> Hours since start of day; * SI: * slots
214 S ST=Y#1*SI\.6+(Y\1*SI)
215 N SS ; how many slots are supposed to be taken by appointment
216 S SS=SL*HSI/60 ; (nb: try SL: 30 min; HSI: 4 slots)
217 N I
218 I Y'<1 D ; If Hours since start of Date is greater than 1
219 . ; loop through pattern. Tired of documenting.
220 . F I=ST+ST:SDDIF D Q:Y="" Q:SS'>0
221 . . S Y=$E(STR,$F(STR,$E(S,I+1))) Q:Y=""
222 . . S S=$E(S,1,I)_Y_$E(S,I+2,999)
223 . . S SS=SS-1
224 . . Q:SS'>0
225 S ^SC(BSDXSCD,"ST",SD\1,1)=S ; new pattern; global set
226 Q
227 ;
228APCAN(BSDXZ,BSDXLOC,BSDXDFN,BSDXSD) ;
229 ;Cancel appointment for patient BSDXDFN in clinic BSDXSC1
230 ;at time BSDXSD
231 N BSDXC,%H
232 S BSDXC("PAT")=BSDXPATID
233 S BSDXC("CLN")=BSDXLOC
234 S BSDXC("TYP")=BSDXTYP
235 S BSDXC("ADT")=BSDXSD
236 S %H=$H D YMD^%DTC
237 S BSDXC("CDT")=X+%
238 S BSDXC("NOT")=BSDXNOT
239 S:'+$G(BSDXCR) BSDXCR=11 ;Other
240 S BSDXC("CR")=BSDXCR
241 S BSDXC("USR")=DUZ
242 ;
243 S BSDXZ=$$CANCEL^BSDXAPI(.BSDXC)
244 Q
245 ;
246BSDXCAN(BSDXAPTID) ;
247 ;Cancel BSDX APPOINTMENT entry
248 N %DT,X,BSDXDATE,Y,BSDXIENS,BSDXFDA,BSDXMSG
249 S %DT="XT",X="NOW" D ^%DT ; X ^DD("DD")
250 S BSDXDATE=Y
251 S BSDXIENS=BSDXAPTID_","
252 S BSDXFDA(9002018.4,BSDXIENS,.12)=BSDXDATE
253 K BSDXMSG
254 D FILE^DIE("","BSDXFDA","BSDXMSG")
255 Q
256 ;
257CANEVT(BSDXPAT,BSDXSTART,BSDXSC) ;EP Called by BSDX CANCEL APPOINTMENT event
258 ;when appointments cancelled via PIMS interface.
259 ;Propagates cancellation to BSDXAPPT and raises refresh event to running GUI clients
260 N BSDXFOUND,BSDXRES
261 Q:+$G(BSDXNOEV)
262 Q:'+$G(BSDXSC)
263 S BSDXFOUND=0
264 I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0)) S BSDXFOUND=$$CANEVT1(BSDXRES,BSDXSTART,BSDXPAT)
265 I BSDXFOUND D CANEVT3(BSDXRES) Q
266 I $D(^BXDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0)) S BSDXFOUND=$$CANEVT1(BSDXRES,BSDXSTART,BSDXPAT)
267 I BSDXFOUND D CANEVT3(BSDXRES)
268 Q
269 ;
270CANEVT1(BSDXRES,BSDXSTART,BSDXPAT) ;
271 ;Get appointment id in BSDXAPT
272 ;If found, call BSDXCAN(BSDXAPPT) and return 1
273 ;else return 0
274 N BSDXFOUND,BSDXAPPT
275 S BSDXFOUND=0
276 Q:'+BSDXRES BSDXFOUND
277 Q:'$D(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART)) BSDXFOUND
278 S BSDXAPPT=0 F S BSDXAPPT=$O(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART,BSDXAPPT)) Q:'+BSDXAPPT D Q:BSDXFOUND
279 . S BSDXNOD=$G(^BSDXAPPT(BSDXAPPT,0)) Q:BSDXNOD=""
280 . I $P(BSDXNOD,U,5)=BSDXPAT,$P(BSDXNOD,U,12)="" S BSDXFOUND=1 Q
281 I BSDXFOUND,+$G(BSDXAPPT) D BSDXCAN(BSDXAPPT)
282 Q BSDXFOUND
283 ;
284CANEVT3(BSDXRES) ;
285 ;Call RaiseEvent to notify GUI clients
286 ;
287 N BSDXRESN
288 S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
289 Q:BSDXRESN=""
290 S BSDXRESN=$P(BSDXRESN,"^")
291 ;D EVENT^BSDX23("SCHEDULE-"_BSDXRESN,"","","")
292 D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
293 Q
294 ;
295ERR(BSDXI,BSDXERR) ;Error processing
296 S BSDXI=BSDXI+1
297 S BSDXERR=$TR(BSDXERR,"^","~")
298 I $TL>0 TROLLBACK
299 S ^BSDXTMP($J,BSDXI)=BSDXERR_$C(30)
300 S BSDXI=BSDXI+1
301 S ^BSDXTMP($J,BSDXI)=$C(31)
302 L -^BSDXAPPT(BSDXAPTID)
303 QUIT
304 ;
305ETRAP ;EP Error trap entry
306 N $ET S $ET="D ^%ZTER HALT" ; Emergency Error Trap
307 ; Rollback, otherwise ^XTER will be empty from future rollback
308 I $TL>0 TROLLBACK
309 D ^%ZTER
310 S $EC="" ; Clear Error
311 ; Log error message and send to client
312 I '$D(BSDXI) N BSDXI S BSDXI=0
313 D ERR(BSDXI,"-100~BSDX08 Error: "_$G(%ZTERZE))
314 QUIT
315 ;
316 ;;;NB: This is code that is unused in both original and port.
317 ; ; If not appt in the "S" node is found in ^SC then check associated RPMS Clinic Multiple
318 ; I BSDXSCIEN="" D I 'BSDXZ Q ;Q:BSDXZ
319 ; . S BSDXERR="BSDX08: Unable to find associated RPMS appointment for this patient. "
320 ; . S BSDXZ=1
321 ; . ; Check if there are associated RPMS clinics. (not currently used) Does the multiple exist? No, then quit
322 ; . I '$D(^BSDXRES(BSDXSC1,20)) S BSDXZ=0 QUIT
323 ; . ; Loop through the multiple. Get Location and then the ^SC "S" node IEN.
324 ; . N BSDX1 S BSDX1=0
325 ; . F S BSDX1=$O(^BSDXRES(BSDXSC1,20,BSDX1)) Q:'+BSDX1 Q:BSDXZ=0 D
326 ; . . Q:'$D(^BSDXRES(BSDXSC1,20,BSDX1,0))
327 ; . . S BSDXLOC=$P(^BSDXRES(BSDXSC1,20,BSDX1,0),U)
328 . ; . . S BSDXSCIEN=$$SCIEN^BSDXAPI(BSDXPATID,BSDXLOC,BSDXSTART) I +BSDXSCIEN S BSDXZ=0 Q
Note: See TracBrowser for help on using the repository browser.