source: Scheduling/trunk/m/BSDXAPI.m@ 1034

Last change on this file since 1034 was 1034, checked in by Sam Habiel, 13 years ago

Refactoring of BSDX26; BSDXAPI has new ep to update note in file 44
File size: 12.4 KB
Line 
1BSDXAPI ; IHS/ANMC/LJF - SCHEDULING APIs ; 11/18/10 5:34pm
2 ;;1.42;BSDX;;Sep 29, 2010;Build 7
3 ;Orignal routine is BSDAPI by IHS/LJF, HMW, and MAW
4 ;local mods (many) by WV/SMH
5 ;Move to BSDX namespace as BSDXAPI from BSDAPI by WV/SMH
6 ; Change History:
7 ; - Fixed errors having to do uncanceling patient appointments if it was a patient cancelled appointment.
8 ; - Use new style Fileman API for storing appointments in file 44 in $$MAKE due to problems with legacy API.
9 ; 2010-11-12:
10 ; - Changed ="C" to ["C" in SCIEN. Cancelled appointments can be "PC" as well.
11 ; 2010-12-5
12 ; Added an entry point to update the patient note in file 44.
13 ;
14MAKE1(DFN,CLIN,TYP,DATE,LEN,INFO) ; Simplified PEP w/ parameters for $$MAKE - making appointment
15 ; Call like this for DFN 23435 having an appointment at Hospital Location 33
16 ; have 3 (scheduled) or 4 (walkin) appt at Dec 20, 2009 @ 10:11:59 for 30 minutes appt
17 ; for Baby foxes hallucinations.
18 ; S RESULT=$$MAKE1^BSDXAPI(23435,33,(3 or 4),3091220.221159,30,"I see Baby foxes")
19 S BSDR("PAT")=DFN ;DFN
20 S BSDR("CLN")=CLIN ;Hosp Loc IEN
21 S BSDR("TYP")=TYP ;3 sched or 4 walkin
22 S BSDR("ADT")=DATE ;Appointment date in FM format
23 S BSDR("LEN")=LEN ;Appt len upto 240 (min)
24 S BSDR("INFO")=INFO ;Reason for appt - up to 150 char
25 S BSDR("USR")=DUZ ;Person who made appt - current user
26 Q $$MAKE(.BSDR)
27 ;
28MAKE(BSDR) ;PEP; call to store appt made
29 ;
30 ; Make call using: S ERR=$$MAKE^BSDXAPI(.ARRAY)
31 ;
32 ; Input Array -
33 ; BSDR("PAT") = ien of patient in file 2
34 ; BSDR("CLN") = ien of clinic in file 44
35 ; BSDR("TYP") = 3 for scheduled appts, 4 for walkins
36 ; BSDR("ADT") = appointment date and time
37 ; BSDR("LEN") = appointment length in minutes (5-120)
38 ; BSDR("OI") = reason for appt - up to 150 characters
39 ; BSDR("USR") = user who made appt
40 ;
41 ;Output: error status and message
42 ; = 0 or null: everything okay
43 ; = 1^message: error and reason
44 ;
45 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
46 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
47 I ($G(BSDR("TYP"))<3)!($G(BSDR("TYP"))>4) Q 1_U_"Appt Type error: "_$G(BSDR("TYP"))
48 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
49 I $G(BSDR("ADT"))'?7N1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
50 ;
51 I ($G(BSDR("LEN"))<5)!($G(BSDR("LEN"))>240) Q 1_U_"Appt Length error: "_$G(BSDR("LEN"))
52 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Made Appt Error: "_$G(BSDR("USR"))
53 I $D(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0)),$P(^(0),U,2)'["C" Q 1_U_"Patient "_BSDR("PAT")_" already has appt at "_BSDR("ADT")
54 ;
55 NEW DIC,DA,Y,X,DD,DO,DLAYGO
56 ;
57 I $D(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0)),$P(^(0),U,2)["C" D
58 . ; "un-cancel" existing appt in file 2
59 . N BSDXFDA,BSDXIENS,BSDXMSG
60 . S BSDXIENS=BSDR("ADT")_","_BSDR("PAT")_","
61 . S BSDXFDA(2.98,BSDXIENS,".01")=BSDR("CLN")
62 . S BSDXFDA(2.98,BSDXIENS,"3")=""
63 . S BSDXFDA(2.98,BSDXIENS,"9")=BSDR("TYP")
64 . S BSDXFDA(2.98,BSDXIENS,"9.5")=9
65 . S BSDXFDA(2.98,BSDXIENS,"14")=""
66 . S BSDXFDA(2.98,BSDXIENS,"15")=""
67 . S BSDXFDA(2.98,BSDXIENS,"16")=""
68 . S BSDXFDA(2.98,BSDXIENS,"19")=""
69 . S BSDXFDA(2.98,BSDXIENS,"20")=$$NOW^XLFDT
70 . D FILE^DIE("","BSDXFDA","BSDXMSG")
71 . N BSDXTEMP S BSDXTEMP=$G(BSDXMSG)
72 E D I $G(BSDXERR(1)) Q 1_U_"FileMan add to DPT error: Patient="_BSDR("PAT")_" Appt="_BSDR("ADT")
73 . N BSDXFDA,BSDXIENS,BSDXMSG
74 . S BSDXIENS="?+2,"_BSDR("PAT")_","
75 . S BSDXIENS(2)=BSDR("ADT")
76 . S BSDXFDA(2.98,BSDXIENS,.01)=BSDR("CLN")
77 . S BSDXFDA(2.98,BSDXIENS,"9")=BSDR("TYP")
78 . S BSDXFDA(2.98,BSDXIENS,"9.5")=9
79 . S BSDXFDA(2.98,BSDXIENS,"20")=$$NOW^XLFDT
80 . D UPDATE^DIE("","BSDXFDA","BSDXIENS","BSDXERR(1)")
81 ; add appt to file 44
82 K DIC,DA,X,Y,DLAYGO,DD,DO
83 I '$D(^SC(BSDR("CLN"),"S",0)) S ^SC(BSDR("CLN"),"S",0)="^44.001DA^^"
84 I '$D(^SC(BSDR("CLN"),"S",BSDR("ADT"),0)) D I Y<1 Q 1_U_"Error adding date to file 44: Clinic="_BSDR("CLN")_" Date="_BSDR("ADT")
85 . S DIC="^SC("_BSDR("CLN")_",""S"",",DA(1)=BSDR("CLN"),(X,DINUM)=BSDR("ADT")
86 . S DIC("P")="44.001DA",DIC(0)="L",DLAYGO=44.001
87 . S Y=1 I '$D(@(DIC_X_")")) D FILE^DICN
88 ;
89 ; Sep 28 2010: Changed old style API to new style API. Keep for reference //smh
90 ;K DIC,DA,X,Y,DLAYGO,DD,DO,DINUM
91 ;S DIC="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
92 ;S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),X=BSDR("PAT")
93 ;S DIC("DR")="1///"_BSDR("LEN")_";3///"_$E($G(BSDR("OI")),1,150)_";7///`"_BSDR("USR")_";8///"_$P($$NOW^XLFDT,".")
94 ;S DIC("P")="44.003PA",DIC(0)="L",DLAYGO=44.003
95 ;D FILE^DICN
96 ;
97 N BSDXIENS S BSDXIENS="?+1,"_BSDR("ADT")_","_BSDR("CLN")_","
98 N BSDXFDA
99 S BSDXFDA(44.003,BSDXIENS,.01)=BSDR("PAT")
100 S BSDXFDA(44.003,BSDXIENS,1)=BSDR("LEN")
101 S BSDXFDA(44.003,BSDXIENS,3)=$E($G(BSDR("OI")),1,150)
102 S BSDXFDA(44.003,BSDXIENS,7)=BSDR("USR")
103 S BSDXFDA(44.003,BSDXIENS,8)=$P($$NOW^XLFDT,".")
104 N BSDXERR
105 D UPDATE^DIE("","BSDXFDA","","BSDXERR")
106 ;
107 I $D(BSDXERR) Q 1_U_"Error adding appt to file 44: Clinic="_BSDR("CLN")_" Date="_BSDR("ADT")_" Patient="_BSDR("PAT")_" Error: "_BSDXERR("DIERR",1,"TEXT",1)
108 ;
109 ; call event driver
110 NEW DFN,SDT,SDCL,SDDA,SDMODE
111 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2
112 S SDDA=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
113 D MAKE^SDAMEVT(DFN,SDT,SDCL,SDDA,SDMODE)
114 Q 0
115 ;
116CHECKIN1(DFN,CLIN,APDATE) ; Simplified PEP w/ parameters for $$CHECKIN - Checking in
117 ; Call like this for DFN 23435 checking in now at Hospital Location 33
118 ; for appt at Dec 20, 2009 @ 10:11:59
119 ; S RESULT=$$CHECKIN1^BSDXAPI(23435,33,3091220.221159)
120 S BSDR("PAT")=DFN ;DFN
121 S BSDR("CLN")=CLIN ;Hosp Loc IEN
122 S BSDR("ADT")=APDATE ;Appt Date
123 S BSDR("CDT")=$$NOW^XLFDT ;Check-in date defaults to now
124 S BSDR("USR")=DUZ ;Check-in user defaults to current
125 Q $$CHECKIN(.BSDR)
126 ;
127CHECKIN(BSDR) ;EP; call to add checkin info to appt; IHS/ITSC/LJF 12/23/2004 PATCH 1002
128 ;
129 ; Make call by using: S ERR=$$CHECKIN^BSDXAPI(.ARRAY)
130 ;
131 ; Input array -
132 ; BSDR("PAT") = ien of patient in file 2
133 ; BSDR("CLN") = ien of clinic in file 44
134 ; BSDR("ADT") = appt date/time
135 ; BSDR("CDT") = checkin date/time
136 ; BSDR("USR") = checkin user
137 ;
138 ; Output value -
139 ; = 0 means everything worked
140 ; = 1^message means error with reason message
141 ;
142 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
143 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
144 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
145 I $G(BSDR("ADT"))'?7N1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
146 I $G(BSDR("CDT")) S BSDR("CDT")=+$E(BSDR("CDT"),1,12) ;remove seconds
147 I $G(BSDR("CDT"))'?7N1".".4N Q 1_U_"Checkin Date/Time error: "_$G(BSDR("CDT"))
148 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Made Appt Error: "_$G(BSDR("USR"))
149 ;
150 ; find ien for appt in file 44
151 NEW IEN,DIE,DA,DR
152 S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
153 I 'IEN Q 1_U_"Error trying to find appointment for checkin: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
154 ;
155 ; remember before status
156 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL
157 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2,SDDA=IEN
158 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
159 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
160 ;
161 ; set checkin
162 S DIE="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
163 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
164 S DR="309///"_BSDR("CDT")_";302///`"_BSDR("USR")_";305///"_$$NOW^XLFDT
165 D ^DIE
166 ;
167 ; set after status
168 S SDDA=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
169 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
170 D AFTER^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
171 ;
172 ; call event driver
173 D EVT^SDAMEVT(.SDATA,4,SDMODE,SDCIHDL)
174 Q 0
175 ;
176CANCEL1(DFN,CLIN,TYP,APDATE,REASON,INFO) ; PEP w/ parameters for $$CANCEL - cancelling appointment
177 ; Call like this for DFN 23435 cancelling an appointment at Hospital Location 33,
178 ; cancellation initiated by patient ("PC" rather than clinic "C"),
179 ; cancelling appt at Dec 20, 2009 @ 10:11:59 because of reason 1 in file 409.2 IEN (weather)
180 ; because foxes come out during bad weather.
181 ; S RESULT=$$CANCEL1^BSDXAPI(23435,33,"PC",3091220.221159,1,"Afraid of foxes")
182 S BSDR("PAT")=DFN
183 S BSDR("CLN")=CLIN
184 S BSDR("TYP")=TYP
185 S BSDR("ADT")=APDATE
186 S BSDR("CDT")=$$NOW^XLFDT
187 S BSDR("USR")=DUZ
188 S BSDR("CR")=REASON
189 S BSDR("NOT")=INFO
190 Q $$CANCEL(.BSDR)
191 ;
192CANCEL(BSDR) ;PEP; called to cancel appt
193 ;
194 ; Make call using: S ERR=$$CANCEL^BSDXAPI(.ARRAY)
195 ;
196 ; Input Array -
197 ; BSDR("PAT") = ien of patient in file 2
198 ; BSDR("CLN") = ien of clinic in file 44
199 ; BSDR("TYP") = C for canceled by clinic; PC for patient canceled
200 ; BSDR("ADT") = appointment date and time
201 ; BSDR("CDT") = cancel date and time
202 ; BSDR("USR") = user who canceled appt
203 ; BSDR("CR") = cancel reason - pointer to file 409.2
204 ; BSDR("NOT") = cancel remarks - optional notes to 160 characters
205 ;
206 ;Output: error status and message
207 ; = 0 or null: everything okay
208 ; = 1^message: error and reason
209 ;
210 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
211 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
212 I ($G(BSDR("TYP"))'="C"),($G(BSDR("TYP"))'="PC") Q 1_U_"Cancel Status error: "_$G(BSDR("TYP"))
213 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
214 I $G(BSDR("ADT"))'?7N1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
215 I $G(BSDR("CDT")) S BSDR("CDT")=+$E(BSDR("CDT"),1,12) ;remove seconds
216 I $G(BSDR("CDT"))'?7N1".".4N Q 1_U_"Cancel Date/Time error: "_$G(BSDR("CDT"))
217 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Canceled Appt Error: "_$G(BSDR("USR"))
218 I '$D(^SD(409.2,+$G(BSDR("CR")))) Q 1_U_"Cancel Reason error: "_$G(BSDR("CR"))
219 ;
220 NEW IEN,DIE,DA,DR
221 S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
222 I 'IEN Q 1_U_"Error trying to find appointment for cancel: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
223 ;
224 I $$CI(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"),IEN) Q 1_U_"Patient already checked in; cannot cancel until checkin deleted: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
225 ;
226 ; remember before status
227 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCPHDL
228 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2,SDDA=IEN
229 S SDCPHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
230 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCPHDL)
231 ;
232 ; get user who made appt and date appt made from ^SC
233 ; because data in ^SC will be deleted
234 NEW USER,DATE
235 S USER=$P($G(^SC(SDCL,"S",SDT,1,IEN,0)),U,6)
236 S DATE=$P($G(^SC(SDCL,"S",SDT,1,IEN,0)),U,7)
237 ;
238 ; update file 2 info
239 NEW DIE,DA,DR
240 S DIE="^DPT("_DFN_",""S"",",DA(1)=DFN,DA=SDT
241 S DR="3///"_BSDR("TYP")_";14///`"_BSDR("USR")_";15///"_BSDR("CDT")_";16///`"_BSDR("CR")_";19///`"_USER_";20///"_DATE
242 S:$G(BSDR("NOT"))]"" DR=DR_";17///"_$E(BSDR("NOT"),1,160)
243 D ^DIE
244 ;
245 ; delete data in ^SC
246 NEW DIK,DA
247 S DIK="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
248 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
249 D ^DIK
250 ;
251 ; call event driver
252 D CANCEL^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDMODE,SDCPHDL)
253 Q 0
254 ;
255CI(PAT,CLINIC,DATE,SDIEN) ;PEP; -- returns 1 if appt already checked-in
256 NEW X
257 S X=$G(SDIEN) ;ien sent in call
258 I 'X S X=$$SCIEN(PAT,CLINIC,DATE) I 'X Q 0
259 S X=$P($G(^SC(CLINIC,"S",DATE,1,X,"C")),U)
260 Q $S(X:1,1:0)
261 ;
262SCIEN(PAT,CLINIC,DATE) ;PEP; returns ien for appt in ^SC
263 NEW X,IEN
264 S X=0 F S X=$O(^SC(CLINIC,"S",DATE,1,X)) Q:'X Q:$G(IEN) D
265 . Q:$P($G(^SC(CLINIC,"S",DATE,1,X,0)),U,9)["C" ;cancelled
266 . I +$G(^SC(CLINIC,"S",DATE,1,X,0))=PAT S IEN=X
267 Q $G(IEN)
268 ;
269APPTYP(PAT,DATE) ;PEP; -- returns type of appt (scheduled or walk-in)
270 NEW X S X=$P($G(^DPT(PAT,"S",DATE,0)),U,7)
271 Q $S(X=3:"SCHED",X=4:"WALK-IN",1:"??")
272 ;
273CO(PAT,CLINIC,DATE,SDIEN) ;PEP; -- returns 1 if appt already checked-out
274 NEW X
275 S X=$G(SDIEN) ;ien sent in call
276 I 'X S X=$$SCIEN(PAT,CLINIC,DATE) I 'X Q 0
277 S X=$P($G(^SC(CLINIC,"S",DATE,1,X,"C")),U,3)
278 Q $S(X:1,1:0)
279 ;
280UPDATENOTE(PAT,CLINIC,DATE,NOTE) ; PEP; Update Note in ^SC for patient's appointment @ DATE
281 ; PAT = DFN
282 ; CLINIC = SC IEN
283 ; DATE = FM Date/Time of Appointment
284 ;
285 ; Returns:
286 ; 0 if okay
287 ; -1 if failure
288 N SCIEN S SCIEN=$$SCIEN(PAT,CLINIC,DATE) ; ien of appt in ^SC
289 I SCIEN<1 QUIT "-1~No Appt can be found in file 44 for Patient "_PAT_" on "_DATE_" in clinic "_CLINIC
290 N BSDXIENS S BSDXIENS=SCIEN_","_DATE_","_CLINIC_","
291 S BSDXFDA(44.003,BSDXIENS,3)=$E(NOTE,1,150)
292 N BSDXERR
293 D FILE^DIE("","BSDXFDA","BSDXERR")
294 I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
295 QUIT 0
Note: See TracBrowser for help on using the repository browser.