source: Scheduling/trunk/m/BSDX25.m@ 1463

Last change on this file since 1463 was 1463, checked in by Sam Habiel, 12 years ago

Moved some unit tests around; Unit tests for BSDX25; minor refactoring for BSDX25
File size: 7.0 KB
Line 
1BSDX25 ; VW/UJO/SMH - WINDOWS SCHEDULING RPCS ; 6/28/12 11:45am
2 ;;1.6;BSDX;;Aug 31, 2011;Build 18
3 ; Licensed under LGPL
4 ;
5 ; Change Log:
6 ; 3110106: SMH -> Changed Check-in EP - Removed unused paramters. Will change C#
7 ;
8 ;
9CHECKIND(BSDXY,BSDXAPTID,BSDXCDT,BSDXCC,BSDXPRV,BSDXROU,BSDXVCL,BSDXVFM,BSDXOG) ;EP
10 ;Entry point for debugging
11 ;
12 ;I +$G(^BSDXDBUG("BREAK","CHECKIN")),+$G(^BSDXDBUG("BREAK"))=DUZ D DEBUG^%Serenji("CHECKIN^BSDX25(.BSDXY,BSDXAPTID,BSDXCDT,BSDXCC,BSDXPRV,BSDXROU,BSDXVCL,BSDXVFM,BSDXOG)",$P(^BSDXDBUG("BREAK"),U,2))
13 Q
14 ;
15CHECKIN(BSDXY,BSDXAPTID,BSDXCDT) ;Private EP Check in appointment
16 ; Old additional vars: ,BSDXCC,BSDXPRV,BSDXROU,BSDXVCL,BSDXVFM,BSDXOG)
17 ; Private to GUI; use BSDXAPI for general API to checkin patients
18 ; Parameters:
19 ; BSDXY: Global Out
20 ; BSDXAPTID: Appointment ID in ^BSDXAPPT
21 ; BSDXCDT: Checkin Date --> Changed
22 ; BSDXCC: Clinic Stop IEN (not used)
23 ; BSDXPRV: Provider IEN (not used)
24 ; BSDXROU: Print Routing Slip? (not used)
25 ; BSDXVCL: PCC+ Clinic IEN (not used)
26 ; BSDXVFM: PCC+ Form IEN (not used)
27 ; BSDXOG: PCC+ Outguide (true or false)
28 ;
29 ; Output:
30 ; ADO.net table with 1 column ErrorID, 1 row result
31 ; - 0 if all okay
32 ; - Another number or text if not
33 ;
34 N BSDXNOD,BSDXPATID,BSDXSTART,DIK,DA,BSDXID,BSDXZ,BSDXIENS,BSDXVEN
35 ;
36 ; Turn off SDAM Appointment Events BSDX Protocol Processing
37 N BSDXNOEV
38 S BSDXNOEV=1 ;Don't execute protocol
39 ;
40 ; Set min DUZ vars
41 D ^XBKVAR
42 ;
43 ; $ET
44 N $ET S $ET="G ERROR^BSDX25"
45 ;
46 N BSDXI S BSDXI=0
47 K ^BSDXTMP($J)
48 S BSDXY="^BSDXTMP("_$J_")"
49 S ^BSDXTMP($J,0)="T00020ERRORID"_$C(30)
50 I '+BSDXAPTID D ERR("BSDX25: Invalid Appointment ID") Q
51 I '$D(^BSDXAPPT(BSDXAPTID,0)) D ERR("BSDX08: Invalid Appointment ID") Q
52 ; Remove Date formatting v.1.5. Client will send date as FM Date.
53 ;S:BSDXCDT["@0000" BSDXCDT=$P(BSDXCDT,"@")
54 ;S %DT="T",X=BSDXCDT D ^%DT S BSDXCDT=Y
55 S BSDXCDT=+BSDXCDT ; Strip off zeros if C# sends them
56 I BSDXCDT=-1 D ERR(70) Q
57 I BSDXCDT>$$NOW^XLFDT S BSDXCDT=$$NOW^XLFDT
58 ;Checkin BSDX APPOINTMENT entry
59 D BSDXCHK(BSDXAPTID,BSDXCDT)
60 S BSDXNOD=^BSDXAPPT(BSDXAPTID,0)
61 S BSDXPATID=$P(BSDXNOD,U,5)
62 S BSDXSTART=$P(BSDXNOD,U)
63 ;
64 S BSDXSC1=$P(BSDXNOD,U,7) ;RESOURCEID
65 I BSDXSC1]"",$D(^BSDXRES(BSDXSC1,0)) D I +$G(BSDXZ) D ERR($P(BSDXZ,U,2)) Q
66 . S BSDXNOD=^BSDXRES(BSDXSC1,0)
67 . S BSDXSC1=$P(BSDXNOD,U,4) ;HOSPITAL LOCATION
68 . I BSDXSC1]"",$D(^SC(BSDXSC1,0)) D APCHK(.BSDXZ,BSDXSC1,BSDXPATID,BSDXCDT,BSDXSTART)
69 ;
70 S BSDXI=BSDXI+1
71 S ^BSDXTMP($J,BSDXI)="0"_$C(30)
72 S BSDXI=BSDXI+1
73 S ^BSDXTMP($J,BSDXI)=$C(31)
74 Q
75 ;
76BSDXCHK(BSDXAPTID,BSDXCDT) ;
77 ;
78 S BSDXIENS=BSDXAPTID_","
79 S BSDXFDA(9002018.4,BSDXIENS,.03)=BSDXCDT
80 D FILE^DIE("","BSDXFDA","BSDXMSG")
81 Q
82 ;
83APCHK(BSDXZ,BSDXSC1,BSDXDFN,BSDXCDT,BSDXSTART) ;
84 ;Checkin appointment for patient BSDXDFN in clinic BSDXSC1
85 ;at time BSDXSTART
86 S BSDXZ=$$CHECKIN1^BSDXAPI(BSDXDFN,BSDXSC1,BSDXSTART)
87 Q
88 ;
89RMCI(BSDXY,BSDXAPPTID) ; EP - Remove Check-in from BSDX APPT and 2/44
90 ; Called by RPC [Fill in later]
91 ;
92 ; Parameters to pass:
93 ; APPTID: IEN in file BSDX APPOINTMENT
94 ;
95 ; Return in global array:
96 ; Record set with Column ERRORID; value of 0 AOK; other value
97 ; --> means that something went wrong
98 ;
99 ; Error Reference:
100 ; -1~Invalid Appointment ID (not passed)
101 ; -2~Invalid Appointment ID (Doesn't exist in ^BSDXAPPT)
102 ; -3~DB has corruption. Call Tech Support. (Resource ID doesn't exist in BSDXAPPT)
103 ; -4~DB has corruption. Call Tech Support. (Resource ID in BSDXAPPT doesnt exist in BSDXRES)
104 ; -5~BSDXAPI Error. Message depends on error.
105 ; -100~Mumps Error
106 ;
107 N BSDXNOEV S BSDXNOEV=1 ;Don't execute protocol
108 ;
109 N $ET S $ET="G ERROR^BSDX25" ; Error Trap
110 ;
111 ; Set return variable and kill contents
112 S BSDXY=$NAME(^BSDXTMP($J))
113 K @BSDXY
114 ;
115 N BSDXI S BSDXI=0 ; Initialize Counter
116 ;
117 S ^BSDXTMP($J,BSDXI)="T00020ERRORID"_$C(30) ; Header of ADO recordset
118 ;
119 TSTART (BSDXI):SERIAL ; Perform Autolocking
120 ;
121 ;;;test
122 I $g(bsdxdie) S X=8/0
123 ;;;
124 I $g(bsdxrestart) k bsdxrestart TRESTART
125 ;;;test
126 ;
127 ; Check for Appointment ID (passed and exists in file)
128 I '+$G(BSDXAPPTID) D ERR("-1~Invalid Appointment ID") QUIT
129 I '$D(^BSDXAPPT(BSDXAPPTID,0)) D ERR("-2~Invalid Appointment ID") QUIT
130 ;
131 ; Remove checkin from BSDX APPOINTMENT entry
132 D BSDXCHK(BSDXAPPTID,"@")
133 ;
134 ; Now, remove checkin from PIMS files 2/44
135 N BSDXNOD S BSDXNOD=^BSDXAPPT(BSDXAPPTID,0)
136 N BSDXPATID S BSDXPATID=$P(BSDXNOD,U,5) ; DFN
137 N BSDXSTART S BSDXSTART=$P(BSDXNOD,U) ; Start Date
138 N BSDXSC1 S BSDXSC1=$P(BSDXNOD,U,7) ; Resource ID
139 ;
140 ; If the resource doesn't exist, error out. DB is corrupt.
141 I 'BSDXSC1 D ERR("-3~DB has corruption. Call Tech Support.") QUIT
142 I '$D(^BSDXRES(BSDXSC1,0)) D ERR("-4~DB has corruption. Call Tech Support.") QUIT
143 ;
144 N BSDXNOD S BSDXNOD=^BSDXRES(BSDXSC1,0) ; Resource 0 node
145 S BSDXSC1=$P(BSDXNOD,U,4) ;HOSPITAL LOCATION
146 ;
147 N BSDXZ ; Scratch variable to hold error message
148 I BSDXSC1]"",$D(^SC(BSDXSC1,0)) S BSDXZ=$$RMCI^BSDXAPI(BSDXPATID,BSDXSC1,BSDXSTART)
149 I +$G(BSDXZ) D ERR("-5~"_$P(BSDXZ,U,2)) QUIT
150 ;
151 TCOMMIT ; Save Data into Globals
152 ;
153 ; Return ADO recordset
154 S BSDXI=BSDXI+1
155 S ^BSDXTMP($J,BSDXI)="0"_$C(30)
156 S BSDXI=BSDXI+1
157 S ^BSDXTMP($J,BSDXI)=$C(31)
158 Q
159 ;
160CHKEVT(BSDXPAT,BSDXSTART,BSDXSC) ;EP Called by BSDX CHECKIN APPOINTMENT event
161 ;when appointments CHECKIN via PIMS interface.
162 ;Propagates CHECKIN to BSDXAPPT and raises refresh event to running GUI clients
163 ;
164 Q:+$G(BSDXNOEV)
165 Q:'+$G(BSDXSC)
166 N BSDXSTAT,BSDXFOUND,BSDXRES
167 S BSDXSTAT=""
168 S:$G(SDATA("AFTER","STATUS"))["CHECKED IN" BSDXSTAT=$P(SDATA("AFTER","STATUS"),"^",4)
169 S BSDXFOUND=0
170 I $D(^BSDXRES("ALOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ALOC",BSDXSC,0)) S BSDXFOUND=$$CHKEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT)
171 I BSDXFOUND D CHKEVT3(BSDXRES) Q
172 I $D(^BXDXRES("ASSOC",BSDXSC)) S BSDXRES=$O(^BSDXRES("ASSOC",BSDXSC,0)) S BSDXFOUND=$$CHKEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT)
173 I BSDXFOUND D CHKEVT3(BSDXRES)
174 Q
175 ;
176CHKEVT1(BSDXRES,BSDXSTART,BSDXPAT,BSDXSTAT) ;
177 ;Get appointment id in BSDXAPT
178 ;If found, call BSDXNOS(BSDXAPPT) and return 1
179 ;else return 0
180 N BSDXFOUND,BSDXAPPT
181 S BSDXFOUND=0
182 Q:'+$G(BSDXRES) BSDXFOUND
183 Q:'$D(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART)) BSDXFOUND
184 S BSDXAPPT=0 F S BSDXAPPT=$O(^BSDXAPPT("ARSRC",BSDXRES,BSDXSTART,BSDXAPPT)) Q:'+BSDXAPPT D Q:BSDXFOUND
185 . S BSDXNOD=$G(^BSDXAPPT(BSDXAPPT,0)) Q:BSDXNOD=""
186 . I $P(BSDXNOD,U,5)=BSDXPAT,$P(BSDXNOD,U,12)="" S BSDXFOUND=1 Q
187 I BSDXFOUND,+$G(BSDXAPPT) D BSDXCHK(BSDXAPPT,BSDXSTAT)
188 Q BSDXFOUND
189 ;
190CHKEVT3(BSDXRES) ;
191 ;Call RaiseEvent to notify GUI clients
192 ;
193 N BSDXRESN
194 S BSDXRESN=$G(^BSDXRES(BSDXRES,0))
195 Q:BSDXRESN=""
196 S BSDXRESN=$P(BSDXRESN,"^")
197 D EVENT^BMXMEVN("BSDX SCHEDULE",BSDXRESN)
198 Q
199 ;
200ERROR ;
201 S $ETRAP="D ^%ZTER HALT" ; Emergency Error Trap for the wise
202 ; Rollback, otherwise ^XTER will be empty from future rollback
203 I $TL>0 TROLLBACK
204 D ^%ZTER
205 S $EC="" ; Clear Error
206 ; Log error message and send to client
207 D ERR("-100~Mumps Error")
208 Q
209 ;
210ERR(BSDXERR) ;Error processing
211 I $TLEVEL>0 TROLLBACK
212 S BSDXERR=$G(BSDXERR)
213 S BSDXERR=$P(BSDXERR,"~")_"~"_$TEXT(+0)_":"_$P(BSDXERR,"~",2) ; Append Routine Name
214 S BSDXI=$G(BSDXI)+1
215 S ^BSDXTMP($J,BSDXI)=BSDXERR_$C(30)
216 S BSDXI=BSDXI+1
217 S ^BSDXTMP($J,BSDXI)=$C(31)
218 QUIT
Note: See TracBrowser for help on using the repository browser.