source: Scheduling/trunk/m/BSDXAPI.m@ 1460

Last change on this file since 1460 was 1460, checked in by Sam Habiel, 12 years ago

refactored BSDX26; still working on BSDX08
File size: 18.9 KB
Line 
1BSDXAPI ; IHS/ANMC/LJF & VW/SMH - SCHEDULING APIs ; 6/25/12 6:13pm
2 ;;1.7T1;BSDX;;Aug 31, 2011;Build 18
3 ; Licensed under LGPL
4 ;
5 ;Orignal routine is BSDAPI by IHS/LJF, HMW, and MAW
6 ; mods (many) by WV/SMH
7 ;Move to BSDX namespace as BSDXAPI from BSDAPI by WV/SMH
8 ; Change History:
9 ; 2010-11-5: (1.42)
10 ; - Fixed errors having to do uncanceling patient appointments if it was a patient cancelled appointment.
11 ; - Use new style Fileman API for storing appointments in file 44 in $$MAKE due to problems with legacy API.
12 ; 2010-11-12: (1.42)
13 ; - Changed ="C" to ["C" in SCIEN. Cancelled appointments can be "PC" as well.
14 ; 2010-12-5 (1.42)
15 ; Added an entry point to update the patient note in file 44.
16 ; 2010-12-6 (1.42)
17 ; MAKE1 incorrectly put info field in BSDR("INFO") rather than BSDR("OI")
18 ; 2010-12-8 (1.42)
19 ; Removed restriction on max appt length. Even though this restriction
20 ; exists in fileman (120 minutes), PIMS ignores it. Therefore, I
21 ; will ignore it here too.
22 ; 2011-01-25 (v.1.5)
23 ; Added entry point $$RMCI to remove checked in appointments.
24 ; In $$CANCEL, if the appointment is checked in, delete check-in rather than
25 ; spitting an error message to the user saying 'Delete the check-in'
26 ; Changed all lines that look like this:
27 ; I $G(BSDR("ADT"))'?7N1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
28 ; to:
29 ; I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
30 ; to allow for date at midnight which does not have a dot at the end.
31 ; 2011-01-26 (v.1.5)
32 ; More user friendly message if patient already has appointment in $$MAKE:
33 ; Spits out pt name and user friendly date.
34 ; 2012-06-18 (v 1.7)
35 ; Removing transacions. Means that code SHOULD NOT fail. Took all checks
36 ; out for making an appointment to MAKECK. We call this first to make sure
37 ; that the appointment is okay to make before committing to make it. We
38 ; still have the provision to delete the data though if we fail when we
39 ; actually make the appointment
40 ;
41MAKE1(DFN,CLIN,TYP,DATE,LEN,INFO) ; Simplified PEP w/ parameters for $$MAKE - making appointment
42 ; Call like this for DFN 23435 having an appointment at Hospital Location 33
43 ; have 3 (scheduled) or 4 (walkin) appt at Dec 20, 2009 @ 10:11:59 for 30 minutes appt
44 ; for Baby foxes hallucinations.
45 ; S RESULT=$$MAKE1^BSDXAPI(23435,33,(3 or 4),3091220.221159,30,"I see Baby foxes")
46 N BSDR
47 S BSDR("PAT")=DFN ;DFN
48 S BSDR("CLN")=CLIN ;Hosp Loc IEN
49 S BSDR("TYP")=TYP ;3 sched or 4 walkin
50 S BSDR("ADT")=DATE ;Appointment date in FM format
51 S BSDR("LEN")=LEN ;Appt len upto 240 (min)
52 S BSDR("OI")=INFO ;Reason for appt - up to 150 char
53 S BSDR("USR")=DUZ ;Person who made appt - current user
54 Q $$MAKE(.BSDR)
55 ;
56MAKE(BSDR) ;PEP; call to store appt made
57 ;
58 ; Make call using: S ERR=$$MAKE^BSDXAPI(.ARRAY)
59 ;
60 ; Input Array -
61 ; BSDR("PAT") = ien of patient in file 2
62 ; BSDR("CLN") = ien of clinic in file 44
63 ; BSDR("TYP") = 3 for scheduled appts, 4 for walkins
64 ; BSDR("ADT") = appointment date and time
65 ; BSDR("LEN") = appointment length in minutes (*1.42 limit removed)
66 ; BSDR("OI") = reason for appt - up to 150 characters
67 ; BSDR("USR") = user who made appt
68 ;
69 ;Output: error status and message
70 ; = 0 or null: everything okay
71 ; = 1^message: error and reason
72 ;
73 N BSDXMKCK S BSDXMKCK=$$MAKECK(.BSDR) ; Check if we can make appointment
74 I BSDXMKCK Q BSDXMKCK ; If we can't, quit with the reason why.
75 ;
76 ;Otherwise, we continue
77 ;
78 N BSDXFDA,BSDXIENS,BSDXMSG ; FILE/UPDATE^DIE variables
79 ;
80 I $D(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0)),$P(^(0),U,2)["C" D
81 . ; "un-cancel" existing appt in file 2
82 . S BSDXIENS=BSDR("ADT")_","_BSDR("PAT")_","
83 . S BSDXFDA(2.98,BSDXIENS,".01")=BSDR("CLN")
84 . S BSDXFDA(2.98,BSDXIENS,"3")=""
85 . S BSDXFDA(2.98,BSDXIENS,"9")=BSDR("TYP")
86 . S BSDXFDA(2.98,BSDXIENS,"9.5")=9
87 . S BSDXFDA(2.98,BSDXIENS,"14")=""
88 . S BSDXFDA(2.98,BSDXIENS,"15")=""
89 . S BSDXFDA(2.98,BSDXIENS,"16")=""
90 . S BSDXFDA(2.98,BSDXIENS,"17")="@" ; v 1.7; cancellation remarks were left over
91 . S BSDXFDA(2.98,BSDXIENS,"19")=""
92 . S BSDXFDA(2.98,BSDXIENS,"20")=$$NOW^XLFDT
93 . D FILE^DIE("","BSDXFDA","BSDXMSG")
94 Q:$D(BSDXMSG) 1_U_"Fileman edit to DPT error: Patient="_BSDR("PAT")_" Appt="_BSDR("ADT")_" Error="_BSDXMSG("DIERR",1,"TEXT",1)
95 ;
96 Q:$G(BSDXSIMERR2) 1_U_$NA(BSDXSIMERR2) ; Unit Test line
97 ;
98 E D ; File new appointment/edit existing appointment in file 2
99 . S BSDXIENS="?+2,"_BSDR("PAT")_","
100 . S BSDXIENS(2)=BSDR("ADT")
101 . S BSDXFDA(2.98,BSDXIENS,.01)=BSDR("CLN")
102 . S BSDXFDA(2.98,BSDXIENS,"9")=BSDR("TYP")
103 . S BSDXFDA(2.98,BSDXIENS,"9.5")=9
104 . S BSDXFDA(2.98,BSDXIENS,"20")=$$NOW^XLFDT
105 . D UPDATE^DIE("","BSDXFDA","BSDXIENS","BSDXMSG")
106 Q:$D(BSDXMSG) 1_U_"FileMan add to DPT error: Patient="_BSDR("PAT")_" Appt="_BSDR("ADT")_" Error="_BSDXMSG("DIERR",1,"TEXT",1)
107 ;
108 Q:$G(BSDXSIMERR3) 1_U_$NA(BSDXSIMERR3) ; Unit Test line
109 ;
110 ; add appt to file 44. This adds it to the FIRST subfile (Appointment)
111 N DIC,DA,Y,X,DD,DO,DLAYGO,DINUM
112 I '$D(^SC(BSDR("CLN"),"S",0)) S ^SC(BSDR("CLN"),"S",0)="^44.001DA^^"
113 I '$D(^SC(BSDR("CLN"),"S",BSDR("ADT"),0)) D I Y<1 Q 1_U_"Error adding date to file 44: Clinic="_BSDR("CLN")_" Date="_BSDR("ADT")
114 . S DIC="^SC("_BSDR("CLN")_",""S"",",DA(1)=BSDR("CLN"),(X,DINUM)=BSDR("ADT")
115 . S DIC("P")="44.001DA",DIC(0)="L",DLAYGO=44.001
116 . S Y=1 I '$D(@(DIC_X_")")) D FILE^DICN
117 ;
118 Q:$G(BSDXSIMERR4) 1_U_$NA(BSDXSIMERR4) ; Unit Test line
119 ;
120 ; add appt for file 44, second subfile (Appointment/Patient)
121 ; Sep 28 2010: Changed old style API to new style API. Keep for reference //smh
122 ;K DIC,DA,X,Y,DLAYGO,DD,DO,DINUM
123 ;S DIC="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
124 ;S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),X=BSDR("PAT")
125 ;S DIC("DR")="1///"_BSDR("LEN")_";3///"_$E($G(BSDR("OI")),1,150)_";7///`"_BSDR("USR")_";8///"_$P($$NOW^XLFDT,".")
126 ;S DIC("P")="44.003PA",DIC(0)="L",DLAYGO=44.003
127 ;D FILE^DICN
128 ;
129 N BSDXIENS S BSDXIENS="?+1,"_BSDR("ADT")_","_BSDR("CLN")_","
130 N BSDXFDA
131 S BSDXFDA(44.003,BSDXIENS,.01)=BSDR("PAT")
132 S BSDXFDA(44.003,BSDXIENS,1)=BSDR("LEN")
133 S BSDXFDA(44.003,BSDXIENS,3)=$E($G(BSDR("OI")),1,150)
134 S BSDXFDA(44.003,BSDXIENS,7)=BSDR("USR")
135 S BSDXFDA(44.003,BSDXIENS,8)=$P($$NOW^XLFDT,".")
136 N BSDXERR
137 D UPDATE^DIE("","BSDXFDA","","BSDXERR")
138 ;
139 I $D(BSDXERR) Q 1_U_"Error adding appt to file 44: Clinic="_BSDR("CLN")_" Date="_BSDR("ADT")_" Patient="_BSDR("PAT")_" Error: "_BSDXERR("DIERR",1,"TEXT",1)
140 ;
141 ;Q:$G(BSDXSIMERR5) 1_U_$NA(BSDXSIMERR5) ; Unit Test line
142 S:$G(BSDXSIMERR5) X=1/0
143 ;
144 ; call event driver
145 NEW DFN,SDT,SDCL,SDDA,SDMODE
146 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2
147 S SDDA=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
148 D MAKE^SDAMEVT(DFN,SDT,SDCL,SDDA,SDMODE)
149 Q 0
150 ;
151MAKECK(BSDR) ; $$ - Is it okay to make an appointment? ; PEP
152 ; Input: Same as $$MAKE
153 ; Output: 1^error or 0 for success
154 ; NB: This subroutine saves no data. Only checks whether it's okay.
155 ;
156 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
157 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
158 I ($G(BSDR("TYP"))<3)!($G(BSDR("TYP"))>4) Q 1_U_"Appt Type error: "_$G(BSDR("TYP"))
159 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
160 I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
161 ;
162 ; Appt Length check removed in v 1.5
163 ;
164 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Made Appt Error: "_$G(BSDR("USR"))
165 ; More verbose error message in v1.5
166 ; Following block to give an error message to user if there is already an appointment for patient. More verbose than others.
167 N BSDXERR ; place to store error message
168 I $D(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0)),$P(^(0),U,2)'["C" DO QUIT BSDXERR ; If there's an appt in the "S" node of file 2 and it's not cancelled
169 . S BSDXERR=1_U_"Patient "_$P(^DPT(BSDR("PAT"),0),U)_" ("_BSDR("PAT")_") "
170 . S BSDXERR=BSDXERR_"already has appt at "_$$FMTE^XLFDT(BSDR("ADT"))
171 . N BSDXSCIEN S BSDXSCIEN=$P(^DPT(BSDR("PAT"),"S",BSDR("ADT"),0),U) ; Clinic IEN in ^SC (0 piece of 0 node of "S" multiple in file 2)
172 . N BSDXSCNAM S BSDXSCNAM=$P(^SC(BSDXSCIEN,0),U) ; PIMS Name of Clinic
173 . S BSDXERR=BSDXERR_$C(13,10)_"PIMS clinic: "_BSDXSCNAM ; tell the user of the PIMS clinic
174 . I $D(^BSDXRES("ALOC",BSDXSCIEN)) DO ; if the Clinic is linked to a BSDX Resource (we find out using the index ALOC in the BSDX RESOURCE file)
175 . . N BSDXRESIEN S BSDXRESIEN=$O(^BSDXRES("ALOC",BSDXSCIEN,""))
176 . . QUIT:'BSDXRESIEN ; Safeguard if index is corrupt
177 . . N BSDXRESNAM S BSDXRESNAM=$P(^BSDXRES(BSDXRESIEN,0),U)
178 . . S BSDXERR=BSDXERR_$C(13,10)_"Scheduling GUI clinic: "_BSDXRESNAM ; tell the user of the BSDX clinic
179 Q 0
180 ;
181UNMAKE(BSDR) ; Reverse Make - Private $$
182 ; Only used in Emergiencies where Fileman data filing fails.
183 ; If previous data exists, which caused an error, it's destroyed.
184 ; NB: ^DIK stops for nobody
185 ; Input: Same array as $$MAKE
186 ; Output: Always 0
187 NEW DIK,DA
188 S DIK="^DPT("_BSDR("PAT")_",""S"","
189 S DA(1)=BSDR("PAT"),DA=BSDR("ADT")
190 D ^DIK
191 ;
192 N IEN S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
193 I 'IEN QUIT 0
194 ;
195 NEW DIK,DA
196 S DIK="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
197 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
198 D ^DIK
199 QUIT 0
200 ;
201CHECKIN1(DFN,CLIN,APDATE) ; Simplified PEP w/ parameters for $$CHECKIN - Checking in
202 ; Call like this for DFN 23435 checking in now at Hospital Location 33
203 ; for appt at Dec 20, 2009 @ 10:11:59
204 ; S RESULT=$$CHECKIN1^BSDXAPI(23435,33,3091220.221159)
205 N BSDR
206 S BSDR("PAT")=DFN ;DFN
207 S BSDR("CLN")=CLIN ;Hosp Loc IEN
208 S BSDR("ADT")=APDATE ;Appt Date
209 S BSDR("CDT")=$$NOW^XLFDT ;Check-in date defaults to now
210 S BSDR("USR")=DUZ ;Check-in user defaults to current
211 Q $$CHECKIN(.BSDR)
212 ;
213CHECKIN(BSDR) ;EP; call to add checkin info to appt; IHS/ITSC/LJF 12/23/2004 PATCH 1002
214 ;
215 ; Make call by using: S ERR=$$CHECKIN^BSDXAPI(.ARRAY)
216 ;
217 ; Input array -
218 ; BSDR("PAT") = ien of patient in file 2
219 ; BSDR("CLN") = ien of clinic in file 44
220 ; BSDR("ADT") = appt date/time
221 ; BSDR("CDT") = checkin date/time
222 ; BSDR("USR") = checkin user
223 ;
224 ; Output value -
225 ; = 0 means everything worked
226 ; = 1^message means error with reason message
227 ;
228 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
229 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
230 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
231 I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
232 I $G(BSDR("CDT")) S BSDR("CDT")=+$E(BSDR("CDT"),1,12) ;remove seconds
233 I $G(BSDR("CDT"))'?7N.1".".4N Q 1_U_"Checkin Date/Time error: "_$G(BSDR("CDT"))
234 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Made Appt Error: "_$G(BSDR("USR"))
235 ;
236 ; find ien for appt in file 44
237 NEW IEN,DIE,DA,DR
238 S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
239 I 'IEN Q 1_U_"Error trying to find appointment for checkin: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
240 ;
241 ; remember before status
242 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL,SDMODE
243 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2,SDDA=IEN
244 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
245 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
246 ;
247 ; set checkin
248 S DIE="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
249 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
250 S DR="309///"_BSDR("CDT")_";302///`"_BSDR("USR")_";305///"_$$NOW^XLFDT
251 D ^DIE
252 ;
253 ; set after status
254 S SDDA=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
255 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
256 D AFTER^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
257 ;
258 ; call event driver
259 D EVT^SDAMEVT(.SDATA,4,SDMODE,SDCIHDL)
260 Q 0
261 ;
262CANCEL1(DFN,CLIN,TYP,APDATE,REASON,INFO) ; PEP w/ parameters for $$CANCEL - cancelling appointment
263 ; Call like this for DFN 23435 cancelling an appointment at Hospital Location 33,
264 ; cancellation initiated by patient ("PC" rather than clinic "C"),
265 ; cancelling appt at Dec 20, 2009 @ 10:11:59 because of reason 1 in file 409.2 IEN (weather)
266 ; because foxes come out during bad weather.
267 ; S RESULT=$$CANCEL1^BSDXAPI(23435,33,"PC",3091220.221159,1,"Afraid of foxes")
268 N BSDR
269 S BSDR("PAT")=DFN
270 S BSDR("CLN")=CLIN
271 S BSDR("TYP")=TYP
272 S BSDR("ADT")=APDATE
273 S BSDR("CDT")=$$NOW^XLFDT
274 S BSDR("USR")=DUZ
275 S BSDR("CR")=REASON
276 S BSDR("NOT")=INFO
277 Q $$CANCEL(.BSDR)
278 ;
279CANCEL(BSDR) ;PEP; called to cancel appt
280 ;
281 ; Make call using: S ERR=$$CANCEL^BSDXAPI(.ARRAY)
282 ;
283 ; Input Array -
284 ; BSDR("PAT") = ien of patient in file 2
285 ; BSDR("CLN") = ien of clinic in file 44
286 ; BSDR("TYP") = C for canceled by clinic; PC for patient canceled
287 ; BSDR("ADT") = appointment date and time
288 ; BSDR("CDT") = cancel date and time
289 ; BSDR("USR") = user who canceled appt
290 ; BSDR("CR") = cancel reason - pointer to file 409.2
291 ; BSDR("NOT") = cancel remarks - optional notes to 160 characters
292 ;
293 ;Output: error status and message
294 ; = 0 or null: everything okay
295 ; = 1^message: error and reason
296 ;
297 ; Okay to Cancel? Call Cancel Check.
298 N BSDXCANCK S BSDXCANCK=$$CANCELCK(.BSDR)
299 I BSDXCANCK Q BSDXCANCK
300 ;
301 ; BSDX 1.5 3110125
302 ; UJO/SMH - Add ability to remove check-in if the patient is checked in
303 ; VEN/SMH on 3120625/v1.7 - PIMS doesn't care if patient is already checked in
304 ; Lets you remove appointment anyways! Not like RPMS.
305 ; Plus... deleting checkin affects S node on 44, which is DELETED anyways!
306 ;
307 ; remember before status
308 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCPHDL,SDMODE
309 S DFN=BSDR("PAT"),SDT=BSDR("ADT"),SDCL=BSDR("CLN"),SDMODE=2,SDDA=IEN
310 S SDCPHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
311 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCPHDL)
312 ; NB: Here only ^TMP globals are set with before values.
313 ;
314 ; get user who made appt and date appt made from ^SC
315 ; because data in ^SC will be deleted
316 NEW USER,DATE
317 S USER=$P($G(^SC(SDCL,"S",SDT,1,IEN,0)),U,6)
318 S DATE=$P($G(^SC(SDCL,"S",SDT,1,IEN,0)),U,7)
319 ;
320 ; update file 2 info --old code
321 ;NEW DIE,DA,DR
322 ;S DIE="^DPT("_DFN_",""S"",",DA(1)=DFN,DA=SDT
323 ;S DR="3///"_BSDR("TYP")_";14///`"_BSDR("USR")_";15///"_BSDR("CDT")_";16///`"_BSDR("CR")_";19///`"_USER_";20///"_DATE
324 ;S:$G(BSDR("NOT"))]"" DR=DR_";17///"_$E(BSDR("NOT"),1,160)
325 ;D ^DIE
326 N BSDXIENS S BSDXIENS=SDT_","_DFN_","
327 N BSDXFDA
328 S BSDXFDA(2.98,BSDXIENS,3)=BSDR("TYP")
329 S BSDXFDA(2.98,BSDXIENS,14)=BSDR("USR")
330 S BSDXFDA(2.98,BSDXIENS,15)=BSDR("CDT")
331 S BSDXFDA(2.98,BSDXIENS,16)=BSDR("CR")
332 S BSDXFDA(2.98,BSDXIENS,19)=USER
333 S BSDXFDA(2.98,BSDXIENS,20)=DATE
334 S:$G(BSDR("NOT"))]"" BSDXFDA(2.98,BSDXIENS,17)=$E(BSDR("NOT"),1,160)
335 N BSDXERR
336 D FILE^DIE("","BSDXFDA","BSDXERR")
337 I $D(BSDXERR) Q 1_U_"Cannot cancel appointment in File 2"
338 ; Failure point 1: If we fail here, nothing has happened yet.
339 ; No rollback needed in ^BSDXAPPT
340 ;
341 ; delete data in ^SC -- this does not (typically) fail. Fileman won't stop
342 NEW DIK,DA
343 S DIK="^SC("_BSDR("CLN")_",""S"","_BSDR("ADT")_",1,"
344 S DA(2)=BSDR("CLN"),DA(1)=BSDR("ADT"),DA=IEN
345 D ^DIK
346 ; Failure point 2: not expected to happen here
347 ;
348 ; call event driver -- point of no return
349 D CANCEL^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDMODE,SDCPHDL)
350 Q 0
351 ;
352CANCELCK(BSDR) ; $$ PEP; Okay to Cancel Appointment?
353 ; Input: .BSDR array as documented in $$CANCEL
354 ; Output: 0 or 1^Error message
355 I '$D(^DPT(+$G(BSDR("PAT")),0)) Q 1_U_"Patient not on file: "_$G(BSDR("PAT"))
356 I '$D(^SC(+$G(BSDR("CLN")),0)) Q 1_U_"Clinic not on file: "_$G(BSDR("CLN"))
357 I ($G(BSDR("TYP"))'="C"),($G(BSDR("TYP"))'="PC") Q 1_U_"Cancel Status error: "_$G(BSDR("TYP"))
358 I $G(BSDR("ADT")) S BSDR("ADT")=+$E(BSDR("ADT"),1,12) ;remove seconds
359 I $G(BSDR("ADT"))'?7N.1".".4N Q 1_U_"Appt Date/Time error: "_$G(BSDR("ADT"))
360 I $G(BSDR("CDT")) S BSDR("CDT")=+$E(BSDR("CDT"),1,12) ;remove seconds
361 I $G(BSDR("CDT"))'?7N.1".".4N Q 1_U_"Cancel Date/Time error: "_$G(BSDR("CDT"))
362 I '$D(^VA(200,+$G(BSDR("USR")),0)) Q 1_U_"User Who Canceled Appt Error: "_$G(BSDR("USR"))
363 I '$D(^SD(409.2,+$G(BSDR("CR")))) Q 1_U_"Cancel Reason error: "_$G(BSDR("CR"))
364 ;
365 NEW IEN S IEN=$$SCIEN(BSDR("PAT"),BSDR("CLN"),BSDR("ADT"))
366 I 'IEN Q 1_U_"Error trying to find appointment for cancel: Patient="_BSDR("PAT")_" Clinic="_BSDR("CLN")_" Appt="_BSDR("ADT")
367 Q 0
368CI(PAT,CLINIC,DATE,SDIEN) ;PEP; -- returns 1 if appt already checked-in
369 NEW X
370 S X=$G(SDIEN) ;ien sent in call
371 I 'X S X=$$SCIEN(PAT,CLINIC,DATE) I 'X Q 0
372 S X=$P($G(^SC(CLINIC,"S",DATE,1,X,"C")),U)
373 Q $S(X:1,1:0)
374 ;
375RMCI(PAT,CLINIC,DATE) ;PEP; -- Remove Check-in; $$
376 ; PAT = DFN
377 ; CLINIC = SC IEN
378 ; DATE = FM Date/Time of Appointment
379 ;
380 ; Returns:
381 ; 0 if okay
382 ; -1 if failure
383 ;
384 ; Call like this: $$RMCI(233,33,3110102.1130)
385 ;
386 ; Move my variables into the ones used by SDAPIs (just a convenience)
387 NEW SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL,SDMODE
388 S DFN=PAT,SDT=DATE,SDCL=CLINIC,SDMODE=2,SDDA=$$SCIEN(DFN,SDCL,SDT)
389 ;
390 I SDDA<1 QUIT 0 ; Appt cancelled; cancelled appts rm'ed from file 44
391 ;
392 ; remember before status
393 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
394 D BEFORE^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
395 ;
396 ; remove check-in using filer.
397 N BSDXIENS S BSDXIENS=SDDA_","_DATE_","_CLINIC_","
398 N BSDXFDA
399 S BSDXFDA(44.003,BSDXIENS,309)="@" ; CHECKED-IN
400 S BSDXFDA(44.003,BSDXIENS,302)="@" ; CHECK IN USER
401 S BSDXFDA(44.003,BSDXIENS,305)="@" ; CHECK IN ENTERED
402 N BSDXERR
403 D FILE^DIE("","BSDXFDA","BSDXERR")
404 I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
405 ;
406 ; set after status
407 ; S SDDA=$$SCIEN(DFN,SDCL,SDT) ;smh -why is this here? SDDA won't change.
408 S SDCIHDL=$$HANDLE^SDAMEVT(1),SDATA=SDDA_U_DFN_U_SDT_U_SDCL
409 D AFTER^SDAMEVT(.SDATA,DFN,SDT,SDCL,SDDA,SDCIHDL)
410 ;
411 ; call event driver
412 D EVT^SDAMEVT(.SDATA,4,SDMODE,SDCIHDL)
413 QUIT 0
414 ;
415SCIEN(PAT,CLINIC,DATE) ;PEP; returns ien for appt in ^SC
416 NEW X,IEN
417 S X=0 F S X=$O(^SC(CLINIC,"S",DATE,1,X)) Q:'X Q:$G(IEN) D
418 . Q:$P($G(^SC(CLINIC,"S",DATE,1,X,0)),U,9)["C" ;cancelled
419 . I +$G(^SC(CLINIC,"S",DATE,1,X,0))=PAT S IEN=X
420 Q $G(IEN)
421 ;
422APPLEN(PAT,CLINIC,DATE) ; $$ PEP; returns an appointment's length
423 ; Get either the appointment length or zero
424 ; TODO: Test
425 N SCIEN S SCIEN=$$SCIEN(PAT,CLINIC,DATE)
426 Q:SCIEN $P(^SC(CLINIC,"S",DATE,1,SCIEN,0),U,2)
427 Q 0
428APPTYP(PAT,DATE) ;PEP; -- returns type of appt (scheduled or walk-in)
429 NEW X S X=$P($G(^DPT(PAT,"S",DATE,0)),U,7)
430 Q $S(X=3:"SCHED",X=4:"WALK-IN",1:"??")
431 ;
432CO(PAT,CLINIC,DATE,SDIEN) ;PEP; -- returns 1 if appt already checked-out
433 NEW X
434 S X=$G(SDIEN) ;ien sent in call
435 I 'X S X=$$SCIEN(PAT,CLINIC,DATE) I 'X Q 0
436 S X=$P($G(^SC(CLINIC,"S",DATE,1,X,"C")),U,3)
437 Q $S(X:1,1:0)
438 ;
439UPDATENT(PAT,CLINIC,DATE,NOTE) ; PEP; Update Note in ^SC for patient's appointment @ DATE
440 ; PAT = DFN
441 ; CLINIC = SC IEN
442 ; DATE = FM Date/Time of Appointment
443 ;
444 ; Returns:
445 ; 0 if okay
446 ; -1 if failure
447 ;
448 ; ERROR SIMULATION
449 I $G(BSDXSIMERR1) QUIT "-1~Simulated Error"
450 ;
451 N SCIEN S SCIEN=$$SCIEN(PAT,CLINIC,DATE) ; ien of appt in ^SC
452 I SCIEN<1 QUIT 0 ; Appt cancelled; cancelled appts rm'ed from file 44
453 N BSDXIENS S BSDXIENS=SCIEN_","_DATE_","_CLINIC_","
454 N BSDXFDA S BSDXFDA(44.003,BSDXIENS,3)=$E(NOTE,1,150)
455 N BSDXERR
456 D FILE^DIE("","BSDXFDA","BSDXERR")
457 I $D(BSDXERR) QUIT "-1~Can't file for Pat "_PAT_" in Clinic "_CLINIC_" at "_DATE_". Fileman reported an error: "_BSDXERR("DIERR",1,"TEXT",1)
458 QUIT 0
Note: See TracBrowser for help on using the repository browser.