| 1 | FBRXFR ;WOIFO/SAB-FILE REMITTANCE REMARKS FOR PHARMACY PAYMENT ;7/17/2003
|
|---|
| 2 | ;;3.5;FEE BASIS;**61**;JAN 30, 1995
|
|---|
| 3 | Q
|
|---|
| 4 | FILERR(FBIENS,FBRRMK) ; File Remittance Remakrs
|
|---|
| 5 | ;
|
|---|
| 6 | ; Input
|
|---|
| 7 | ; FBIENS - required, internal entry numbers for subfile 162.11
|
|---|
| 8 | ; in standard format as specified for FileMan DBS calls
|
|---|
| 9 | ; FBRRMK - required, array passed by reference
|
|---|
| 10 | ; array of remittance remarks to file
|
|---|
| 11 | ; array does not have to contain any data or be defined
|
|---|
| 12 | ; format
|
|---|
| 13 | ; FBRRMK(#)=FBRRMKC
|
|---|
| 14 | ; where
|
|---|
| 15 | ; # = sequentially assigned number starting with 1
|
|---|
| 16 | ; FBRRMKC = remittance remark (internal value file 162.93)
|
|---|
| 17 | ; Output
|
|---|
| 18 | ; Data in File 162.11 will be modified
|
|---|
| 19 | ;
|
|---|
| 20 | N FB,FBFDA,FBI,FBSIENS
|
|---|
| 21 | ;
|
|---|
| 22 | ; delete remitance remarks currently on file
|
|---|
| 23 | D GETS^DIQ(162.11,FBIENS,"38*","","FB")
|
|---|
| 24 | K FBFDA
|
|---|
| 25 | S FBSIENS="" F S FBSIENS=$O(FB(162.15,FBSIENS)) Q:FBSIENS="" D
|
|---|
| 26 | . S FBFDA(162.15,FBSIENS,.01)="@"
|
|---|
| 27 | I $D(FBFDA) D FILE^DIE("","FBFDA")
|
|---|
| 28 | ;
|
|---|
| 29 | ; file remarks from input array
|
|---|
| 30 | K FBFDA
|
|---|
| 31 | S FBI=0 F S FBI=$O(FBRRMK(FBI)) Q:'FBI D
|
|---|
| 32 | . S FBFDA(162.15,"+"_FBI_","_FBIENS,.01)=$P(FBRRMK(FBI),U)
|
|---|
| 33 | I $D(FBFDA) D UPDATE^DIE("","FBFDA")
|
|---|
| 34 | ;
|
|---|
| 35 | Q
|
|---|
| 36 | ;
|
|---|
| 37 | LOADRR(FBIENS,FBRRMK) ; Load Remittance Remarks
|
|---|
| 38 | ; Input
|
|---|
| 39 | ; FBIENS - required, internal entry numbers for subfile 162.11
|
|---|
| 40 | ; in standard format as specified for FileMan DBS calls
|
|---|
| 41 | ; FBRRMK - required, array passed by reference
|
|---|
| 42 | ; array to load adjustments into
|
|---|
| 43 | ; Output
|
|---|
| 44 | ; FBRRMK - the FBRRMK input array passed by reference will be modified
|
|---|
| 45 | ; format
|
|---|
| 46 | ; FBRRMK(#)=FBRRMKC
|
|---|
| 47 | ; where
|
|---|
| 48 | ; # = sequentially assigned number starting with 1
|
|---|
| 49 | ; FBRRMKC = remittance remark (internal value file 162.93)
|
|---|
| 50 | ; if no remarks are on file then the array will be undefined
|
|---|
| 51 | N FB,FBC,FBI,FBSIENS
|
|---|
| 52 | ;
|
|---|
| 53 | K FBRRMK
|
|---|
| 54 | ;
|
|---|
| 55 | S FBC=0
|
|---|
| 56 | D GETS^DIQ(162.11,FBIENS,"38*","I","FB")
|
|---|
| 57 | S FBSIENS="" F S FBSIENS=$O(FB(162.15,FBSIENS)) Q:FBSIENS="" D
|
|---|
| 58 | . S FBC=FBC+1
|
|---|
| 59 | . S FBRRMK(FBC)=FB(162.15,FBSIENS,.01,"I")
|
|---|
| 60 | ;
|
|---|
| 61 | Q
|
|---|
| 62 | ;
|
|---|
| 63 | RRL(FBIENS) ; Remittance Remarks List Extrinsic Function
|
|---|
| 64 | ; Input
|
|---|
| 65 | ; FBIENS - required, internal entry numbers for subfile 162.11
|
|---|
| 66 | ; in standard format as specified for FileMan DBS calls
|
|---|
| 67 | ; Result
|
|---|
| 68 | ; string containing sorted list (by external code) of remarks
|
|---|
| 69 | ; format
|
|---|
| 70 | ; FBRRMKCE 1, FBRRMKCE 2
|
|---|
| 71 | ; where
|
|---|
| 72 | ; FBRRMKCE = remittance remark code (external value)
|
|---|
| 73 | N FBRET,FBRRMK
|
|---|
| 74 | D LOADRR^FBRXFR(FBIENS,.FBRRMK)
|
|---|
| 75 | S FBRET=$$RRL^FBUTL4(.FBRRMK)
|
|---|
| 76 | Q FBRET
|
|---|
| 77 | ;
|
|---|
| 78 | ;FBRXFR
|
|---|
