source: Scheduling/trunk/m/BSDXAPI.m@ 1452

Last change on this file since 1452 was 1452, checked in by Sam Habiel, 12 years ago

done with BSDX07
File size: 17.8 KB
Line 
1BSDXAPI ; IHS/ANMC/LJF & VW/SMH - SCHEDULING APIs ; 6/20/12 12:40pm
2 ;;1.7T1;BSDX;;Aug 31, 2011;Build 18
3 ; Licensed under LGPL
4 ;
5 ;Orignal routine is BSDAPI by IHS/LJF, HMW, and MAW
6 ; mods (many) by WV/SMH
7 ;Move to BSDX namespace as BSDXAPI from BSDAPI by WV/SMH
8 ; Change History:
9 ; 2010-11-5: (1.42)
10 ; - Fixed errors having to do uncanceling patient appointments if it was a patient cancelled appointment.
11 ; - Use new style Fileman API for storing appointments in file 44 in $$MAKE due to problems with legacy API.
12 ; 2010-11-12: (1.42)
13 ; - Changed ="C" to ["C" in SCIEN. Cancelled appointments can be "PC" as well.
14 ; 2010-12-5 (1.42)
15 ; Added an entry point to update the patient note in file 44.
16 ; 2010-12-6 (1.42)
17 ; MAKE1 incorrectly put info field in BSDR("INFO") rather than BSDR("OI")
18 ; 2010-12-8 (1.42)
19 ; Removed restriction on max appt length. Even though this restriction
20 ; exists in fileman (120 minutes), PIMS ignores it. Therefore, I
21 ; will ignore it here too.
22 ; 2011-01-25 (v.1.5)
23 ; Added entry point $$RMCI to remove checked in appointments.
24 ; In $$CANCEL, if the appointment is checked in, delete check-in rather than
25 ; spitting an error message to the user saying 'Delete the check-in'
26 ; Changed all lines that look like this:
27 ; I $G(BSDR("ADT"))'?7N1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
28 ; to:
29 ; I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
30 ; to allow for date at midnight which does not have a dot at the end.
31 ; 2011-01-26 (v.1.5)
32 ; More user friendly message if patient already has appointment in $$MAKE:
33 ; Spits out pt name and user friendly date.
34 ; 2012-06-18 (v 1.7)
35 ; Removing transacions. Means that code SHOULD NOT fail. Took all checks
36 ; out for making an appointment to MAKECK. We call this first to make sure
37 ; that the appointment is okay to make before committing to make it. We
38 ; still have the provision to delete the data though if we fail when we
39 ; actually make the appointment
40 ;
41MAKE1(DFN,CLIN,TYP,DATE,LEN,INFO) ; Simplified PEP w/ parameters for $$MAKE - making appointment
42 ; Call like this for DFN 23435 having an appointment at Hospital Location 33
43 ; have 3 (scheduled) or 4 (walkin) appt at Dec 20, 2009 @ 10:11:59 for 30 minutes appt
44 ; for Baby foxes hallucinations.
45 ; S RESULT=$$MAKE1^BSDXAPI(23435,33,(3 or 4),3091220.221159,30,"I see Baby foxes")
46 S BSDR("PAT")=DFN ;DFN
47 S BSDR("CLN")=CLIN ;Hosp Loc IEN
48 S BSDR("TYP")=TYP ;3 sched or 4 walkin
49 S BSDR("ADT")=DATE ;Appointment date in FM format
50 S BSDR("LEN")=LEN ;Appt len upto 240 (min)
51 S BSDR("OI")=INFO ;Reason for appt - up to 150 char
52 S BSDR("USR")=DUZ ;Person who made appt - current user
53 Q $$MAKE(.BSDR)
54 ;
55MAKE(BSDR) ;PEP; call to store appt made
56 ;
57 ; Make call using: S ERR=$$MAKE^BSDXAPI(.ARRAY)
58 ;
59 ; Input Array -
60 ; BSDR("PAT") = ien of patient in file 2
61 ; BSDR("CLN") = ien of clinic in file 44
62 ; BSDR("TYP") = 3 for scheduled appts, 4 for walkins
63 ; BSDR("ADT") = appointment date and time
64 ; BSDR("LEN") = appointment length in minutes (*1.42 limit removed)
65 ; BSDR("OI") = reason for appt - up to 150 characters
66 ; BSDR("USR") = user who made appt
67 ;
68 ;Output: error status and message
69 ; = 0 or null: everything okay
70 ; = 1^message: error and reason
71 ;
72 N BSDXMKCK S BSDXMKCK=$$MAKECK(.BSDR) ; Check if we can make appointment
73 I BSDXMKCK Q BSDXMKCK ; If we can't, quit with the reason why.
74 ;
75 ;Otherwise, we continue
76 ;
77 N BSDXFDA,BSDXIENS,BSDXMSG ; FILE/UPDATE^DIE variables
78 ;
79 I $D(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0)),$P(^(0),U,2)["C" D
80 . ; "un-cancel" existing appt in file 2
81 . S BSDXIENS=BSDR("ADT")_","_BSDR("PAT")_","
82 . S BSDXFDA(2.98,BSDXIENS,".01")=BSDR("CLN")
83 . S BSDXFDA(2.98,BSDXIENS,"3")=""
84 . S BSDXFDA(2.98,BSDXIENS,"9")=BSDR("TYP")
85 . S BSDXFDA(2.98,BSDXIENS,"9.5")=9
86 . S BSDXFDA(2.98,BSDXIENS,"14")=""
87 . S BSDXFDA(2.98,BSDXIENS,"15")=""
88 . S BSDXFDA(2.98,BSDXIENS,"16")=""
89 . S BSDXFDA(2.98,BSDXIENS,"17")="@" ; v 1.7; cancellation remarks were left over
90 . S BSDXFDA(2.98,BSDXIENS,"19")=""
91 . S BSDXFDA(2.98,BSDXIENS,"20")=$$NOW^XLFDT
92 . D FILE^DIE("","BSDXFDA","BSDXMSG")
93 Q:$D(BSDXMSG) 1_U_"Fileman edit to DPT error: Patient="_BSDR("PAT")_" Appt="_BSDR("ADT")_" Error="_BSDXMSG("DIERR",1,"TEXT",1)
94 ;
95 Q:$G(BSDXSIMERR2) 1_U_$NA(BSDXSIMERR2) ; Unit Test line
96 ;
97 E D ; File new appointment/edit existing appointment in file 2
98 . S BSDXIENS="?+2,"_BSDR("PAT")_","
99 . S BSDXIENS(2)=BSDR("ADT")
100 . S BSDXFDA(2.98,BSDXIENS,.01)=BSDR("CLN")
101 . S BSDXFDA(2.98,BSDXIENS,"9")=BSDR("TYP")
102 . S BSDXFDA(2.98,BSDXIENS,"9.5")=9
103 . S BSDXFDA(2.98,BSDXIENS,"20")=$$NOW^XLFDT
104 . D UPDATE^DIE("","BSDXFDA","BSDXIENS","BSDXMSG")
105 Q:$D(BSDXMSG) 1_U_"FileMan add to DPT error: Patient="_BSDR("PAT")_" Appt="_BSDR("ADT")_" Error="_BSDXMSG("DIERR",1,"TEXT",1)
106 ;
107 Q:$G(BSDXSIMERR3) 1_U_$NA(BSDXSIMERR3) ; Unit Test line
108 ;
109 ; add appt to file 44. This adds it to the FIRST subfile (Appointment)
110 N DIC,DA,Y,X,DD,DO,DLAYGO
111 I '$D(^SC(BSDR("CLN"),"S",0)) S ^SC(BSDR("CLN"),"S",0)="^44.001DA^^"
112 I '$D(^SC(BSDR("CLN"),"S",BSDR("ADT"),0)) D I Y<1 Q 1_U_"Error adding date to file 44: Clinic="_BSDR("CLN")_" Date="_BSDR("ADT")
113 . S DIC="^SC("_BSDR("CLN")_",""S"",",DA(1)=BSDR("CLN"),(X,DINUM)=BSDR("ADT")
114 . S DIC("P")="44.001DA",DIC(0)="L",DLAYGO=44.001
115 . S Y=1 I '$D(@(DIC_X_")")) D FILE^DICN
116 ;
117 Q:$G(BSDXSIMERR4) 1_U_$NA(BSDXSIMERR4) ; Unit Test line
118 ;
119 ; add appt for file 44, second subfile (Appointment/Patient)
120 ; Sep 28 2010: Changed old style API to new style API. Keep for reference //smh
121 ;K DIC,DA,X,Y,DLAYGO,DD,DO,DINUM
122 ;S DIC="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
123 ;S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),X=BSDR("PAT")
124 ;S DIC("DR")="1///"_BSDR("LEN")_";3///"_$E($G(BSDR("OI")),1,150)_";7///`"_BSDR("USR")_";8///"_$P($$NOW^XLFDT,".")
125 ;S DIC("P")="44.003PA",DIC(0)="L",DLAYGO=44.003
126 ;D FILE^DICN
127 ;
128 N BSDXIENS S BSDXIENS="?+1,"_BSDR("ADT")_","_BSDR("CLN")_","
129 N BSDXFDA
130 S BSDXFDA(44.003,BSDXIENS,.01)=BSDR("PAT")
131 S BSDXFDA(44.003,BSDXIENS,1)=BSDR("LEN")
132 S BSDXFDA(44.003,BSDXIENS,3)=$E($G(BSDR("OI")),1,150)
133 S BSDXFDA(44.003,BSDXIENS,7)=BSDR("USR")
134 S BSDXFDA(44.003,BSDXIENS,8)=$P($$NOW^XLFDT,".")
135 N BSDXERR
136 D UPDATE^DIE("","BSDXFDA","","BSDXERR")
137 ;
138 I $D(BSDXERR) Q 1_U_"Error adding appt to file 44: Clinic="_BSDR("CLN")_" Date="_BSDR("ADT")_" Patient="_BSDR("PAT")_" Error: "_BSDXERR("DIERR",1,"TEXT",1)
139 ;
140 ;Q:$G(BSDXSIMERR5) 1_U_$NA(BSDXSIMERR5) ; Unit Test line
141 S:$G(BSDXSIMERR5) X=1/0
142 ;
143 ; call event driver
144 NEW DFN,SDT,SDCL,SDDA,SDMODE
145 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2
146 S SDDA=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
147 D MAKE^SDAMEVT(DFN,SDT,SDCL,SDDA,SDMODE)
148 Q 0
149 ;
150MAKECK(BSDR) ; $$ - Is it okay to make an appointment? ; PEP
151 ; Input: Same as $$MAKE
152 ; Output: 1^error or 0 for success
153 ; NB: This subroutine saves no data. Only checks whether it's okay.
154 ;
155 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
156 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
157 I ($G(BSDR("TYP"))<3)!($G(BSDR("TYP"))>4) Q 1_U_"Appt Type error: "_$G(BSDR("TYP"))
158 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
159 I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
160 ;
161 ; Appt Length check removed in v 1.5
162 ;
163 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Made Appt Error: "_$G(BSDR("USR"))
164 ; More verbose error message in v1.5
165 ; Following block to give an error message to user if there is already an appointment for patient. More verbose than others.
166 N BSDXERR ; place to store error message
167 I $D(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0)),$P(^(0),U,2)'["C" DO QUIT BSDXERR ; If there's an appt in the "S" node of file 2 and it's not cancelled
168 . S BSDXERR=1_U_"Patient "_$P(^DPT(BSDR("PAT"),0),U)_" ("_BSDR("PAT")_") "
169 . S BSDXERR=BSDXERR_"already has appt at "_$$FMTE^XLFDT(BSDR("ADT"))
170 . N BSDXSCIEN S BSDXSCIEN=$P(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0),U) ; Clinic IEN in ^SC (0 piece of 0 node of "S" multiple in file 2)
171 . N BSDXSCNAM S BSDXSCNAM=$P(^SC(BSDXSCIEN,0),U) ; PIMS Name of Clinic
172 . S BSDXERR=BSDXERR_$C(13,10)_"PIMS clinic: "_BSDXSCNAM ; tell the user of the PIMS clinic
173 . I $D(^BSDXRES("ALOC",BSDXSCIEN)) DO ; if the Clinic is linked to a BSDX Resource (we find out using the index ALOC in the BSDX RESOURCE file)
174 . . N BSDXRESIEN S BSDXRESIEN=$O(^BSDXRES("ALOC",BSDXSCIEN,""))
175 . . QUIT:'BSDXRESIEN ; Safeguard if index is corrupt
176 . . N BSDXRESNAM S BSDXRESNAM=$P(^BSDXRES(BSDXRESIEN,0),U)
177 . . S BSDXERR=BSDXERR_$C(13,10)_"Scheduling GUI clinic: "_BSDXRESNAM ; tell the user of the BSDX clinic
178 Q 0
179 ;
180UNMAKE(BSDR) ; Reverse Make - Private $$
181 ; Only used in Emergiencies where Fileman data filing fails.
182 ; If previous data exists, which caused an error, it's destroyed.
183 ; NB: ^DIK stops for nobody
184 ; Input: Same array as $$MAKE
185 ; Output: Always 0
186 NEW DIK,DA
187 S DIK="^DPT("_BSDR("PAT")_",""S"","
188 S DA(1)=BSDR("PAT"),DA=BSDR("ADT")
189 D ^DIK
190 ;
191 N IEN S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
192 I 'IEN QUIT 0
193 ;
194 NEW DIK,DA
195 S DIK="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
196 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
197 D ^DIK
198 QUIT 0
199 ;
200CHECKIN1(DFN,CLIN,APDATE) ; Simplified PEP w/ parameters for $$CHECKIN - Checking in
201 ; Call like this for DFN 23435 checking in now at Hospital Location 33
202 ; for appt at Dec 20, 2009 @ 10:11:59
203 ; S RESULT=$$CHECKIN1^BSDXAPI(23435,33,3091220.221159)
204 S BSDR("PAT")=DFN ;DFN
205 S BSDR("CLN")=CLIN ;Hosp Loc IEN
206 S BSDR("ADT")=APDATE ;Appt Date
207 S BSDR("CDT")=$$NOW^XLFDT ;Check-in date defaults to now
208 S BSDR("USR")=DUZ ;Check-in user defaults to current
209 Q $$CHECKIN(.BSDR)
210 ;
211CHECKIN(BSDR) ;EP; call to add checkin info to appt; IHS/ITSC/LJF 12/23/2004 PATCH 1002
212 ;
213 ; Make call by using: S ERR=$$CHECKIN^BSDXAPI(.ARRAY)
214 ;
215 ; Input array -
216 ; BSDR("PAT") = ien of patient in file 2
217 ; BSDR("CLN") = ien of clinic in file 44
218 ; BSDR("ADT") = appt date/time
219 ; BSDR("CDT") = checkin date/time
220 ; BSDR("USR") = checkin user
221 ;
222 ; Output value -
223 ; = 0 means everything worked
224 ; = 1^message means error with reason message
225 ;
226 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
227 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
228 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
229 I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
230 I $G(BSDR("CDT")) S BSDR("CDT")=+$E(BSDR("CDT"),1,12) ;remove seconds
231 I $G(BSDR("CDT"))'?7N.1".".4N Q 1_U_"Checkin Date/Time error: "_$G(BSDR("CDT"))
232 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Made Appt Error: "_$G(BSDR("USR"))
233 ;
234 ; find ien for appt in file 44
235 NEW IEN,DIE,DA,DR
236 S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
237 I 'IEN Q 1_U_"Error trying to find appointment for checkin: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
238 ;
239 ; remember before status
240 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL
241 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2,SDDA=IEN
242 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
243 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
244 ;
245 ; set checkin
246 S DIE="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
247 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
248 S DR="309///"_BSDR("CDT")_";302///`"_BSDR("USR")_";305///"_$$NOW^XLFDT
249 D ^DIE
250 ;
251 ; set after status
252 S SDDA=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
253 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
254 D AFTER^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
255 ;
256 ; call event driver
257 D EVT^SDAMEVT(.SDATA,4,SDMODE,SDCIHDL)
258 Q 0
259 ;
260CANCEL1(DFN,CLIN,TYP,APDATE,REASON,INFO) ; PEP w/ parameters for $$CANCEL - cancelling appointment
261 ; Call like this for DFN 23435 cancelling an appointment at Hospital Location 33,
262 ; cancellation initiated by patient ("PC" rather than clinic "C"),
263 ; cancelling appt at Dec 20, 2009 @ 10:11:59 because of reason 1 in file 409.2 IEN (weather)
264 ; because foxes come out during bad weather.
265 ; S RESULT=$$CANCEL1^BSDXAPI(23435,33,"PC",3091220.221159,1,"Afraid of foxes")
266 S BSDR("PAT")=DFN
267 S BSDR("CLN")=CLIN
268 S BSDR("TYP")=TYP
269 S BSDR("ADT")=APDATE
270 S BSDR("CDT")=$$NOW^XLFDT
271 S BSDR("USR")=DUZ
272 S BSDR("CR")=REASON
273 S BSDR("NOT")=INFO
274 Q $$CANCEL(.BSDR)
275 ;
276CANCEL(BSDR) ;PEP; called to cancel appt
277 ;
278 ; Make call using: S ERR=$$CANCEL^BSDXAPI(.ARRAY)
279 ;
280 ; Input Array -
281 ; BSDR("PAT") = ien of patient in file 2
282 ; BSDR("CLN") = ien of clinic in file 44
283 ; BSDR("TYP") = C for canceled by clinic; PC for patient canceled
284 ; BSDR("ADT") = appointment date and time
285 ; BSDR("CDT") = cancel date and time
286 ; BSDR("USR") = user who canceled appt
287 ; BSDR("CR") = cancel reason - pointer to file 409.2
288 ; BSDR("NOT") = cancel remarks - optional notes to 160 characters
289 ;
290 ;Output: error status and message
291 ; = 0 or null: everything okay
292 ; = 1^message: error and reason
293 ;
294 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
295 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
296 I ($G(BSDR("TYP"))'="C"),($G(BSDR("TYP"))'="PC") Q 1_U_"Cancel Status error: "_$G(BSDR("TYP"))
297 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
298 I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
299 I $G(BSDR("CDT")) S BSDR("CDT")=+$E(BSDR("CDT"),1,12) ;remove seconds
300 I $G(BSDR("CDT"))'?7N.1".".4N Q 1_U_"Cancel Date/Time error: "_$G(BSDR("CDT"))
301 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Canceled Appt Error: "_$G(BSDR("USR"))
302 I '$D(^SD(409.2,+$G(BSDR("CR")))) Q 1_U_"Cancel Reason error: "_$G(BSDR("CR"))
303 ;
304 NEW IEN,DIE,DA,DR
305 S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
306 I 'IEN Q 1_U_"Error trying to find appointment for cancel: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
307 ;
308 ; BSDX 1.5 3110125
309 ; UJO/SMH - Add ability to remove check-in if the patient is checked in
310 ; I $$CI(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"),IEN) Q 1_U_"Patient already checked in; cannot cancel until checkin deleted: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
311 ; Remove check-in if the patient is checked in.
312 N BSDXRESULT S BSDXRESULT=0 ; Result; should be zero if success; -1 + message if failure
313 I $$CI(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"),IEN) SET BSDXRESULT=$$RMCI(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
314 I BSDXRESULT Q BSDXRESULT
315 ;
316 ; remember before status
317 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCPHDL
318 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2,SDDA=IEN
319 S SDCPHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
320 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCPHDL)
321 ;
322 ; get user who made appt and date appt made from ^SC
323 ; because data in ^SC will be deleted
324 NEW USER,DATE
325 S USER=$P($G(^SC(SDCL,"S",SDT,1,IEN,0)),U,6)
326 S DATE=$P($G(^SC(SDCL,"S",SDT,1,IEN,0)),U,7)
327 ;
328 ; update file 2 info
329 NEW DIE,DA,DR
330 S DIE="^DPT("_DFN_",""S"",",DA(1)=DFN,DA=SDT
331 S DR="3///"_BSDR("TYP")_";14///`"_BSDR("USR")_";15///"_BSDR("CDT")_";16///`"_BSDR("CR")_";19///`"_USER_";20///"_DATE
332 S:$G(BSDR("NOT"))]"" DR=DR_";17///"_$E(BSDR("NOT"),1,160)
333 D ^DIE
334 ;
335 ; delete data in ^SC
336 NEW DIK,DA
337 S DIK="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
338 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
339 D ^DIK
340 ;
341 ; call event driver
342 D CANCEL^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDMODE,SDCPHDL)
343 Q 0
344 ;
345CI(PAT,CLINIC,DATE,SDIEN) ;PEP; -- returns 1 if appt already checked-in
346 NEW X
347 S X=$G(SDIEN) ;ien sent in call
348 I 'X S X=$$SCIEN(PAT,CLINIC,DATE) I 'X Q 0
349 S X=$P($G(^SC(CLINIC,"S",DATE,1,X,"C")),U)
350 Q $S(X:1,1:0)
351 ;
352RMCI(PAT,CLINIC,DATE) ;PEP; -- Remove Check-in; $$
353 ; PAT = DFN
354 ; CLINIC = SC IEN
355 ; DATE = FM Date/Time of Appointment
356 ;
357 ; Returns:
358 ; 0 if okay
359 ; -1 if failure
360 ;
361 ; Call like this: $$RMCI(233,33,3110102.1130)
362 ;
363 ; Move my variables into the ones used by SDAPIs (just a convenience)
364 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL
365 S DFN=PAT,SDT=DATE,SDCL=CLINIC,SDMODE=2,SDDA=$$SCIEN(DFN,SDCL,SDT)
366 ;
367 I SDDA<1 QUIT 0 ; Appt cancelled; cancelled appts rm'ed from file 44
368 ;
369 ; remember before status
370 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
371 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
372 ;
373 ; remove check-in using filer.
374 N BSDXIENS S BSDXIENS=SDDA_","_DATE_","_CLINIC_","
375 S BSDXFDA(44.003,BSDXIENS,309)="@" ; CHECKED-IN
376 S BSDXFDA(44.003,BSDXIENS,302)="@" ; CHECK IN USER
377 S BSDXFDA(44.003,BSDXIENS,305)="@" ; CHECK IN ENTERED
378 N BSDXERR
379 D FILE^DIE("","BSDXFDA","BSDXERR")
380 I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
381 ;
382 ; set after status
383 S SDDA=$$SCIEN(DFN,SDCL,SDT)
384 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
385 D AFTER^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
386 ;
387 ; call event driver
388 D EVT^SDAMEVT(.SDATA,4,SDMODE,SDCIHDL)
389 QUIT 0
390 ;
391SCIEN(PAT,CLINIC,DATE) ;PEP; returns ien for appt in ^SC
392 NEW X,IEN
393 S X=0 F S X=$O(^SC(CLINIC,"S",DATE,1,X)) Q:'X Q:$G(IEN) D
394 . Q:$P($G(^SC(CLINIC,"S",DATE,1,X,0)),U,9)["C" ;cancelled
395 . I +$G(^SC(CLINIC,"S",DATE,1,X,0))=PAT S IEN=X
396 Q $G(IEN)
397 ;
398APPTYP(PAT,DATE) ;PEP; -- returns type of appt (scheduled or walk-in)
399 NEW X S X=$P($G(^DPT(PAT,"S",DATE,0)),U,7)
400 Q $S(X=3:"SCHED",X=4:"WALK-IN",1:"??")
401 ;
402CO(PAT,CLINIC,DATE,SDIEN) ;PEP; -- returns 1 if appt already checked-out
403 NEW X
404 S X=$G(SDIEN) ;ien sent in call
405 I 'X S X=$$SCIEN(PAT,CLINIC,DATE) I 'X Q 0
406 S X=$P($G(^SC(CLINIC,"S",DATE,1,X,"C")),U,3)
407 Q $S(X:1,1:0)
408 ;
409UPDATENT(PAT,CLINIC,DATE,NOTE) ; PEP; Update Note in ^SC for patient's appointment @ DATE
410 ; PAT = DFN
411 ; CLINIC = SC IEN
412 ; DATE = FM Date/Time of Appointment
413 ;
414 ; Returns:
415 ; 0 if okay
416 ; -1 if failure
417 N SCIEN S SCIEN=$$SCIEN(PAT,CLINIC,DATE) ; ien of appt in ^SC
418 I SCIEN<1 QUIT 0 ; Appt cancelled; cancelled appts rm'ed from file 44
419 N BSDXIENS S BSDXIENS=SCIEN_","_DATE_","_CLINIC_","
420 S BSDXFDA(44.003,BSDXIENS,3)=$E(NOTE,1,150)
421 N BSDXERR
422 D FILE^DIE("","BSDXFDA","BSDXERR")
423 I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
424 QUIT 0
Note: See TracBrowser for help on using the repository browser.