source: WorldVistAEHR/trunk/r/ACCOUNTS_RECEIVABLE-PRCA-PRY-RC/RCDPEDA1.m@ 1093

Last change on this file since 1093 was 613, checked in by George Lilly, 15 years ago

initial load of WorldVistAEHR
File size: 3.2 KB
Line 
1RCDPEDA1 ;ALB/TMK - ACTIVITY REPORT HEADER ;04-NOV-02
2 ;;4.5;Accounts Receivable;**173**;Mar 20, 1995
3 ;;Per VHA Directive 10-93-142, this routine should not be modified.
4 Q
5 ;
6HDR(RCCT,RCPG,RCSTOP,RCDT1,RCDT2,RCDET,RCNITE) ;Prints report heading
7 ; Function returns RCPG = current page # and RCCT = running line count
8 ; and RCSTOP = 1 if user aborted print
9 ; Parameters RCCT,RCPG,RCSTOP must be passed by reference
10 ; RCDT1,RCDT2 = from,to date
11 ; RCDET = flag = 1 if detail is desired
12 N Z,Z0,X,Y
13 Q:RCNITE&(RCPG)
14 I RCPG!($E(IOST,1,2)="C-") D
15 . Q:$G(RCNITE)
16 . I RCPG&($E(IOST,1,2)="C-") D ASK(.RCSTOP) Q:RCSTOP
17 . W @IOF,*13 ; Write form feed
18 Q:RCSTOP
19 S RCPG=RCPG+1
20 S Z0="EDI LOCKBOX DAILY ACTIVITY "_$S($G(RCDET):"DETAIL",1:"SUMMARY")_" REPORT"
21 S Z=$$SETSTR^VALM1($J("",80-$L(Z0)\2)_Z0,"",1,79)
22 S Z=$$SETSTR^VALM1("Page: "_RCPG,Z,70,10)
23 D SETLINE^RCDPEDAR(RCNITE,Z,.RCCT)
24 S Z0="RUN DATE: "_$$FMTE^XLFDT(DT,2),Z0=$J("",80-$L(Z0)\2)_Z0
25 S Z=$$SETSTR^VALM1(Z0,"",1,79)
26 D SETLINE^RCDPEDAR(RCNITE,Z,.RCCT)
27 D SETLINE^RCDPEDAR(RCNITE," ",.RCCT)
28 D SETLINE^RCDPEDAR(RCNITE,"DATE RANGE SELECTED: "_$$FMTE^XLFDT(RCDT1,2)_"-"_$$FMTE^XLFDT(RCDT2,2),.RCCT)
29 D SETLINE^RCDPEDAR(RCNITE," ",.RCCT)
30 I $G(RCDET) D
31 . S Z=$$SETSTR^VALM1("DEP # DEPOSIT DT "_$J("",22)_"DEP AMOUNT FMS DEPOSIT STAT","",1,80)
32 . D SETLINE^RCDPEDAR(RCNITE,Z,.RCCT)
33 . D SETLINE^RCDPEDAR(RCNITE," ",.RCCT)
34 . S Z=$$SETSTR^VALM1($J("",3)_"EFT # EFT PAYER TRACE #"_$J("",4)_"DATE PD PAYMENT AMOUNT ERA MATCH STATUS","",1,80)
35 . D SETLINE^RCDPEDAR(RCNITE,Z,.RCCT)
36 . S Z=$$SETSTR^VALM1($J("",14)_"PAYMENT FROM","",1,30)
37 . S Z=$$SETSTR^VALM1("DEP RECEIPT #",Z,46,15)
38 . S Z=$$SETSTR^VALM1("DEP RECEIPT STATUS",Z,61,19)
39 . D SETLINE^RCDPEDAR(RCNITE,Z,.RCCT)
40 D SETLINE^RCDPEDAR(RCNITE,$TR($J("",IOM-1)," ","="),.RCCT)
41 Q
42 ;
43ASK(RCSTOP) ; Ask to continue
44 ; If passed by reference ,RCSTOP is returned as 1 if print is aborted
45 I $E(IOST,1,2)'["C-" Q
46 N DIR,DIROUT,DIRUT,DTOUT,DUOUT
47 S DIR(0)="E" W ! D ^DIR
48 I ($D(DIRUT))!($D(DUOUT)) S RCSTOP=1 Q
49 Q
50 ;
51EFTDET(Z2,Z3,RCCT,RCPG,RCSTOP,RCDT1,RCDT2,RCDET,RCFMS1,RCNITE) ; Display EFT Detail
52 N X
53 S X=$$SETSTR^VALM1(Z2,"",4,6)
54 S X=$$SETSTR^VALM1($P(Z3,U,4),X,11,20)
55 S X=$$SETSTR^VALM1($$FMTE^XLFDT($P(Z3,U,12)\1,2),X,32,8)
56 S X=$$SETSTR^VALM1($J($P(Z3,U,7),"",2),X,42,18)
57 S X=$$SETSTR^VALM1($$EXTERNAL^DILFD(344.31,.08,"",+$P(Z3,U,8))_$S($P(Z3,U,8)=1:"/ERA #"_$P(Z3,U,10),1:""),X,61,20)
58 I '$G(RCNITE),($Y+5)>IOSL D HDR(.RCCT,.RCPG,.RCSTOP,RCDT1,RCDT2,RCDET,RCNITE) Q:RCSTOP
59 D SETLINE^RCDPEDAR(RCNITE,X,.RCCT)
60 S X=$$SETSTR^VALM1($E($P(Z3,U,2),1,20)_"/"_$P(Z3,U,3),"",15,35)
61 I $P(Z3,U,9) S X=$$SETSTR^VALM1($P($G(^RCY(344,+$P(Z3,U,9),0)),U),X,46,10)
62 S X=$$SETSTR^VALM1($G(RCFMS1(Z2)),X,61,19)
63 I '$G(RCNITE),($Y+5)>IOSL D HDR(.RCCT,.RCPG,.RCSTOP,RCDT1,RCDT2,RCDET,RCNITE) Q:RCSTOP
64 D SETLINE^RCDPEDAR(RCNITE,X,.RCCT)
65 I $O(^RCY(344.31,Z2,2,0)) D Q:RCSTOP
66 . N V
67 . I '$G(RCNITE),($Y+5)>IOSL D HDR(.RCCT,.RCPG,.RCSTOP,RCDT1,RCDT2,RCDET,RCNITE) Q:RCSTOP
68 . D SETLINE^RCDPEDAR(RCNITE,$J("",10)_"ERROR MESSAGES FOR EFT DETAIL:",.RCCT)
69 . S V=0 F S V=$O(^RCY(344.31,Z2,2,V)) Q:'V D Q:RCSTOP
70 .. I '$G(RCNITE),($Y+5)>IOSL D HDR(.RCCT,.RCPG,.RCSTOP,RCDT1,RCDT2,RCDET,RCNITE) Q:RCSTOP
71 .. D SETLINE^RCDPEDAR(RCNITE,$J("",12)_$G(^RCY(344.31,Z2,2,V,0)),.RCCT)
72 Q
73 ;
Note: See TracBrowser for help on using the repository browser.