| 1 | GMRCILKP ;SLC/JFR - LOOK UP IFC BY REMOTE CONS #; 1/2/02 14:34
|
|---|
| 2 | ;;3.0;CONSULT/REQUEST TRACKING;**22**;DEC 27, 1997
|
|---|
| 3 | EN ; start here
|
|---|
| 4 | N DIR,DIRUT,DIROUT,DTOUT,DUOUT,X,Y,GMRCSIT,GMRCO,DFN,GMRCREMC
|
|---|
| 5 | N VALMBCK,VALMCNT,GMRCA,GMRCDIF,GMRCDVL,GMRCLOC,GMRCWARD,GMRCX,GMRCDISP
|
|---|
| 6 | S DIR(0)="PO^4:EMQ"
|
|---|
| 7 | S DIR("S")="I $$STA^XUAF4(+Y)=+$$STA^XUAF4(+Y)"
|
|---|
| 8 | S DIR("A")="Choose the facility to which the remote entry belongs"
|
|---|
| 9 | D ^DIR
|
|---|
| 10 | I $D(DIRUT) Q
|
|---|
| 11 | S GMRCSIT=+Y
|
|---|
| 12 | K X,Y,DIR
|
|---|
| 13 | S DIR(0)="NO^1:9999999"
|
|---|
| 14 | S DIR("A")="Select the Remote Consult Entry #"
|
|---|
| 15 | D ^DIR
|
|---|
| 16 | I $D(DIRUT) Q
|
|---|
| 17 | S GMRCREMC=Y
|
|---|
| 18 | S GMRCO=$O(^GMR(123,"AIFC",GMRCSIT,GMRCREMC,0))
|
|---|
| 19 | I '$G(GMRCO) D G EN
|
|---|
| 20 | . W $C(7),!!
|
|---|
| 21 | . W "No Consult on file for the selected site with that remote number!"
|
|---|
| 22 | . W !!
|
|---|
| 23 | . K DIR
|
|---|
| 24 | . S DIR(0)="E" D ^DIR
|
|---|
| 25 | . W !,"Select again"
|
|---|
| 26 | S DFN=$P(^GMR(123,GMRCO,0),U,2)
|
|---|
| 27 | K DIR
|
|---|
| 28 | S DIR(0)="S^B:brief;D:detailed"
|
|---|
| 29 | S DIR("A")="Display type"
|
|---|
| 30 | S DIR("B")="B"
|
|---|
| 31 | D ^DIR
|
|---|
| 32 | I $D(DTOUT)!($D(DUOUT)) Q
|
|---|
| 33 | S GMRCDISP=Y
|
|---|
| 34 | I GMRCDISP="B" D G EN
|
|---|
| 35 | . N GMRCST,GMRCSS,GMRCPNM,GMRCSN
|
|---|
| 36 | . D DEM^GMRCU
|
|---|
| 37 | . S GMRCSN=$P(GMRCSN,"-",3)
|
|---|
| 38 | . S GMRCPNM=$E(GMRCPNM,1,23)
|
|---|
| 39 | . S GMRCST=$$GET1^DIQ(100.01,$P(^GMR(123,GMRCO,0),U,12),.1)
|
|---|
| 40 | . S GMRCSS=$E($$SVC^GMRCAU(GMRCO),1,22)
|
|---|
| 41 | . W !!,"Local cslt# To Service",?37,"Status Patient",?74,"SSN"
|
|---|
| 42 | . W !,$$REPEAT^XLFSTR("-",79)
|
|---|
| 43 | . W !,GMRCO,?14,GMRCSS,?39,GMRCST,?46,GMRCPNM,?74,GMRCSN,!!
|
|---|
| 44 | . K DIR S DIR(0)="E" D ^DIR
|
|---|
| 45 | . W !,"Select again"
|
|---|
| 46 | . D ^GMRCREXT
|
|---|
| 47 | I GMRCDISP="D" D G EN
|
|---|
| 48 | . D DT^GMRCSLM2(GMRCO)
|
|---|
| 49 | . I '$D(^TMP("GMRCR",$J,"DT")) W !,"Error finding details!" Q
|
|---|
| 50 | . M ^TMP("GMRCR",$J,"DTLIST")=^TMP("GMRCR",$J,"DT")
|
|---|
| 51 | . S VALMCNT=$O(^TMP("GMRCR",$J,"DTLIST"," "),-1)
|
|---|
| 52 | . D EN^VALM("GMRC DETAILED DISPLAY")
|
|---|
| 53 | . D ^GMRCREXT
|
|---|
| 54 | Q
|
|---|
